在Delphi中为TSomething设置默认参数值

Question

我想知道在Delphi中是否可以实现这一点（或者是否有更好的方法绕过它）：

type
 TSomething = record
  X, Y : Integer;
 end;

GetSomething(x,y) -> 返回包含这些值的记录。

... 然后你有一个以 TSomething 为参数的函数，并且你想将其设置为默认值。

function Foo( Something : TSomething = GetSomething( 1, 3 );

编译器在这里报错，但我不确定是否有解决方法！这可行吗？

- deluvas

Answer 1

使用重载：

procedure Foo(const ASomething: TSomething); overload;
begin
  // do something with ASomething
end;

procedure Foo; overload;
begin
  Foo(GetSomething(1, 3));
end;

- Uli Gerhardt

Answer 2

最简单的方法是使用重载过程：

program TestOverloading;

{$APPTYPE CONSOLE}

uses
  SysUtils;

type
  TSomething = record
    X,Y : integer;
  end;

const
  cDefaultSomething : TSomething = (X:100; Y:200);

procedure Foo(aSomething : TSomething); overload;
begin
  writeln('X:',aSomething.X);
  writeln('Y:',aSomething.Y);
end;

procedure Foo; overload;
begin
  Foo(cDefaultSomething);
end;

begin
  Foo;
  readln;
end.

- Svein Bringsli

Answer 3

使用类而不是记录，像这样做就可以了：

使用类而不是记录，像这样做就可以了：

TSomething = class
public 
  X: integer;
  Y: integer
end;

procedure Foo(Something: TSomething = nil);
begin
  if (Something = nil) then
    Something := GetSomething(1, 3);
  ...
end;

- splash

---

为了避免一些RTTI开销，X和Y可以声明为“public”，而不是隐式的“published”。 - mjn

感谢 @mjustin 指出这一点。我的隐含假设是，控制生成 RTTI 的指令已设置为默认值：{$M-}。;-) - splash

Answer 4

如果你使用指针而不是记录类型，你可以将nil作为默认值:

type
  TSomething = record
    X, Y : Integer;
  end;

  PSomething = ^TSomething;

function Foo(Something: PSomething = nil);

实际上，将指针作为参数传递通常更快，因为它避免了复制内存块。

- Rafael Piccolo