XSLT 1.0累加、求和、乘法

Question

我有一组固定的小节点：<a>、<b>、<c>、<d>。每个节点的值只能是1或0。 此外，每个节点都有一个权重：分别是1、2、3、4。不使用节点属性。 如何使用XSLT 1.0将每个节点的值乘以它的权重相加？例如：

<a>0</a>
<b>1</b>
<c>0</c>
<d>1</d>

总计：6

<a>1</a>
<b>1</b>
<c>0</c>
<d>0</d>

总数：3

<a>0</a>
<b>1</b>
<c>1</c>
<d>1</d>

总和：9

- Vincent

---

好问题，+1。请查看我的答案，其中包含完整且简短的XSLT 1.0解决方案。 :) - Dimitre Novatchev

Answer 1

并不是非常优雅，但这就是我想到的。

<xsl:stylesheet
version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:my="my:my"
exclude-result-prefixes="my">
<xsl:output method="text"/>
<xsl:strip-space elements="*"/>

<my:node-weight>
    <node name="a" weight="1"/>
    <node name="b" weight="2"/>
    <node name="c" weight="3"/>
    <node name="d" weight="4"/>
</my:node-weight>

<xsl:template match="root">
    <xsl:apply-templates select="*[1]" mode="sum"/>
</xsl:template>

<xsl:template match="*" mode="sum">
    <xsl:param name="sumNumber" select="0"/>
    <xsl:variable name="thisWeight" select="document('')/*/my:node-weight/node[@name = local-name(current())]/@weight"/>
    <xsl:choose>
        <xsl:when test="following-sibling::*">
            <xsl:apply-templates select="following-sibling::*[1]" mode="sum">
                <xsl:with-param name="sumNumber" select="$sumNumber + $thisWeight * number()"/>
            </xsl:apply-templates>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="$sumNumber + $thisWeight * number()"/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

</xsl:stylesheet>

当应用于以下格式良好的文档时：

<root>
    <a>0</a>
    <b>1</b>
    <c>0</c>
    <d>1</d>
</root>

结果是6

<root>
    <a>1</a>
    <b>1</b>
    <c>0</c>
    <d>0</d>
</root>

结果是3

<root>
    <a>0</a>
    <b>1</b>
    <c>1</c>
    <d>1</d>
</root>

结果为9

- Flack

---

+1 我喜欢细粒度遍历。但除此之外，权重可以只是一个计数器，我会使用一个变量来表示下一个节点和计算，避免重复的代码。 - user357812

Answer 2

这个XSLT 1.0转换:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/*">
  <xsl:call-template name="sumWeighted"/>
 </xsl:template>

 <xsl:template name="sumWeighted">
   <xsl:param name="pList" select="*"/>
   <xsl:param name="pIndex" select="1"/>
   <xsl:param name="pAccum" select="0"/>

   <xsl:choose>
    <xsl:when test="$pIndex > count($pList)">
     <xsl:value-of select="$pAccum"/>
    </xsl:when>
    <xsl:otherwise>
      <xsl:call-template name="sumWeighted">
        <xsl:with-param name="pList" select="$pList"/>
        <xsl:with-param name="pIndex"
             select="$pIndex+1"/>
        <xsl:with-param name="pAccum"
             select="$pAccum+$pList[$pIndex]*$pIndex"/>
      </xsl:call-template>
    </xsl:otherwise>
   </xsl:choose>
 </xsl:template>
</xsl:stylesheet>

应用于提供的XML文档时:

<t>
    <a>0</a>
    <b>1</b>
    <c>0</c>
    <d>1</d>
</t>

,

<t>
    <a>1</a>
    <b>1</b>
    <c>0</c>
    <d>0</d>
</t>

and

<t>
    <a>0</a>
    <b>1</b>
    <c>1</c>
    <d>1</d>
</t>

分别产生所需的结果：

6

3

9

---

参考资料：

如果您想使用XSLT进行非常复杂的数学计算，请查看以下内容：

http://fxsl.sourceforge.net/articles/xslCalculator/The%20FXSL%20Calculator.html

---

XPath 2.0 / XSLT 2.0 解决方案：

只需使用此XPath 2.0一行代码：

   sum(/*/*/(number()*position()))

- Dimitre Novatchev

---

@Dimitre，你也能批评一下我的解决方案吗？我会非常感激。 - Flack

@Flack：你的解决方案很好。它有点啰嗦了。特别是权重不是必要的，因为每个权重只是元素的位置。 - Dimitre Novatchev

@Dimitre，我认为假设权重可以改变并不是完全没有意义的。虽然在这个话题中并不需要。 - Flack

@Flack：没错。就我个人而言，我总是想专注于问题的本质，而不提供可能会分散和混淆注意力的额外信息。这就是为什么我的回答有其当前的形式。我提供的参考链接包含可能是最复杂的数学计算之一。因此，如果有人对此感兴趣，他们将会跟随该链接去深入了解。 - Dimitre Novatchev

@Dimitre，我并没有评判，事实上我还点了赞 :) 我只是想为自己多做一些探索，纯属好玩。 - Flack