logo标签列表

逗号分隔字符串解析XSLT到for-each节点

xslt
16

我有一个包含csv值的输入字符串。例如，1,2,3。 我需要将每个值分隔并在for-each循环中分配到目标节点。

我得到了下面这个模板，它可以根据分隔符拆分输入字符串。如何将每个分隔的值分配给for-each循环中的目标元素。

<xsl:template name="output-tokens">
<xsl:param name="list"/>
<xsl:param name="delimiter"/>
<xsl:variable name="newlist">
  <xsl:choose>
    <xsl:when test="contains($list, $delimiter)">
      <xsl:value-of select="normalize-space($list)"/>
    </xsl:when>
    <xsl:otherwise>
      <xsl:value-of select="concat(normalize-space($list), $delimiter)"/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:variable>
<xsl:variable name="first" select="substring-before($newlist, $delimiter)"/>
<xsl:variable name="remaining"
              select="substring-after($newlist, $delimiter)"/>
<xsl:variable name="count" select="position()"/>
<num>
  <xsl:value-of select="$first"/>
</num>
<xsl:if test="$remaining">
  <xsl:call-template name="output-tokens">
    <xsl:with-param name="list" select="$remaining"/>
    <xsl:with-param name="delimiter">
      <xsl:value-of select="$delimiter"/>
    </xsl:with-param>
  </xsl:call-template>
</xsl:if>
</xsl:template>

输入的 XML：

<out1:AvailableDates>
<out1:AvailableDate>15/12/2011,16/12/2011,19/12/2011,20/12/2011,21/12/2011</out1:AvailableDate>
</out1:AvailableDates>

期望输出：

<tns:AvailableDates>
<tns:AvailableDate>15/12/2011</tns:AvailableDate>
<tns:AvailableDate>16/12/2011</tns:AvailableDate>
<tns:AvailableDate>120/12/2011</tns:AvailableDate>
</tns:AvailableDates>
3个回答
21

这是一个完整而简短、真实的XSLT 1.0解决方案:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:out1="undefined" xmlns:tns="tns:tns"
  exclude-result-prefixes="out1 tns">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="out1:AvailableDate">
  <tns:AvailableDates>
    <xsl:apply-templates/>
  </tns:AvailableDates>
 </xsl:template>

 <xsl:template match="text()" name="split">
  <xsl:param name="pText" select="."/>
  <xsl:param name="pItemElementName" select="'tns:AvailableDate'"/>
  <xsl:param name="pItemElementNamespace" select="'tns:tns'"/>

    <xsl:if test="string-length($pText) > 0">
     <xsl:variable name="vNextItem" select=
      "substring-before(concat($pText, ','), ',')"/>

      <xsl:element name="{$pItemElementName}"
                   namespace="{$pItemElementNamespace}">
       <xsl:value-of select="$vNextItem"/>
      </xsl:element>

      <xsl:call-template name="split">
        <xsl:with-param name="pText" select=
                       "substring-after($pText, ',')"/>
        <xsl:with-param name="pItemElementName" select="$pItemElementName"/>
        <xsl:with-param name="pItemElementNamespace" select="$pItemElementNamespace"/>
      </xsl:call-template>
    </xsl:if>
 </xsl:template>
</xsl:stylesheet>

当应用于提供的XML文档时（已更正为成为well-formed）：

<out1:AvailableDates xmlns:out1="undefined">
    <out1:AvailableDate>15/12/2011,16/12/2011,19/12/2011,20/12/2011,21/12/2011</out1:AvailableDate>
</out1:AvailableDates>

产生了所需的、正确的结果:

<tns:AvailableDates xmlns:tns="tns:tns">
   <tns:AvailableDate>15/12/2011</tns:AvailableDate>
   <tns:AvailableDate>16/12/2011</tns:AvailableDate>
   <tns:AvailableDate>19/12/2011</tns:AvailableDate>
   <tns:AvailableDate>20/12/2011</tns:AvailableDate>
   <tns:AvailableDate>21/12/2011</tns:AvailableDate>
</tns:AvailableDates>
@Arun：很高兴我的回答对您有用。您能否请将答案标记为已接受（点击答案旁边的复选标志）？这是在SO表达感激之情的官方方式。 - Dimitre Novatchev
当然。在我的XSL中，我收到了这个消息：<xsl:template match="/">和<xsl:template name="...">是XSL中唯一允许的<template>元素。当我使用<xsl:template match="/out1:Response/out1:AvailableDates/out1:AvailableDate">时，就会出现这种情况。 - Arun
@Arun：这条信息意味着在你的 xsl:template 指令中，你使用了一个除 match 或 name 之外的属性。找到你使用的其他属性并将其删除。 - Dimitre Novatchev
11

使用XSLT 2.0，您可以使用tokenize(string, separator)函数代替命名模板。

以下是示例xsl代码：

<xsl:stylesheet version="2.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:tns="http://tnsnamespace">

    <xsl:template match="AvailableDate">
        <tns:AvailableDates>
            <xsl:for-each select="tokenize(current(), ',')">
                <tns:AvailableDate>
                    <xsl:value-of select="."/>
                </tns:AvailableDate>
            </xsl:for-each>
        </tns:AvailableDates>
    </xsl:template>
</xsl:stylesheet>

得到以下结果：

<?xml version="1.0" encoding="UTF-8"?>
<tns:AvailableDates xmlns:tns="http://tnsnamespace">
    <tns:AvailableDate>15/12/2011</tns:AvailableDate>
    <tns:AvailableDate>16/12/2011</tns:AvailableDate>
    <tns:AvailableDate>19/12/2011</tns:AvailableDate>
    <tns:AvailableDate>20/12/2011</tns:AvailableDate>
    <tns:AvailableDate>21/12/2011</tns:AvailableDate>
</tns:AvailableDates>

更新:

使用Xslt 2.0处理器的向后兼容模式，以下模板将给出相同的结果：

<xsl:template match="AvailableDate">
    <tns:AvailableDates>
        <xsl:variable name="myValue">
            <xsl:call-template name="output-tokens">
                <xsl:with-param name="list" select="."/>
                <xsl:with-param name="delimiter" select="','"/>
            </xsl:call-template>
        </xsl:variable>

        <xsl:for-each select="$myValue/node()">
            <tns:AvailableDate>
                <xsl:value-of select="."/>
            </tns:AvailableDate>
        </xsl:for-each>
    </tns:AvailableDates>
</xsl:template>

对于Xslt 1.0，使用标准函数无法简单地访问通过变量传递的节点 - 参见@Dimitre Novatchev的答案：XSLT 1.0 - 创建节点集并将其作为参数传递

为此，XSLT 1.0处理器包含扩展函数：node-set(...)

对于Saxon 6.5，node-set()函数定义在http://icl.com/saxon命名空间中。

因此，在XSLT 1.0处理器的情况下，解决方案是：

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:exslt="http://exslt.org/common"
    xmlns:out1="http://out1namespace"
    xmlns:tns="http://tnsnamespace"
    exclude-result-prefixes="out1 exslt">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="out1:AvailableDate">
        <tns:AvailableDates>
            <xsl:variable name="myValue">
                <xsl:call-template name="output-tokens">
                    <xsl:with-param name="list" select="."/>
                    <xsl:with-param name="delimiter" select="','"/>
                </xsl:call-template>
            </xsl:variable>
            <xsl:for-each select="exslt:node-set($myValue)/node()">
                <tns:AvailableDate>
                    <xsl:value-of select="."/>
                </tns:AvailableDate>
            </xsl:for-each>
        </tns:AvailableDates>
    </xsl:template>

    <xsl:template name="output-tokens">
        <xsl:param name="list"/>
        <xsl:param name="delimiter"/>
        <xsl:variable name="newlist">
            <xsl:choose>
                <xsl:when test="contains($list, $delimiter)">
                    <xsl:value-of select="normalize-space($list)"/>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:value-of select="concat(normalize-space($list), $delimiter)"/>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:variable>
        <xsl:variable name="first" select="substring-before($newlist, $delimiter)"/>
        <xsl:variable name="remaining"
            select="substring-after($newlist, $delimiter)"/>
        <xsl:variable name="count" select="position()"/>
        <num>
            <xsl:value-of select="$first"/>
        </num>
        <xsl:if test="$remaining">
            <xsl:call-template name="output-tokens">
                <xsl:with-param name="list" select="$remaining"/>
                <xsl:with-param name="delimiter">
                    <xsl:value-of select="$delimiter"/>
                </xsl:with-param>
            </xsl:call-template>
        </xsl:if>
    </xsl:template>

</xsl:stylesheet>

感谢 @Dimitre Novatchev 纠正我并提供了有关从变量中访问节点集的答案。

非常感谢。我正在使用BPEL 10g。它具有XSLT版本1.0。它可以做什么？ - Arun
我已经更新了关于Xslt-1.0的答案 - 它使用了你的output-tokens命名模板。 - Vitaliy
@Vitaliy：请使用任何符合XSLT 1.0标准的处理器运行您的XSLT 1.0解决方案，并查看是否会产生错误。在XSLT 1.0中，对RTF（结果树片段）允许执行的操作非常有限。请进行更正。 - Dimitre Novatchev
@Dimitre Novatchev - 是的，我看到它不适用于Saxon 6.5.5（只有在我添加version="1.1"时才有效），但在向后兼容模式下，它适用于Saxon 9.3。 - Vitaliy
@Dimitre Novatchev - 使用node-set()扩展函数进行修复 - Vitaliy
@Vitaliy：很好。如果您编辑并使用EXSLT命名空间（它被大部分现有的XSLT 1.0处理器支持），而不是专有的Saxon命名空间，我将为此答案投赞成票。 - Dimitre Novatchev
0

就我个人而言，我更喜欢基于自定义扩展函数的这种变体。该方法紧凑、干净，并且在XSLT 1.0中运行良好（至少在任何最近的JVM中嵌入了XALAN 2.7）。

1）声明一个带有静态方法的类，返回org.w3c.dom.Node

package com.reverseXSL.util;

import org.w3c.dom.*;
import java.util.regex.*;
import javax.xml.parsers.DocumentBuilderFactory;

public class XslTools {

  public static Node splitToNodes(String input, String regex) throws Exception {
    Document doc = DocumentBuilderFactory.newInstance().newDocumentBuilder().newDocument();
    Element item, list = doc.createElement("List");
    Pattern p = Pattern.compile(regex);
    Matcher m = p.matcher(input);
    while (m.find()) {
      item = doc.createElement("Item");
      StringBuffer sb = new StringBuffer();
      for (int i=1; i<=m.groupCount(); ++i) if (m.start(i)>=0) sb.append(m.group(i));
      Text txt = doc.createTextNode(sb.toString());
      item.appendChild(txt);
      list.appendChild(item);
    }
    return list; 
  }

}

此函数基于正则表达式模式拆分输入字符串，并创建一个文档片段，其格式为<list><Item>A</Item><Item>B</Item><Item>C</Item></List>。 正则表达式按顺序匹配，每次匹配都会产生一个Item元素，其值由每个正则表达式匹配中的捕获组（有些可能为空）组成。这样可以摆脱分隔符和其他语法字符。

例如，要拆分逗号分隔的列表，如" A, B ,, C"，跳过空值并修剪额外的空格（因此获取上述节点列表），请使用类似于'\s*([^,]+?)\s*(?:,|$)'的正则表达式 - 令人费解！如果您想通过固定大小（这里为10个字符）拆分输入文本，并使最后一个Item获取剩余部分，请使用类似于'(.{10}|.+)'的正则表达式 - 真棒！

然后，您可以在XSLT 1.0中使用该函数（非常紧凑！）：

<xsl:stylesheet version="1.0" xmlns:var="com.reverseXSL.util.XslTools" extension-element-prefixes="var" ...
...
<xsl:template ...
  ...
  <xsl:for-each select="var:splitToNodes(Detail/CsvText,'\s*([^,]+?)\s*(?:,|$)')/Item">
    <Loop><xsl:value-of select="."/></Loop>
  </xsl:for-each>
...

在模板匹配上执行，产生输入片段<Detail><CsvText>a, b ,c </CsvText></Detail>，您将生成<Loop>a</Loop><Loop>b</Loop><Loop>c</Loop>

诀窍是不要忘记按照XPath "/Item"（或 "/*"）生成节点/项的函数调用，正如您所注意到的那样，这样一个节点序列就会返回到for-each循环中。

1
如果你正在使用Xalan，那么你可以使用EXSLT str:tokenize() 扩展函数，Xalan支持该函数，而不必编写自己的函数。但是，XSLT 1.0并不一定意味着你正在使用Xalan或Java。 - michael.hor257k
网页内容由stack overflow 提供, 点击上面的
可以查看英文原文，
原文链接