在处理像典型的客户（Customer）和员工（Employee）这样的业务类时，是更好地仅使用getter和setter还是使用属性？
我正在翻译一些关于Java书籍中的面向对象示例到Delphi（用于自学）。在这些示例中，总是使用GetName()和SetName()，而不使用属性。
现在，我可以看到，如果我创建一个具有公开属性的组件，那么使用属性将会有非常好的理由，但在普通类中，哪种方法更好呢？是通过使用getter和setter使代码更易读（强调我们正在读取/写入属性），还是使用属性（乍一看可能会与无参数方法混淆）？
哇，属性的含义远不止于“它们只是getter和setter方法的包装器”。
属性是一种优雅而强大的方式，可以提供对类字段的受控访问。
正如已经说明的，您可以直接访问类字段。这非常好，并使代码更清晰。这也是实现类的可行第一个版本的一种很好的方式。
TMyClass = class
private
FValue: String;
public
property Value: String read FValue write FValue;
end;
稍后，您可以重新设计您的类以使用方法验证和操作字段访问。公共接口仍然相同。
TMyClass = class
private
FValue: String;
procedure SetValue(AValue: String);
public
property Value: String read FValue write SetValue;
end;
procedure TMyClass.SetValue(AValue: String);
begin
if AValue = ''
then FValue := 'No value!'
else FValue := AValue;
end;
Properties 可以方便地查看只读/写入字段。例如，一个只读/不可变类：
TClient = class
private
FName: String;
FSite: String;
FMail: String;
public
constructor Create(AName, ASite, AMail: String);
property Name: String read FName;
property Site: String read FSite;
property Mail: String read FMail;
end;
TClient = class
private
FName: String;
protected
function GetName: String; virtual; abstract;
public
property Name: String read GetName write FName;
end;
TImportantClient = class(TClient)
protected
function GetName: String; override;
end;
TArgumentativeClient = class(TClient)
protected
function GetName: String; override;
end;
function TImportantClient.GetName: String;
begin
Result := '+++ ' + FName;
end;
function TArgumentativeClient.GetName: String;
begin
Result := ':-( ' + FName;
end;
{----- ----- ----- ----- -----}
var
ClientA,
ClientB: TClient;
begin
ClientA := TImportantClient.Create;
ClientB := TArgumentativeClient.Create;
ClientA.Name := 'Mr. Nice';
ClientB.Name := 'Mr. Dumbhead';
ShowMessage(ClientA.Name);
ShowMessage(ClientB.Name);
end;
{----- ----- ----- ----- -----}
在你的类中，你可以定义默认类字段，这意味着你可以直接访问该字段而无需指定属性名。
A := MyStringList[i]:
MyStringList[i] := B;
{ instead of }
A := MyStringList.Strings[i];
MyStringList.Strings[i] := B;
{ or }
A := MyStringList.GetString(i);
MyStringList.SetString(i, B);
使用 Index 关键字，Delphi 将会将一个常量值作为参数传递给 getter/setter 方法。
TMyRect = class
private
FValues: Array[0..3] of Integer;
function GetProperty(Index: Integer): Integer;
public
property Top : Integer Index 0 read GetProperty;
property Left : Integer Index 1 read GetProperty;
property Width : Integer Index 2 read GetProperty;
property Height : Integer Index 3 read GetProperty;
end;
function TMyRect.GetProperty(Index: Integer): Integer;
begin
Result := FValues[Index];
end;
还有一些主题需要涵盖（例如实现接口、存储值、RTTI / 设计时属性等），但这篇文章开始变得有点长了...
这些网站上可以阅读更多信息：
不需要。在Java中，只有因为它没有属性才需要Getters和Setters。使用属性可以使代码更加清晰简洁。如果需要Getter或Setter，则可以将其构建到属性中，而无需在访问代码中添加大量的函数调用。
属性是Delphi的一个很好的优势。我自己做了不少Java和Delphi，毫无疑问会选择属性。实际上，这两种方法最终都会做同样的事情，唯一的区别就在于属性看起来比getter/setter整洁得多。
我建议您选择属性，并充分利用它们！