这个 F# 工作流是如何评估的？

Question

我对 F# 还比较陌生，但已经在阅读关于工作流和计算表达式的内容。根据我所了解的，我认为自己至少有一个关于工作流用途和语法基础的理解。后来我在这里看到了一个例子：BitWorker Workflow。

我试着将这个示例代码复制到本地项目中，并成功运行它。我开始移动一些东西并尝试理解代码的功能，但我仍然不太理解这个工作流程是如何工作的。我还没有看到其他工作流语法像这样：do bitWriter stream {... 而非 do workflow {... 的例子。

let stream = new IO.MemoryStream()

// write TCP headers
do bitWriter stream {
    do! BitWriter.WriteInt16(12345s)           // source port
    do! BitWriter.WriteInt16(12321s)           // destination port
    do! BitWriter.WriteInt32(1)                // sequence number
    do! BitWriter.WriteInt32(1)                // ack number
    do! BitWriter.WriteInt32(2, numBits = 4)   // data offset
    do! BitWriter.WriteInt32(0, numBits = 3)   // reserved
}

我没想到stream会成为bitWriter工作流程的一部分。在这里使用stream对工作流程有什么影响？

- pavuxun

Answer 1

如果我们看一个最简单的例子来实现这样的工作流程，那么解释起来会更容易些。首先，我将定义一种你可以执行的操作类型。为了简化起见，让我们只使用一个：

type Operation =  
  | WriteInt32 of int

典型的F#计算生成器不需要任何构造函数参数，但实际上您可以使用参数-此处的计算生成器以流作为参数并创建StreamWriter。在Bind操作中，参数是我们的Operation值之一，我们通过将该值写入流编写该参数。然后我们只需使用f()调用其余的计算即可。

type BitWriter(stream:IO.Stream) = 
  let wr = new IO.StreamWriter(stream)
  member x.Bind(op, f) = 
    match op with
    | WriteInt32 i -> wr.Write(i)
    f ()
  member x.Zero() = ()
  member x.Run( () ) = wr.Dispose()

Zero操作和Run操作并不特别有趣，但是 Zero 在转换中是必需的，而Run允许我们处理writer的清除。这不是定义计算表达式最常见的方式 - 它不遵循单子结构 - 但它实际上有效！在使用它之前需要两个帮助函数：

let writeInt32 i = WriteInt32 i
let bitWriter stream = BitWriter(stream)

现在，您可以编写与上述库基本相同的代码：

let stream = new IO.MemoryStream()

bitWriter stream {
  do! writeInt32 1
  do! writeInt32 2
  do! writeInt32 3
}

- Tomas Petricek