Yocto Bitbake 配方: 如何覆盖 do_install() 和 do_install_append() 函数

Question

我尝试将开源的 "procps" 包添加到我的工作 Yocto 编译中。该软件包安装了一堆二进制文件，替换了 BusyBox 提供的文件。 我只需要其中一个二进制文件- pgrep。

在我的层中，我创建了一个名为 "procps_%bbappend" 的 bbappend 文件。构建时它被捕获并编译成功，但是在安装时失败了。错误信息似乎表明未完全覆盖 do_install() 和 do_install_append() 钩子。

我该如何更改我的 bitbake bbappend 文件，以仅安装 "procps" 包中的 pgrep 实用程序而不安装其他标准安装？

这里是我失败的bbappend文件：

do_install () {
    install -d ${D}${base_bindir}
    mv ${D}/../build/pgrep ${D}/bin/pgrep
}

do_install_append () {
    install -d ${D}${base_bindir}
    mv ${D}/../build/pgrep ${D}/bin/pgrep
}

bindir_progs = ""
base_bindir_progs = ""
base_sbindir_progs = ""

这里是完整的"procps" bitbake配方：

SUMMARY = "System and process monitoring utilities"
DESCRIPTION = "Procps contains a set of system utilities that provide system information about processes using \
the /proc filesystem. The package includes the programs ps, top, vmstat, w, kill, and skill."
HOMEPAGE = "https://gitorious.org/procps"
SECTION = "base"
LICENSE = "GPLv2+ & LGPLv2+"
LIC_FILES_CHKSUM="file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
                  file://COPYING.LIB;md5=4cf66a4984120007c9881cc871cf49db \
                 "

DEPENDS = "ncurses"

inherit autotools gettext pkgconfig update-alternatives

SRC_URI = "http://downloads.sourceforge.net/project/procps-ng/Production/procps-ng-${PV}.tar.xz \
           file://sysctl.conf \
          "

SRC_URI[md5sum] = "6cc5b94c1c5b8cbc89ad345a7b522f74"
SRC_URI[sha256sum] = "e9493169a2d2adc0bc045538707310c8e877b385e4e296143b62607d2bb044ed"

S = "${WORKDIR}/procps-ng-${PV}"

EXTRA_OECONF = "--enable-skill --disable-modern-top"

CPPFLAGS += "-I${S}"

do_install_append () {
    install -d ${D}${base_bindir}
    [ "${bindir}" != "${base_bindir}" ] && for i in ${base_bindir_progs}; do mv ${D}${bindir}/$i ${D}${base_bindir}/$i; done
    install -d ${D}${base_sbindir}
    [ "${sbindir}" != "${base_sbindir}" ] && for i in ${base_sbindir_progs}; do mv ${D}${sbindir}/$i ${D}${base_sbindir}/$i; done
        if [ "${base_sbindir}" != "${sbindir}" ]; then
                rmdir ${D}${sbindir}
        fi

        install -d ${D}${sysconfdir}
        install -m 0644 ${WORKDIR}/sysctl.conf ${D}${sysconfdir}/sysctl.conf
        if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then
                install -d ${D}${sysconfdir}/sysctl.d
                ln -sf ../sysctl.conf ${D}${sysconfdir}/sysctl.d/99-sysctl.conf
        fi
}

CONFFILES_${PN} = "${sysconfdir}/sysctl.conf"

bindir_progs = "free pkill pmap pgrep pwdx skill snice top uptime"
base_bindir_progs += "kill pidof ps watch"
base_sbindir_progs += "sysctl"

ALTERNATIVE_PRIORITY = "200"

ALTERNATIVE_${PN} = "${bindir_progs} ${base_bindir_progs} ${base_sbindir_progs}"

ALTERNATIVE_${PN}-doc = "kill.1 uptime.1"
ALTERNATIVE_LINK_NAME[kill.1] = "${mandir}/man1/kill.1"
ALTERNATIVE_LINK_NAME[uptime.1] = "${mandir}/man1/uptime.1"

python __anonymous() {
    for prog in d.getVar('base_bindir_progs', True).split():
        d.setVarFlag('ALTERNATIVE_LINK_NAME', prog, '%s/%s' % (d.getVar('base_bindir', True), prog))

    for prog in d.getVar('base_sbindir_progs', True).split():
        d.setVarFlag('ALTERNATIVE_LINK_NAME', prog, '%s/%s' % (d.getVar('base_sbindir', True), prog))
}

- PhilBot

Answer 1

do_install () {
    install -d ${D}${base_bindir}
    mv ${D}/../build/pgrep ${D}/bin/pgrep
}

do_install_append () {
    install -d ${D}${base_bindir}
    mv ${D}/../build/pgrep ${D}/bin/pgrep
}

这里有一些混淆的地方：

• 您无法“覆盖”另一个_append：原始配方中的那个将仍然被添加
• 即使您可以，您的版本也会尝试在安装和附加中两次mv同一个文件：那样会失败。mv通常在此处不是一个好主意：使用install就是它的用途。
• 使用${D}/../build/不正确，您可能想要${B}——但这也应该是do_install()的默认目录，因此您根本不需要它。

您可以让原始的do_install()做它想做的事情，然后在do_install_append()中删除您不想要的部分……但我认为修改包如此之多不是一个好主意：如果另一个包运行时依赖于procps并期望您删除的工具呢？

以下是一些替代方案：

• 将配方复制到新名称下，然后进行修改
• 让do_install保持不变，在您的bbappend中添加一个新的包PACKAGES =+ ${PN}-pgrep并设置FILES_${PN}-pgrep = "${bindir}/pgrep"：然后您可以只安装新的小procps-pgrep包而不是procps。由于procps使用的备选系统，这可能需要一些微调……

- Jussi Kukkonen