我需要编写一个批处理文件来完成一些任务。
最初我认为我的问题非常简单 - 获取指定目录中txt文件的修改日期，将该日期与当前日期进行比较，如果相同则执行某项操作。 如果不同，则执行其他操作。
我用来获取当前日期的命令是：
%date%
我用来获取指定文件修改日期的代码行是：
SET filename="C:\New Folder\New.txt"
FOR %%f IN (%filename%) DO SET filedatetime=%%~tf
ECHO %filedatetime:~0,-6% >> %destination%
在上述情况下，我只是使用echo查看返回的内容，似乎日期已经返回，但是我得到了额外的信息：
2012/02/19 02
我想知道如何获取上述值，并使它们可比较，以及如何正确地进行比较。
在批处理中处理日期比应该更困难。
有一个命令可以在这种情况下使您的工作变得容易。FORFILES具有处理自特定日期以来已修改的文件的功能。使用 FORFILES /？从命令行获取有关其使用的文档。
这个简单的命令将列出所有今天已被修改的文件：
forfiles /m * /d 0
forfiles /m %filename% /d 0
if %errorlevel% == 0 (
echo The file was modified today
REM do whatever else you need to do
) else (
echo The file has not been modified today
REM do whatever else you need to do
)
有一种更简洁的方法来完成上述操作。使用&&运算符可以在先前的命令成功时有条件地执行命令，||用于在先前的命令失败时有条件地执行命令。但是，请注意，如果&&命令失败，||命令也将被执行。
forfiles /m %filename% /d 0 && (
echo The file was modified today
REM do whatever else you need to do
) || (
echo The file has not been modified today
REM do whatever else you need to do
)
我喜欢dbenham的方法，但如果你想让你的代码工作，你可以这样做：
set currentDate=%date%
SET filename="C:\MyFile.txt"
FOR %%f IN (%filename%) DO SET filedatetime=%%~tf
IF %filedatetime:~0, 10% == %currentDate% goto same
goto notsame
:same
echo Dates the same, do some code here
goto next
:notsame
echo Dates NOT the same, do some code here
goto end
:next
如果你将来需要再次使用它，那么了解如何使其工作是值得的。
dbenham的方法可行，但我注意到forfiles的errorlevel应该是1表示错误，所以进行了修改：
forfiles /p C:\Users\[path] /m "special_file.txt" /d 0
IF ERRORLEVEL 1 (echo boo unsucessful and old file) else (echo yay sucessful and updated today)
https://learn.microsoft.com/en-us/windows-server/administration/windows-commands/forfiles https://ss64.com/nt/errorlevel.html
forfiles /m %filename% /d 0 >nul 2>nul ...- dbenham/d - nn匹配修改日期的情况下才有效。有可能匹配任何比/d - nn更新的东西吗？ - pcnate