我刚意识到F# records是引用类型，同时也发现了有多少装箱和拆箱操作。我有很多像这样的小型records：
type InputParam =
| RegionString of string
| RegionFloat of float32
但是，如果我尝试使用"Struct"属性对它进行标记，我会得到一个编译器错误，指出"FS3204 如果一个联合类型有不止一种情况并且是一个结构体，则联合类型内的所有字段都必须被赋予唯一名称。" 语言参考 显示如何创建结构体判别联合：
[<Struct>]
type InputParamStruct =
| RegionString of RegionString: string
| RegionFloat of RegionFloat: float32
首先，这些不是 Records - 它们是带标签的联合体。记录是具有命名数据的简单聚合，具有生成的相等性/哈希，并且将其作为结构体也是可能的，但不会带来额外的要求。
结构化带标签的联合体的更严格要求是：
前两个要点是作为值类型固有的。值类型和引用类型只是不同的。
最后一个要点很有趣。请考虑以下内容：
type DU1 =
| Case1 of string
| Case2 of float
[<Struct>]
type DU2 =
| Case1 of sval: string
| Case2 of fval: float
对于 DU1，每种情况都有一个内部类，其中包含用于访问底层数据的属性。 这些属性被命名为 Item1、Item2 等等，由于它们被封装在内部类中，因此在访问时是唯一的。
对于 DU2，sval 和 fval 值被展开；没有包含它们的内部类。这是因为目标是结构的性能/大小。联合情况下数据的命名策略（Item1 / Item2 / 等等）不适用，因为所有数据都是平展开的。因此，设计决策是要求具有唯一名称的情况，而不是将用例本身的名称与 Item1 / Item2 / 等等的某些变体拼凑在一起。独特性问题固有于编译器中联合本身的设计，而不仅仅是代码生成设计选择。
最后，这个问题还有另一个有趣的答案:
为什么 F# 不会默认使用结构体来表示记录？
F# 中的元组、记录和 DU 都可以标记为 [<Struct>]，但默认情况下不是结构体。这是因为结构体并不仅仅是一个可以提高效率的按钮。往往由于结构体太大而导致过度复制而获得更低的 CPU 性能。在 F# 中，拥有大型元组、非常非常大的记录和辨别联合十分普遍。如果默认情况下将它们都变成结构体，则不是一个好的选择。引用类型非常强大，并且被设计为在 .NET 上工作得非常好，不应该默认避免使用它们，只是因为在某些情况下使用结构体可能会导致稍微更快的性能。
每当您关心性能时，请不要基于假设或直觉改变事物：使用像 PerfView、dotTrace 或 dotMemory 这样的分析工具；并使用 BenchmarkDotNet 这样的统计工具来对小的更改进行基准测试。性能是一个极其复杂的领域，一旦考虑到明显糟糕的问题（例如在大数据集上的 O(n^2) 算法），就很少是简单的。
type InputParam =
| RegionString of string
| RegionFloat of float32
还有这个引用类型：
type InputParam =
| RegionString of RegionString: string
| RegionFloat of RegionFloat: float32
两者在功能上完全相同。唯一的区别在于编译器如何命名它们。它们都创建一个名为“RegionString”的子类，但具有不同的属性名称--“RegionString.item”与“RegionString.RegionString”。
当您将第一个示例转换为结构时，它会放弃子类并尝试在记录上粘贴2个“item”属性，导致FS3204独特名称错误。
就性能而言，在组合这些微小类型时，您应该使用结构体。考虑这个示例脚本：
type Name = Name of string
let ReverseName (Name s) =
s.ToCharArray() |> Array.rev |> System.String |> Name
[<Struct>]
type StrName = StrName of string
let StrReverseName (StrName s) =
s.ToCharArray() |> Array.rev |> System.String |> StrName
#time
Array.init 10000000 (fun x -> Name (x.ToString()))
|> Array.map ReverseName
|> ignore
#time
#time
Array.init 10000000 (fun x -> StrName (x.ToString()))
|> Array.map StrReverseName
|> ignore
#time
sizeof<Name>
sizeof<StrName>
Real: 00:00:04.637, CPU: 00:00:04.703, GC gen0: 340, gen1: 104, gen2: 7
...
Real: 00:00:02.620, CPU: 00:00:02.625, GC gen0: 257, gen1: 73, gen2: 1
...
val it : int = 8
val it : int = 8
功能域建模非常棒，但您必须记住这些具有相同的性能开销：
let c = CustomerID 5
let i = 5 :> obj