如何使用批处理文件双击安装APK文件

Question

我想编写一个批处理文件，帮助我在双击任何apk文件时安装apk文件。

例如，当我单击apk文件时，myBatchFile.bat将执行。

myBatchFile.bat应该包含什么内容？

adb install what?

谢谢

- Simon

---

你的 APK 文件路径怎么样？ - petey

我不知道如何在批处理文件中接收所点击文件的地址。 - Simon

我认为你想要一个批处理脚本的水滴行为。这个链接应该会有所帮助：https://dev59.com/aV7Va4cB1Zd3GeqPJWek - petey

Answer 1

首先备份 HKEY_CURRENT_USER\SOFTWARE\Classes 注册表。这样，如果在测试 .bat 文件时出现问题，您可以恢复设置。

您需要安装 .apk 文件的 shell 处理程序。处理程序是一个 .bat 文件，称为 MyApkInstaller.bat。当您在 Windows Explorer 中双击一个 .apk 文件时，处理程序 MyApkInstaller.bat 将运行，并将 .apk 文件名传递给处理程序。

@echo off

echo Installing %1...
adb install %1 && echo Done || echo Failed
pause

安装/卸载处理程序到Windows注册表的脚本。

@echo off
setlocal

set _progId=MyApkInstaller
set _handler=MyApkInstaller.bat

if not "%1"=="" goto uninstall

:install
echo Installing...
reg add HKCU\Software\Classes\.apk\OpenWithProgIds /v %_progId% /t REG_SZ /f
reg add HKCU\Software\Classes\%_progId%\Shell\Open\Command /ve /t REG_SZ /d "%~dp0%_handler% ""%%1""" /f
goto finish

:uninstall
echo Uninstalling...
reg delete HKCU\Software\Classes\.apk
reg delete HKCU\Software\Classes\%_progId%

:finish
endlocal

- Dmitry Sokolov

Answer 2

你可以将这些写入你的xxx.bat文件中。

@echo %1

adb install -r %1

pause

设置环境变量是必要的，通过选择xxx.bat的方式打开xxxx.apk

- Arvin yang

Answer 3

< p> adb 可以按以下方式在模拟器上安装*.apk：

adb install PATH

所以，您可以简单地创建一个像这样的批处理文件：

@echo off

echo installing your application...
adb install %1

保存后，选择此批处理文件作为*.apk文件的默认应用程序。（在资源管理器中找到apk文件 > 右键单击 > 属性 > 更改 > YOUR_BATCH_FILE）

- Mehdi Khademloo