使用循环将地图元素添加到列表

Question

使用循环将地图元素添加到列表

3

我试图用从查询/findAllBy中创建的对象来填充一个地图列表...但最终我总是得到与循环中最后一个地图相同的地图列表。

我已经设定了断点并逐步执行该方法，发现1）从查询返回的数据是正确的，2）当我逐步执行循环时，数据被正确地插入到地图中，3）失败是在将地图插入列表中。我使用的所有将元素插入列表的方法(.add、.push、<<、list[(i)] = map等)都会覆盖列表中之前的所有元素。

请帮忙解决。我不知道为什么会出现这种情况。希望这对你们中的某个人来说是个容易的问题。

def shiftRecords = Shift.findAllByUserAndStartTimeBetween( userInstance, startDate, endDate )
ArrayList allShifts = new ArrayList()
LinkedHashMap thisShift = new LinkedHashMap()
def size = shiftRecords.size()

for ( int i = 0; i < size; i++ ){
    thisShift["id"] = shiftRecords[(i)].id
    thisShift["user"] = shiftRecords[(i)].user
    thisShift["startTime"] = shiftRecords[(i)].startTime
    thisShift["posCode"] = shiftRecords[(i)].posCode
    thisShift["deptCode"] = shiftRecords[(i)].deptCode
    thisShift["billingIDX"] = shiftRecords[(i)].billingIDX

    Position thisPos = Position.findByPositionCode( thisShift.posCode )
    thisShift["posTitle"] = thisPos.shortTitle
    thisShift["deptTitle"] = thisPos.departmentTitle

    allShifts.add( (i), thisShift )
}

我希望将所有Shift的结果作为地图列表，并从Shift查询结果中选择数据。我尝试使用shiftRecords.each和eachWithIndex。问题出现在任何类型的循环中，当thisShift地图插入到allShifts中时。它不仅插入了一个地图实例，而且用当前的thisShift地图替换了所有列表元素。

- CheddarMonkey

2个回答

3

尝试：

def shiftRecords = Shift.findAllByUserAndStartTimeBetween( userInstance, startDate, endDate )
def allShifts = shiftRecords.collect { it ->
    def pos = Position.findByPositionCode( it.posCode )
    [ id         : it.id,
      user       : it.user,
      startTime  : it.startTime,
      posCode    : it.posCode,
      deptCode   : it.deptCode,
      billingIDX : it.billingIDX,
      posTitle   : pos.shortTitle,
      deptTitle  : pos.departmentTitle ]
}

- tim_yates

笑，我也把我的解决方案简单化了。 :) - dmahapatro

感谢您为答案增添更多的GROOVE。我需要尽可能多的建议。您和@dmahapatro提供了出色的答案。 - CheddarMonkey

网页内容由stack overflow 提供, 点击上面的

可以查看英文原文，
原文链接

- dmahapatro · Accepted Answer

def shiftRecords = Shift.findAllByUserAndStartTimeBetween( 
                               userInstance, startDate, endDate )
ArrayList allShifts = new ArrayList()
def size = shiftRecords.size()

for ( int i = 0; i < size; i++ ){
    LinkedHashMap thisShift = new LinkedHashMap()
    thisShift["id"] = shiftRecords[(i)].id
    thisShift["user"] = shiftRecords[(i)].user
    thisShift["startTime"] = shiftRecords[(i)].startTime
    thisShift["posCode"] = shiftRecords[(i)].posCode
    thisShift["deptCode"] = shiftRecords[(i)].deptCode
    thisShift["billingIDX"] = shiftRecords[(i)].billingIDX

    Position thisPos = Position.findByPositionCode( thisShift.posCode )
    thisShift["posTitle"] = thisPos.shortTitle
    thisShift["deptTitle"] = thisPos.departmentTitle

    allShifts << thisShift
}

每次迭代shiftRecords时，您需要创建一个新地图。虽然以上代码可以在 Groovy 中过度简化，如下所示：

def shiftRecords = Shift.findAllByUserAndStartTimeBetween( 
                               userInstance, startDate, endDate )
def allShifts = []

shiftRecords.each{
    def thisShift = [:]
    thisShift.id = it.id
    thisShift.user = it.user
    thisShift.startTime = it.startTime
    thisShift.posCode = it.posCode
    thisShift.deptCode = it.deptCode
    thisShift.billingIDX = it.billingIDX

    Position thisPos = Position.findByPositionCode( thisShift.posCode )
    thisShift.posTitle = thisPos.shortTitle
    thisShift.deptTitle = thisPos.departmentTitle

    allShifts << thisShift
}