树莓派的QT交叉编译：找不到GLESv2

Question

我正在尝试为我的树莓派3计算模块编译qt 5.9，主要是遵循这里的在线指南（https://wiki.qt.io/RaspberryPi2EGLFS）。因此，我将pi系统根设置为挂载点/mnt/pi-rootfs。我还使用脚本sysroot-relativelinks.py将符号链接设置为相对路径。

qtbase配置使用以下参数进行调用：

./configure -opengl es2 -device linux-rpi3-g++ -device-option 
CROSS_COMPILE=/home/osboxes/Downloads/gcc-linaro-6.3.1-2017.05-x86_64_arm-linux-gnueabihf/bin/arm-linux-gnueabihf- 
-sysroot /mnt/pi-rootfs -opensource -confirm-license -optimized-qmake 
-reduce-exports -release -make libs -prefix /usr/local/qt5pi 
-hostprefix /usr/local/qt5pi

这个配置了Qt但没有配置OpenGL，我收到了以下信息：

ERROR: Feature 'opengles2' was enabled, but the pre-condition 'config.win32 || (!config.watchos && !features.opengl-desktop && libs.opengl_es2)' failed.

ERROR: The OpenGL functionality tests failed!
You might need to modify the include and library search paths by editing QMAKE_INCDIR_OPENGL[_ES2],
QMAKE_LIBDIR_OPENGL[_ES2] and QMAKE_LIBS_OPENGL[_ES2] in the mkspec for your platform.

Check config.log for details.

看一下配置文件，我有：

> /home/osboxes/Downloads/gcc-linaro-6.3.1-2017.05-x86_64_arm-linux-gnueabihf/bin/arm-linux-gnueabihf-g++ -c -march=armv8-a -mtune=cortex-a53 -mfpu=crypto-neon-fp-armv8 -mfloat-abi=hard --sysroot=/mnt/pi-rootfs --sysroot=/mnt/pi-rootfs -O2 -Wall -W -fPIC  -I. -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux -I/home/osboxes/Downloads/qt5/qtbase/mkspecs/devices/linux-rpi3-g++ -o opengles2.o opengles2.cpp
> opengles2.cpp:44:25: fatal error: GLES2/gl2.h: No such file or directory
>    #include <GLES2/gl2.h>
>                          ^
> compilation terminated.
> Makefile:179: recipe for target 'opengles2.o' failed
> make: *** [opengles2.o] Error 1
 => source failed verification.
test config.gui.libraries.opengl_es2 FAILED

因此，它没有正确地设置路径，因此我编辑了linux-rpi3-g++的mkspecs文件。 因此，该文件的相关部分如下：

QMAKE_LFLAGS           += -Wl,-rpath-link,$$[QT_SYSROOT]/opt/vc/lib

VC_LIBRARY_PATH         = /opt/vc/lib
VC_INCLUDE_PATH         = /opt/vc/include

# terrible, they do not appear to resolve "=" in rpath!
VC_LINK_LINE            = -L=$${VC_LIBRARY_PATH} -Wl,-rpath-link,$$[QT_SYSROOT]$${VC_LIBRARY_PATH}

QMAKE_LIBDIR_OPENGL_ES2 = =$${VC_LIBRARY_PATH}
QMAKE_LIBDIR_EGL        = $$QMAKE_LIBDIR_OPENGL_ES2
QMAKE_LIBDIR_OPENVG     = $$QMAKE_LIBDIR_OPENGL_ES2

QMAKE_INCDIR_EGL        = \
                        $${VC_INCLUDE_PATH} \
                        $${VC_INCLUDE_PATH}/interface/vcos/pthreads \
                        $${VC_INCLUDE_PATH}/interface/vmcs_host/linux

QMAKE_INCDIR_OPENGL_ES2 = $${QMAKE_INCDIR_EGL}

QMAKE_LIBS_OPENGL_ES2   = $${VC_LINK_LINE} -lGLESv2

# The official opt vc EGL references GLESv2 symbols: need to link it
QMAKE_LIBS_EGL          = $${VC_LINK_LINE} -lEGL -lGLESv2

所以，我尝试了许多方法都包括在不同的地方添加$$[QT_SYSROOT]前缀，例如在VC_LIBRARY_PATH和VC_INCLUDE_PATH等位置，即使我让它找到了包含路径，它也无法链接到GLES2库（我已经验证这些库确实位于正确的位置：/mnt/pi-rootfs/opt/vc/lib）。

我想知道是否有人有解决这个问题的建议，希望不需要编辑qt mkspecs文件或进行其他类似的修改。

编辑 因此，我修改了mkspecs文件，如下所示：

QMAKE_LFLAGS           += -Wl,-rpath-link,$$[QT_SYSROOT]/opt/vc/lib

VC_LIBRARY_PATH         = $$[QT_SYSROOT]/opt/vc/lib  # prepended
VC_INCLUDE_PATH         = $$[QT_SYSROOT]/opt/vc/include #prepended

# terrible, they do not appear to resolve "=" in rpath!
VC_LINK_LINE            = -L=$${VC_LIBRARY_PATH} -Wl,-rpath-link,$$[QT_SYSROOT]$${VC_LIBRARY_PATH}

QMAKE_LIBDIR_OPENGL_ES2 = =$${VC_LIBRARY_PATH}
QMAKE_LIBDIR_EGL        = $$QMAKE_LIBDIR_OPENGL_ES2
QMAKE_LIBDIR_OPENVG     = $$QMAKE_LIBDIR_OPENGL_ES2

QMAKE_INCDIR_EGL        = \
                        $${VC_INCLUDE_PATH} \
                        $${VC_INCLUDE_PATH}/interface/vcos/pthreads \
                        $${VC_INCLUDE_PATH}/interface/vmcs_host/linux

QMAKE_INCDIR_OPENGL_ES2 = $${QMAKE_INCDIR_EGL}

#QMAKE_LIBS_OPENGL_ES2   = $${VC_LINK_LINE} -lGLESv2  #original
QMAKE_LIBS_OPENGL_ES2   = -lGLESv2  #changed

# The official opt vc EGL references GLESv2 symbols: need to link it
#QMAKE_LIBS_EGL          = $${VC_LINK_LINE} -lEGL -lGLESv2 #original
QMAKE_LIBS_EGL          = -lEGL -lGLESv2  #changed

这会导致在查找gles时出现链接错误：

> /home/osboxes/Downloads/gcc-linaro-6.3.1-2017.05-x86_64_arm-linux-gnueabihf/bin/arm-linux-gnueabihf-g++ -Wl,-rpath-link,/mnt/pi-rootfs/opt/vc/lib -Wl,-rpath-link,/mnt/pi-rootfs/usr/lib/arm-linux-gnueabihf -Wl,-rpath-link,/mnt/pi-rootfs/lib/arm-linux-gnueabihf -mfloat-abi=hard --sysroot=/mnt/pi-rootfs --sysroot=/mnt/pi-rootfs -Wl,-O1 -fuse-ld=gold -o opengles2 opengles2.o   -L=/mnt/pi-rootfs/opt/vc/lib -lGLESv2 
> /home/osboxes/Downloads/gcc-linaro-6.3.1-2017.05-x86_64_arm-linux-gnueabihf/bin/../lib/gcc/arm-linux-gnueabihf/6.3.1/../../../../arm-linux-gnueabihf/bin/ld.gold: error: cannot find -lGLESv2
> opengles2.o:opengles2.cpp:function main: error: undefined reference to 'glUniform1f'
> opengles2.o:opengles2.cpp:function main: error: undefined reference to 'glClear'
> collect2: error: ld returned 1 exit status
> Makefile:65: recipe for target 'opengles2' failed

路径-L=/mnt/pi-rootfs/opt/vc/lib是正确的，我确认这就是glesv2库所在的位置。

- Luca

---

在configure中添加$$[QT_SYSROOT]前缀并粘贴新的编译器命令。 - Luca Carlon

@LucaCarlon 看看我的更改。这是我尝试的。我已经在配置中设置了 sysroot 标志。我还需要尝试什么？你能发一个小例子吗？ - Luca

Answer 1

在Raspbian Stretch中，必须调用"rpi-update"，否则/opt/vc/lib中将缺少"libGLESv2.so"。这将修复链接器错误"cannot find -lGLESv2"。

https://www.raspberrypi.org/forums/viewtopic.php?t=191638

更新：之前提到的解决方案可能会有一些不良副作用。因此，我建议改为执行以下操作：

ln -s libbrcmEGL.so /opt/vc/lib/libEGL.so
ln -s libbrcmGLESv2.so /opt/vc/lib/libGLESv2.so
ln -s libbrcmOpenVG.so /opt/vc/lib/libOpenVG.so
ln -s libbrcmWFC.so /opt/vc/lib/libWFC.so

- zer0

---

感谢分享这个。 - Luca

花了好几个小时才弄明白发生了什么，谢谢。 - Sameer Puri

似乎又出现了错误，看起来5.10.1正在检查软件包管理器。 - tofutim

Answer 2

这是我使用的qmake.conf文件（对我有效）：

include(../common/linux_device_pre.conf)

QMAKE_LFLAGS           += -Wl,-rpath-link,$$[QT_SYSROOT]/opt/vc/lib
QMAKE_LFLAGS           += -Wl,-rpath-link,$$[QT_SYSROOT]/home/pi/qtdeps/lib

QMAKE_LIBDIR_OPENGL_ES2 = $$[QT_SYSROOT]/opt/vc/lib
QMAKE_LIBDIR_EGL        = $$QMAKE_LIBDIR_OPENGL_ES2
QMAKE_LIBDIR_OPENVG     = $$QMAKE_LIBDIR_OPENGL_ES2

QMAKE_INCDIR_EGL        = $$[QT_SYSROOT]/opt/vc/include \
                          $$[QT_SYSROOT]/opt/vc/include/interface/vcos/pthreads \
                          $$[QT_SYSROOT]/opt/vc/include/interface/vmcs_host/linux

QMAKE_INCDIR_OPENGL_ES2 = $${QMAKE_INCDIR_EGL}
QMAKE_INCDIR_OPENVG     = $${QMAKE_INCDIR_EGL}

QMAKE_LIBS_EGL          = -lEGL -lGLESv2
QMAKE_LIBS_OPENVG       = -lEGL -lOpenVG -lGLESv2

QMAKE_CFLAGS            = -march=armv8-a -mtune=cortex-a53 -mfpu=crypto-neon-fp-armv8
QMAKE_CXXFLAGS          = $$QMAKE_CFLAGS

DISTRO_OPTS            += hard-float
DISTRO_OPTS            += deb-multi-arch

# Preferred eglfs backend
EGLFS_DEVICE_INTEGRATION= eglfs_brcm

include(../common/linux_arm_device_post.conf)

load(qt_config)

- Luca Carlon

Answer 3

我的起点是2017-11-29-raspbian-stretch，我使用crosstool-ng在OSX上构建了我的工具链。

尽管sudo rpi-update有所帮助并引入了'libGLESv2.so'，但对于我来说它并没有解决问题。问题实际上出现在QT配置中。QT使用gcc -dumpmachine来建立元组。对我来说，它是'arm-raspbian-linux-gnueabihf'。QT最终在像/usr/lib/arm-raspbian-linux-gnueabihf这样的位置搜索库和包，但这些位置并不存在。(当使用GLESv2编译时，它无法找到类似'libpthread.so'这样的库)。相反，如果您查看操作系统，正确的位置是/usr/lib/arm-linux-gnueabihf。解决方案是修改qtbase中的configure.pri。

--- a/configure.pri
+++ b/configure.pri
@@ -241,7 +241,7 @@ defineReplace(qtConfFunc_licenseCheck) {

 # this is meant for linux device specs only
 defineTest(qtConfTest_machineTuple) {
-    qtRunLoggedCommand("$$QMAKE_CXX -dumpmachine", $${1}.tuple)|return(false)
+    qtRunLoggedCommand("$$QMAKE_CXX -dumpmachine | sed 's/-raspbian//'", $${1}.tuple)|return(false)
     $${1}.cache += tuple
     export($${1}.cache)
     return(true)

这将把元组从crosstool-ng更改为三元组。

更新。 如果您正在使用crosstool-ng，与此“修复”相比的另一种选择是使用CT_TARGET=arm-linux-gnueabihf（而不是CT_TARGET_ALIAS）。

- tofutim