如何在DOS中计时脚本？

Question

如何在DOS提示符下计时脚本？

*NIX的等效方法是：

$ time myscript

real 0m0.886s
user 0m0.846s
sys 0m0.031s

$

有没有DOS的等效物？谢谢。

- skcubrats

---

你是真的在谈论DOS，还是Windows的命令行界面？ - user unknown

可能是如何在Windows命令行中测量命令执行时间？的重复问题。 - oHo

Answer 1

你可以使用来自Windows Server 2003资源工具包的timeit.exe。此外，你还可以获得大量其他有用的工具和Unix命令端口。

C:\Documents and Settings\Rob>timeit sleep 3

Version Number:   Windows NT 5.1 (Build 2600)
Exit Time:        2:40 pm, Thursday, December 10 2009
Elapsed Time:     0:00:03.296
Process Time:     0:00:00.015
System Calls:     7576
Context Switches: 1974
Page Faults:      1072
Bytes Read:       6172
Bytes Written:    11086
Bytes Other:      144432

- Rob

---

这种方法对我来说是最简单的，但有一个烦恼。我正在计时一个位于c:\windows\system32的dos批处理文件。当我尝试计时它时，即使它在我的系统路径中，我仍然必须输入.bat的完全限定路径。 - buzz3791

Answer 2

这是一个DOS批处理脚本，可以为您计算时间差，而不仅仅是执行“echo %time%”。

只要你的“计时用户部分”没有超过24小时，以下代码就能正常工作。请多包容或给我建议，这还是一份正在改进中的工作成果，我花了大约一个小时。

将“PAUSE”替换为调用你自己的脚本来计时你自己的代码。

DOS BAT文件如下：

注意：已编辑以修复前导零的八进制问题，并将前导零放入输出结果中。

注意：已编辑以处理跨越“午夜”的小时包装，并在输出中添加前导零。

@echo off
@rem --------------------------------------------
setlocal ENABLEEXTENSIONS

set start_time=%time%
echo Beginning at: %start_time%
echo Running Timed Batch File
echo.

@rem echo %*  <-- Extension for all args -- easier than following line
@rem echo %0 %1 %2 %3 %4 %5 %6 %7 %8 %9 ... ...

@rem DO YOUR WORK HERE -- see "call" / PAUSE is here to "fake" work
@rem call userscript.bat %*
PAUSE

set stop_time=%time%
echo.
echo Timed Batch File Completed
echo Start time: %start_time%
echo Stop time : %stop_time%


set TEMPRESULT=%start_time:~0,2%
call:FN_REMOVELEADINGZEROS
set start_hour=%TEMPRESULT%
@rem
set TEMPRESULT=%start_time:~3,2%
call:FN_REMOVELEADINGZEROS
set start_min=%TEMPRESULT%
@rem
set TEMPRESULT=%start_time:~6,2%
call:FN_REMOVELEADINGZEROS
set start_sec=%TEMPRESULT%
@rem
set TEMPRESULT=%start_time:~9,2%
call:FN_REMOVELEADINGZEROS
set start_hundredths=%TEMPRESULT%

set TEMPRESULT=%stop_time:~0,2%
call:FN_REMOVELEADINGZEROS
set stop_hour=%TEMPRESULT%
@rem
set TEMPRESULT=%stop_time:~3,2%
call:FN_REMOVELEADINGZEROS
set stop_min=%TEMPRESULT%
@rem
set TEMPRESULT=%stop_time:~6,2%
call:FN_REMOVELEADINGZEROS
set stop_sec=%TEMPRESULT%
@rem
set TEMPRESULT=%stop_time:~9,2%
call:FN_REMOVELEADINGZEROS
set stop_hundredths=%TEMPRESULT%

set /A start_total=(((((%start_hour%*60)+%start_min%)*60)+%start_sec%)*100)+%start_hundredths%
set /A stop_total=(((((%stop_hour%*60)+%stop_min%)*60)+%stop_sec%)*100)+%stop_hundredths%

set /A total_time=%stop_total% - %start_total%

set /A total_hundredths=%total_time% %% 100
set total_hundredths=00%total_hundredths%
set total_hundredths=%total_hundredths:~-2%
set /A total_time=%total_time% / 100

set /A total_sec="%total_time% %% 60"
set total_sec=00%total_sec%
set total_sec=%total_sec:~-2%
set /A total_time=%total_time% / 60

set /A total_min="%total_time% %% 60"
set total_min=00%total_min%
set total_min=%total_min:~-2%
set /A total_time=%total_time% / 60

set /A total_hour="%total_time% %% 60"
@rem Handle if it wrapped around over midnight
if "%total_hour:~0,1%"=="-" set /A total_hour=%total_hour% + 24

echo Total time: %total_hour%:%total_min%:%total_sec%.%total_hundredths%

@rem --------------------------------------------
@rem Exit the BAT Program
endlocal
goto END

@rem --------------------------------------------
@rem FN_REMOVELEADINGZEROS function
@rem  Used to remove leading zeros from Decimal
@rem  numbers so they are not treated as Octal.
:FN_REMOVELEADINGZEROS
if "%TEMPRESULT%"=="0" goto END
if "%TEMPRESULT:~0,1%" NEQ "0" goto END
set TEMPRESULT=%TEMPRESULT:~1%
goto FN_REMOVELEADINGZEROS

@rem --------------------------------------------
@rem BAT PROGRAM / FUNCTION FILE EXIT
:END

- Adisak

Answer 3

你可以把这段放在你的批处理文件开头和结尾处：

echo %time%

- akf

---

警告：不要直接在命令行中使用它（echo %time% & myprog & echo %time%），因为两者的扩展都是在命令执行之前完成的。 - Todd Owen

Answer 4

如果您不介意使用第三方EXE来帮助，timer.exe 来自 Gammadyne 是非常有用的。

setlocal ENABLEEXTENSIONS
FOR /F %%G IN ('timer') DO SET start_time=%%G

@rem Do your work Here
call userscript.bat %*

timer %start_time% "Total time"
endlocal

- Adisak