F#引用表达式列表 -> 表达式处理

Question

我该如何让以下内容生效？

我需要编写一个函数，它可以接受一个 Expr 列表，并返回一个 Expr （Expr 列表-> Epxr）。

type DataObject() =
    let data = System.Collections.Generic.Dictionary<int, obj>()
    member this.AddValue propertyIndex value = data.Add(propertyIndex, value)
    member this.GetValue propertyIndex = 
        match data.TryGetValue propertyIndex with
        | (true, value) -> value
        | (false, _)    -> box "property not found"

...
(fun args -> 
    <@@ 
        let data = new DataObject(values)
        args |> List.iteri (fun i arg -> data.AddValue i <@@ (%%arg) : string @@>)
        data 
    @@>)

我创建了DataObject类型来添加args的值。但是我无法管理代码迭代通过不同的args（args.[0]..args.[i]）。我得到的消息是：

“变量“arg”在引用中被绑定，但被用作一个加入表达式的一部分。这是不允许的，因为它可能逃脱其范围。”

如果我明确访问args（args.[0]，args.[1]，...），解决方案就可以工作，但只要我尝试添加迭代，我就会遇到问题。由于args列表的长度是灵活的，所以对我来说这不是可行的解决方案。

我尝试了不同的方法，但都没有成功。有什么解决办法吗？

【编辑】

将Tomas的反馈添加到我的解决方案中，我得到了这个结果：

type DataObject(values: obj []) =
    let propertyMap = new Map<int, obj>(values |> Seq.mapi (fun i value -> (i, value)))
    member this.GetValue propertyIndex : obj = 
        match propertyMap.TryFind propertyIndex with
        | Some(value) -> value
        | None        -> box "property not found"

(fun args ->  
    let boxedArgs = 
        args |> List.map (fun arg -> 
            match arg with
            | Quotations.Patterns.Var var -> 
                if var.Type = typeof<int> then 
                    <@@ (box (%%arg: int)) @@>
                else if var.Type = typeof<string> then 
                    <@@ (box (%%arg: string)) @@>
                else if var.Type = typeof<System.Guid> then 
                    <@@ (box (%%arg: System.Guid)) @@>
                else 
                    failwith ("Aha: " + var.Type.ToString())
            | _ -> failwith ("Unknown Expr as parameter"))
        <@@ new DataObject(%%(Expr.NewArray(typeof<obj>, boxedArgs))) @@>))

这很有效！唯一的问题是我想摆脱if...else结构来得到正确的转换。有什么想法吗？

- BBL

---

关于编辑，我认为你可以用 Expr.Coerce(arg, typeof<obj>) 替换 if - 这应该会给你一个表示任何其他表达式 arg 装箱的表达式。 - Tomas Petricek

Answer 1

这是一个棘手的问题！要理解为什么您的代码不起作用，需要清楚地区分两个层次-在一个层次（元），您正在组成引用，在另一个层次（基础）中，您正在使用数据对象运行一些代码。

您的代码之所以无法工作，是因为args是元级别的表达式列表，您正试图在基本级别上对其进行迭代。迭代需要在元级别上发生。

解决这个问题的一种方法是在元级别上进行迭代，并生成调用所有参数的AddValue的函数列表。然后您可以组成这些函数：

(fun args -> 
    // Given arguments [a0; a1; ...] Generate a list of functions:
    //
    //   [ fun data -> data.AddValue 0 a0; data ]
    //   [ fun data -> data.AddValue 1 a1; data ... ]
    args 
    |> List.mapi (fun i arg -> 
      <@ fun (data:DataObject) -> data.AddValue i (%%arg : string); data @>)

    // Compose all the functions just by calling them - note that the above functions 
    // take DataObject, mutate it and then return it. Given [f0; f1; ...] produce:
    //
    //    ... (f1 (f0 (new DataObject())))
    //
    |> List.fold (fun dobj fe -> <@ (%fe) (%dobj) @>) <@ new DataObject() @> )

写这个很有趣，但它变得非常复杂。实际上，您可以通过向数据对象添加AddValues方法（使用obj []）并使用Expr.NewArray创建一个包含所有参数值的单个数组（在基本级别）来简化事情：

<@@ let d = new DataObject()
    d.AddValues(%(Expr.NewArray(typeof<obj>, args)))
    d @@>

- Tomas Petricek

---

嗨Tomas。感谢您的输入，它让我向前迈进了几步。我已经编辑了问题，并提供了解决方案。您是否也有一些if..then构造的想法？（请参见问题中的编辑） - BBL