在XSLT 1.0中如何使用前导零填充数字

Question

我们有一个XML文件中的数字，最多可以到3位数，必须转换为固定长度文本以便加载到另一个系统中。

我需要在输出结果中在前面添加零以将其填充到长度为15（固定长度文本）。

示例：

 - 1 becomes   000000000000001
 - 11 becomes  000000000000011
 - 250 becomes 000000000000250

我试过这个：

<xsl:value-of select="substring(concat('000000000000000', msg:BankAccount/msg:Counter), 12, 15)"/>

我想要在开头得到15个零并提取子字符串，但是由于在结果中得到了错误的子字符串，所以我一定犯了一个错误。

0000000000000000000000009LLOYDS BANK PLC
00000000000000000000000010LLOYDS BANK PLC

我也尝试了format-number，但它返回NaN（非数字）

<xsl:value-of select="format-number(msg:BankAccount/msg:Counter, '000000000000000')"/>

返回 'NaN'。

那么我做错了什么，最好的方法是什么？

- Our Man in Bananas

---

msg:Counter 结尾是否为 "LLOYDS BANK PLC"？format-number() 只能用于数字。 - JLRishe

不，它只有一个数字，我将“LLOYDS BANK PLC”保留在其中以显示错误所导致的影响。 - Our Man in Bananas

如果msg:Counter是一个数字，那么format-number没有理由返回NaN。你没有告诉我们有什么问题。 - Michael Kay

Answer 1

另一种方法是

substring(string(1000000000000000 + $x), 2)

- Michael Kay

---

是的，我假设$x是一个数字或将被转换为数字的值（具体细节取决于它是XPath 1.0还是2.0）。 - Michael Kay

非常优雅的解决方案。 - DAB

完美。被接受的答案对我没用，但这个更简洁并且有效！ - Gyromite

Answer 2

我需要在输出中使用前导零将其填充到长度为15 (

那就是

substring(
  concat('000000000000000', msg:BankAccount/msg:Counter), 
  string-length(msg:BankAccount/msg:Counter) + 1, 
  15
)

- Tomalak

Answer 3

也可以使用字符串格式化完成

<xsl:value-of select="format-number(msg:BankAccount/msg:Counter, '000000000000000')" />

一般来说：

<xsl:value-of select="format-number(number_you_would_like_to_padd, 'string_how_much_zeros_you_would like')" />

- payas

Answer 4

另一个选项是xsl:number...

<xsl:number value="number_to_format" format="000000000000001"/>

完整示例...

XML输入

<doc>
    <test>1</test>
    <test>11</test>
    <test>250</test>
</doc>

XSLT 1.0

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="text"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="test">
    <xsl:number value="." format="000000000000001"/>
    <xsl:text>&#xA;</xsl:text>
  </xsl:template>

</xsl:stylesheet>

输出

000000000000001
000000000000011
000000000000250

代码调试网站: http://xsltfiddle.liberty-development.net/pPzifpg

- Daniel Haley

---

我使用了 xsl:number，它非常好用！ - Andrew Truckle

Answer 5

另一个要考虑的选项...

<xsl:apply-templates select="Groups/Group[@Name='TheSource']/Field[@Name='BankAccount']" />
<xsl:text>999999999999999</xsl:text>
<!-- uncomment below and comment above line to use without test number -->
<!-- <xsl:text>|</xsl:text> -->

<xsl:template match="Groups/Group[@Name='BankAcctFile']/Field[@Name='BankAccount']">
    <xsl:call-template name="padleft">
        <xsl:with-param name="padChar" select="'0'" />
        <xsl:with-param name="padVar" select="substring(current(),1,15)" />
        <xsl:with-param name="length" select="15" />
    </xsl:call-template>
</xsl:template>

- JayTeeEye

---

没有调用模板的内容，这并不能回答这个问题。 - michael.hor257k

被调用的模板示例的内容已添加在上方。 - JayTeeEye

不，它不是。 - michael.hor257k