VBScript - 捕获stdout输出

Question

VBScript - 捕获stdout输出

3

我知道这个问题在另一个问题中已经得到了回答，但是我根本不明白该如何操作。

我试图将命令行程序（Aria2下载器）的输出结果放入HTA脚本中，以便可以动态地解析下载百分比、文件大小等内容，并将其更新到DIV中。

以下是我调整过并一直在尝试使用的代码，但它只会在命令行完成之前锁定界面，然后显示所有的输出结果，而不是实时地显示它们。

Const WshRunning = 0
Const WshFinished = 1
Const WshFailed = 2
strCommand = "ping.exe 127.0.0.1"

Set WshShell = CreateObject("WScript.Shell")
Set WshShellExec = WshShell.Exec(strCommand)

Do While WshShellExec.Status = WshRunning
    window.setTimeOut "", 100
Loop

Select Case WshShellExec.Status
    Case WshFinished
        strOutput = WshShellExec.StdOut.ReadAll()
    Case WshFailed
        strOutput = WshShellExec.StdErr.ReadAll()
End Select

Set objItem = Document.GetElementByID("status")
    objItem.InnerHTML = "" & strOutput & ""

如何修改代码以避免锁定用户界面，并在输出流传入时将其捕获并显示在“状态”div中？

- Ctrlaltdenied

“Const WshFailed = 2” 的基础是什么？MS文档中没有提供这样的状态码。https://msdn.microsoft.com/en-us/subscriptions/443b45a5(v=vs.84).aspx - ChrisJJ

1个回答

网页内容由stack overflow 提供, 点击上面的

可以查看英文原文，
原文链接

- MC ND · Accepted Answer

问题在于您的代码没有结束，也没有将控制权交还给浏览器。直到程序结束，循环才会停止，所以用户的感受是界面一直卡住直到子进程结束。

您需要设置一个回调函数，这样浏览器会定期调用您的代码，您就可以更新状态并结束循环。

<html>
<head>
    <title>pingTest</title>
    <HTA:APPLICATION
        APPLICATIONNAME="pingTest"
        ID="pingTest"
        VERSION="1.0"
    />
</head>

<script language="VBScript">
    Const WshRunning = 0
    Const WshFinished = 1
    Const WshFailed = 2

    Dim WshShellExec, Interval

    Sub Window_onLoad
        LaunchProcess
    End Sub

    Sub LaunchProcess
        Set WshShellExec = CreateObject("WScript.Shell").Exec("ping -n 10 127.0.0.1")
        Interval = window.setInterval(GetRef("UpdateStatus"),500)
    End Sub    

    Sub UpdateStatus
    Dim status 
        Set status = Document.GetElementByID("status")
        Select Case WshShellExec.Status
            Case WshRunning
                status.InnerHTML = status.InnerHTML & "<br>" & WshShellExec.StdOut.ReadLine()
            Case WshFinished, WshFailed
                status.InnerHTML = status.InnerHTML & "<br>" & Replace(WshShellExec.StdOut.ReadAll(),vbCRLF,"<br>")
                window.clearInterval(Interval)
                Interval = Empty
        End Select
    End Sub
</script>

<body>
    <div id="status"></div>
</body>
</html>