如何从目标获取包含目录以在add_custom_target中使用？

Question

如何从目标获取包含目录以在add_custom_target中使用？

12

我正在使用 target_link_libraries 对依赖进行建模，就像这篇博客文章中所做的那样。

target_link_libraries(Foo
    LibraryA
    LibraryB
)

这个方法很好用，但由于各种原因我需要使用add_custom_target通过自定义命令预处理一个文件。问题是，这个自定义目标依赖于LibraryA和LibraryB的包含文件。我真的希望像target_link_libraries一样实现以下内容（请参见LibraryA和LibraryB部分）:

add_custom_target(Bar ALL
    COMMAND ${CMAKE_C_COMPILER} thing.cpp LibraryA LibraryB /P
    WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/Path/Here
    COMMENT "Preprocessing to a file"
    VERBATIM
)

然而，这样做不起作用。 LibraryA和LibraryB按照它们的样子被放入其中。即使它起作用了，我想我会得到更多的包括，因为我认为目标也包括库。也许这不是一个好方法。

那么，在这里我该怎么办？我如何从每个目标中提取include目录以供自定义命令使用？我发现如果我使用find_package(Foo REQUIRED)，我可以访问Foo_DIR，但它指向构建目录而不是包含目录的源目录。

- Stradigos

你的目标是从 LibraryA 和 LibraryB 的目标中提取包含目录，并在自定义命令中使用这些目录吗？ - Kevin

@squareskittles 正确。我只需要从LibraryA和LibraryB中的头文件。 - Stradigos

你在自定义命令中如何使用它们？如果 CMAKE_C_COMPILER 是 gcc，你是否打算将它们作为包含目录传递给编译器？使用 -I 标志吗？ - Kevin

1

这是我试图找出的一部分。如果我有一个变量可以提供路径，我可以使用Include标志将它们包含到自定义命令中。如果我无法获得它，因为我正在使用目标建模依赖关系，也许有些事情我可以做。我只是不知道该怎么做。 - Stradigos

2个回答

2

正如评论所述，当前被接受的答案无法处理传递依赖项。这个问题让我一整天都很困惑，所以我现在要梳理一下。

我正在构建LibraryLinkUtilities 这里。这是我在项目中使用的CMakeLists.txt：

cmake_minimum_required(VERSION 3.15.0)

project ("CMakeProject1")

set(LLU_ROOT "D:/test/LibraryLinkUtilities/install")
set(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "" FORCE)

find_package(LLU NO_MODULE PATH_SUFFIXES LLU)

add_library(${PROJECT_NAME} SHARED ${PROJECT_NAME}.cpp)

target_link_libraries(${PROJECT_NAME} PRIVATE LLU::LLU)

当我用Visual Studio打开.sln文件时，一切都很正常，不管是哪种构建类型都可以。但是我发现在配置中包含目录为空。这让我很疑惑，因为我想知道项目实际上包括哪些目录。然后我使用print_target_properties函数来修复此处，以打印有关导入目标的所有属性：

function(print_target_properties target)
    if(NOT TARGET ${target})
      message(STATUS "There is no target named '${target}'")
      return()
    endif()

    foreach(property ${CMAKE_PROPERTY_LIST})
        string(REPLACE "<CONFIG>" "DEBUG" property ${property})

        get_property(was_set TARGET ${target} PROPERTY ${property} SET)
        if(was_set)
            get_target_property(value ${target} ${property})
            message("${target} ${property} = ${value}")
        endif()
    endforeach()
endfunction()

print_target_properties(LLU::LLU)

请注意红线处，LLU::LLU 依赖于 WSTP::WSTP 和 WolframLibrary::WolframLibrary。因此我使用以下代码打印所有包含目录：

include(CMakePrintHelpers)
get_target_property(LLUDEPENDS LLU::LLU INTERFACE_LINK_LIBRARIES)
cmake_print_properties(TARGETS LLU::LLU ${LLUDEPENDS} PROPERTIES INTERFACE_INCLUDE_DIRECTORIES)

- yode

网页内容由stack overflow 提供, 点击上面的

可以查看英文原文，
原文链接

- Kevin · Accepted Answer

您可以使用 get_target_property() 从每个目标中提取包含目录。目标的 INCLUDE_DIRECTORIES 属性包含该目标的包含目录。由于您有两个目标，LibraryA 和 LibraryB，我们需要调用它两次。然后，我们可以使用 foreach() 将包含目录列表连接在一起。如果您在编译器命令（如 MSVC）中将这些作为包含目录使用，则还可以在循环中每个目录后面添加 /I 编译器选项：

# Get the include directories for the target.
get_target_property(LIBA_INCLUDES LibraryA INCLUDE_DIRECTORIES)
get_target_property(LIBB_INCLUDES LibraryB INCLUDE_DIRECTORIES)

# Construct the compiler string for the include directories.
foreach(dir ${LIBA_INCLUDES} ${LIBB_INCLUDES})
    string(APPEND INCLUDE_COMPILER_STRING "/I${dir} ")
endforeach()

接着，您可以使用已构建的INCLUDE_COMPILER_STRING变量调用自定义目标命令：

add_custom_target(Bar ALL
    COMMAND ${CMAKE_C_COMPILER} thing.cpp ${INCLUDE_COMPILER_STRING} /P
    WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/Path/Here
    COMMENT "Preprocessing to a file"
    VERBATIM
)

如果您想要更简洁的内容，可以使用生成器表达式示例此处，它获取目标的包含目录并在自定义目标命令中内联扩展它们。也可以尝试以下代码：

add_custom_target(Bar ALL
    COMMAND ${CMAKE_C_COMPILER} thing.cpp 
        "/I$<JOIN:$<TARGET_PROPERTY:LibraryA,INCLUDE_DIRECTORIES>,;/I>"
        "/I$<JOIN:$<TARGET_PROPERTY:LibraryB,INCLUDE_DIRECTORIES>,;/I>"
        /P
    WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/Path/Here
    COMMENT "Preprocessing to a file"
    VERBATIM
    COMMAND_EXPAND_LISTS
)