XSLT定义一个变量并检查其是否存在

Question

我正在尝试转换一个XML文档。首先，我定义了一个全局变量：

 <xsl:variable name="foo"><xsl:value-of select="bar"/></xsl:variable>

现在我转换的XML可能会定义<bar>some data</bar>，也有可能没有定义。

一旦我声明了下面的全局变量，如果它被定义了，我将尝试输出以下内容：

<foo>DEFINED</foo>

如果它没有被定义：

<foo>NOT DEFINED</foo>

我正在使用<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">。如何最好地处理这个问题？

- randombits

---

变量 foo 在变量定义之后被定义。唯一的问题是它是否包含文本节点。 - Jim Garrison

我是否更好地询问如何检查文本节点是否已定义的问题？ - randombits

如果输入包含 <bar/> 或 <bar></bar>，您希望发生什么？ - Jim Garrison

Answer 1

由于您正在使用XSLT 1.0，因此可以使用string()进行测试。

以下是一个样式表示例：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="/*">
        <xsl:variable name="foo" select="bar"/>
        <results>
            <xsl:choose>
                <xsl:when test="string($foo)">
                    <foo>DEFINED</foo>
                </xsl:when>
                <xsl:otherwise>
                    <foo>NOT DEFINED</foo>
                </xsl:otherwise>
            </xsl:choose>           
        </results>
    </xsl:template>

</xsl:stylesheet>

请注意，空格被折叠，因此<bar> </bar>将返回false。另外，在直接测试元素而不是变量时，string()将起作用。

以下是一些输入/输出示例：

---

输入

<test>
    <bar/>
</test>

或者

<test>
    <bar></bar>
</test>

或者

<test>
    <bar>    </bar>
</test>

输出

<foo>NOT DEFINED</foo>

---

输入

<test>
    <bar>x</bar>
</test>

输出

<foo>DEFINED</foo>

如果您使用XSLT 2.0，您可以将变量声明为xs:string，并且只需在测试中使用变量名（test="$foo"）。

例如：

<xsl:stylesheet version="2.0" xmlns:xs="http://www.w3.org/2001/XMLSchema" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" exclude-result-prefixes="xs">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="/*">
        <xsl:variable name="foo" select="bar" as="xs:string"/>
        <results>
            <xsl:choose>
                <xsl:when test="$foo">
                    <foo>DEFINED</foo>
                </xsl:when>
                <xsl:otherwise>
                    <foo>NOT DEFINED</foo>
                </xsl:otherwise>
            </xsl:choose>           
        </results>
    </xsl:template>

</xsl:stylesheet>

- Daniel Haley

Answer 2

我不确定这是否有效，但是...

在你的样式表中添加xmlns:fn="http://www.w3.org/2005/xpath-functions"。

<xsl:choose>
  <xsl:when test="fn:boolean(foo)">
    <foo>DEFINED</foo>
  </xsl:when>
  <xsl:otherwise>
    <foo>NOT DEFINED</foo>
  </xsl:otherwise>
</xsl:choose>

编辑：@JimGarrison 如果它有效，这将把<bar/>或<bar></bar>视为已定义。

- indeterminately sequenced

---

您不必声明 fn 前缀，也不需要将其添加到 boolean() 中。 - Daniel Haley

Answer 3

变量foo将包含xml节点bar（而不仅是bar的内容）。因此，“@indeterminately sequenced”的答案是正确的，您可以使用test="boolean($foo)"测试foo是否包含xml节点（bar）。但我更喜欢test="name($foo)"或者test="name($foo) = 'bar'"。

<xsl:variable name ="foo" select="*/bar" />

<xsl:template match="/">
    <results>
        <xsl:choose>
            <xsl:when test="name($foo)">
                <foo>DEFINED</foo>
            </xsl:when>
            <xsl:otherwise>
                <foo>NOT DEFINED</foo>
            </xsl:otherwise>
        </xsl:choose>
    </results>
</xsl:template>

- hr_117