通过XSL访问多个XML文件

Question

通过XSL访问多个XML文件

3

我目前正在尝试访问多个XML文件中的数据。我已经轻松地从第一个名为Rainfall.xml的文件中访问了数据，但是无法从我的列表中的下一个文件Max_temp.xml检索任何数据。

总体目标是将4-5个XML文件合并在一起，包括有关各种天气事件以及记录这些事件的站点的所有数据。

以下是示例代码：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output method="xml"/>

    <!-- TODO customize transformation rules 
         syntax recommendation http://www.w3.org/TR/xslt 
    -->
<xsl:variable name="maxTemp" select="document('Max_temp.xml')" />  

<xsl:template match="rainfall">
&lt;weather&gt;
      <xsl:apply-templates select="measurement" />
&lt;/weather&gt;

</xsl:template>


<xsl:template match="measurement">
    &lt;measurement&gt;
        &lt;StationNum&gt;<xsl:value-of select="StationNum"/>&lt;/StationNum&gt;
        &lt;Date&gt;<xsl:value-of select="concat(Day,'/',Month,'/',Year)"/>&lt;/Date&gt;
        <xsl:variable name="Date" select="concat(Day,'/',Month'/',Year)"/>
        &lt;Rainfall&gt;<xsl:value-of select="Volume"/>&lt;/Rainfall&gt;
        &lt;MaxTemp&gt;<xsl:value-of select="$MaxTemp/maxTemp/measurement[concat(Day,'/',Month'/',Year)].equals(Date)"/>&lt;/MaxTemp&gt;
    &lt;/measurement&gt;
</xsl:template>

</xsl:stylesheet>

正在使用的XML文件的结构如下所示：

<typeOfFile(Rainfall, Temp, Solar Radiation etc)>
    <measurment>
        <Code>...</Code>
        <Station>...</Station>
        <Day>...</Day>
        <Month>...</Month>
        <Year>...</Year>
        <Volume>...</Volume>
    </measurement>
</typeOfFile>

当我尝试加载相应的Rainfall.xml文件并使用此XSL样式表进行格式化时，浏览器没有响应。

请问有人能指点我正确的方向吗？如果有人能提供关于如何使用XSL样式表创建和格式化XML文件的信息，将不胜感激。

- Rory Perry

<weather>、<measurement>等标签的目的是什么？输出标签吗？更多使用变量 $MaxTemp，但你声明的是 maxTemp - XSLT是大小写敏感的。 - potame

1个回答

网页内容由stack overflow 提供, 点击上面的

可以查看英文原文，
原文链接

- Tomalak · Accepted Answer

以下方法可行（XSLT 1.0）：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output method="xml"/>

    <!-- select the <measurement> elements of all the various input files -->
    <xsl:variable name="maxTemp" select="document('Max_temp.xml')/*" />
    <xsl:variable name="rainfall" select="document('rainfall.xml')/*" />
    <xsl:variable name="solarRadiation" select="document('solar_radiation.xml')/*" />

    <!-- index <measurement> elements by their station and date -->
    <xsl:key name="kMeasurement" match="measurement"
        use="concat(Station, '/', Day, '/', Month, '/', Year)"
    />

    <xsl:template match="/">
        <weather>
            <xsl:apply-templates select="$maxTemp/measurement" />
        </weather>
    </xsl:template>

    <xsl:template match="measurement">
        <xsl:variable name="currentKey" select="concat(Station, '/', Day, '/', Month, '/', Year)" />

        <measurement>
            <StationNum><xsl:value-of select="Station"/></StationNum>
            <Date><xsl:value-of select="concat(Day, '/', Month, '/', Year)"/></Date>

            <!-- since we are handling maxTemp measurements here, we can output that directly -->
            <MaxTemp><xsl:value-of select="Value"/></MaxTemp>

            <!-- to access the others we need a context switch and a key lookup -->
            <xsl:for-each select="$rainfall">
                <Rainfall><xsl:value-of select="key('kMeasurement', $currentKey)/Volume"/></Rainfall>
            </xsl:for-each>
            <xsl:for-each select="$solarRadiation">
                <SolarRadiation><xsl:value-of select="key('kMeasurement', $currentKey)/Watt"/></SolarRadiation>
            </xsl:for-each>
            <!-- and so on -->
        </measurement>
    </xsl:template>
</xsl:stylesheet>

您需要将其应用于一个空的虚拟输入文档（类似于简单的<xml />）。

然后，它会将所有实际文件加载到变量中，并按照其中一个文件中的条目创建输出。我选择了最高温度测量值，但是如果所有文件都包含相同日期的数据点，则不会有任何影响。

这些最高温度数据点中的每一个都会生成一个输出<measurement>元素。

为此，它使用<xsl:key>从相关文档中提取正确的测量值。 <xsl:key>是一个键/值存储（即字典，哈希表）：它通过某个关键字符串对节点进行索引，在我们的情况下是站点ID和日期的组合。

但是，它仅返回与当前节点位于同一文档中的节点。因此，要输出Max_temp.xml之外的任何内容，我们必须将上下文切换到另一个文档。 <xsl:for-each>可以做到这一点，因此我们在这里使用它来设置我们调用key()的范围（$rainfall 和 $solarRadiation只持有单个元素）。

请注意，由于我必须猜测您的实际输入文档结构，因此一些XPath可能不准确。请相应地进行调整。