logo标签列表

使用查询参数生成URL

urlhaskellyesodquery-string
3

无法找到一个简单问题的解决方案，答案应该很明显。如何在 Hamlet 模板中呈现带有查询参数的 URL？

例如，@{ItemsR} 会生成 http://localhost:3000/items ，那么我该如何生成类似于 http://localhost:3000/items?page=10&sort=name 的 URL 呢？

ItemsR 应该有一些参数，请尝试使用 @{ItemsR 10 "name"}。 - josejuan
如果我理解正确的话，处理程序参数来自路径段。 - lambdas
是的，如果您希望使用“传统参数”，您可以直接在模板上呈现您的URL（例如<a href=@{ItemsR}?page=^{pageNumber}&...）。但是路由更好（类型安全）。 - josejuan
那么没有办法做类似 @{ItemsR [("page", "10"), ("sort", "name")]} 这样的事情吗？ - lambdas
1个回答
2

Yesod是RESTful的，如果你想使用QueryString格式，则应该使用url格式参数（例如/items/page/10/sortby/name），否则你将失去Yesod类型安全的url管理。

以下示例展示了如何使用不同的RESTful表示形式以及重定向（呈现一个查询字符串url）到从查询字符串读取参数的请求。

{-# LANGUAGE QuasiQuotes #-}
{-# LANGUAGE TypeFamilies #-}
{-# LANGUAGE TemplateHaskell #-}
{-# LANGUAGE OverloadedStrings #-}
{-# LANGUAGE MultiParamTypeClasses #-}
import Yesod
import Data.Text
import Network.Wai.Handler.Warp (run)

data RouteTest = RouteTest

mkYesod "RouteTest" [parseRoutes|
/item/all/page/#Int/sortby/#Text Items1R GET
/items/page/#Int/sortby/#Text Items2R GET
/items/#Int/#Text Items3R GET
/itemsquery ItemsQueryR GET
|]

instance Yesod RouteTest where
    defaultLayout widget = do
        pc <- widgetToPageContent widget
        hamletToRepHtml [hamlet|\<!DOCTYPE html><html lang="en"><body>^{pageBody pc}</body></html>|]

getItemsR :: Text -> Int -> Text -> HandlerT RouteTest IO Html
getItemsR path page sortby =
  defaultLayout [whamlet|
    <h1>Items Page ##{page} sorted by #{sortby}
    <h4>(Using #{path} path format)
    <p>Same request in query string format
      <a href="@{ItemsQueryR}?page=#{page}&sort=#{sortby}">
        here
  |]

getItems1R = getItemsR $ pack "large"
getItems2R = getItemsR $ pack "medium"
getItems3R = getItemsR $ pack "short"

getItemsQueryR = do
  req <- getRequest
  defaultLayout [whamlet|
    <h1>Query String arguments format
    <ul>
      $forall (k, v) <- reqGetParams req
        <li>
          <b>#{k}</b>: #{v}
  |]

main = run 8181 =<< toWaiApp RouteTest

当然，您可以编写一个辅助程序来处理类似于@{ItemsR page sortby}这样的内容。
renderItemsQueryR page sortby = hamletToRepHtml [hamlet|@{ItemsQueryR}?page=#{page}&sort=#{sortby}|]

但你必须使用如下方式

...
url <- renderItemsQueryR page sortby
defaultLayout [whamlet|
    ...
    <a href=#{url}>
    ...
|]

最后，您可以编写其他帮助程序来呈现任何查询字符串URL。

renderQueryString path keyValues = do
  let querystring = intercalate "&" $ map (\(k, v) -> concat [k, "=", v]) keyValues
  hamletToRepHtml [hamlet|@{path}?#{querystring}|]

那么，renderItemsQueryR 可以写成这样：
renderItemsQueryR page sortby = renderQueryString ItemsQueryR [("page"  , show page)
                                                              ,("sortby", sortby   )]
网页内容由stack overflow 提供, 点击上面的
可以查看英文原文，
原文链接