在Delphi 2009中添加到dfm的DoubleBuffered属性在Delphi 2007中不存在。

Question

这是否意味着我不能在Delphi 2007和2009之间共享表单？

- Fabio Gomes

Answer 1

DoubleBuffered属性在TWinControl上已经存在一段时间了。Delphi 2009的区别在于它现在已经发布了。 如果您只能忽略错误（而不是使属性起作用），这里有一个可能的解决方案：

unit Delphi2009Form;

interface

uses
  Windows, Classes, SysUtils, Controls, Forms;

type
{$IFDEF VER200}
  TDelphi2009Form = class(TForm);
{$ELSE}
  TDelphi2009Form = class(TForm)
  private
    procedure ReaderError(Reader: TReader; const Message: string; var Handled: Boolean);
  protected
    procedure ReadState(Reader: TReader); override;
  end;

  TReaderErrorProc = procedure(const Message: string);

var
  ReaderErrorProc: TReaderErrorProc = nil;
{$ENDIF}

implementation

{$IFNDEF VER200}
type
  THackReader = class(TReader);

procedure TDelphi2009Form.ReaderError(Reader: TReader; const Message: string; var Handled: Boolean);
begin
  with THackReader(Reader) do
    Handled := AnsiSameText(PropName, 'DoubleBuffered') or AnsiSameText(PropName, 'ParentDoubleBuffered');
  if Handled and Assigned(ReaderErrorProc) then
    ReaderErrorProc(Message);
end;

procedure TDelphi2009Form.ReadState(Reader: TReader);
begin
  Reader.OnError := ReaderError;
  inherited ReadState(Reader);
end;
{$ENDIF}

end.

然后，将项目中表单的声明更改为继承自TDelphi2009Form，例如：

type
  TFormMain = class(TDelphi2009Form)
  ...

这将在运行时起作用——属性错误将被忽略。为了使其在设计时也能起作用，请创建一个仅限设计的包，将designide.dcp添加到其requires子句中，并将以下单元添加到其中：

unit Delphi2009FormReg;

interface

uses
  Delphi2009Form;

procedure Register;

implementation

uses
  DesignIntf, DesignEditors, ToolsAPI;

procedure ShowReaderError(const Message: string);
begin
  with BorlandIDEServices as IOTAMessageServices do
    AddTitleMessage(Message);
end;

procedure Register;
begin
  RegisterCustomModule(TDelphi2009Form, TCustomModule);
  ReaderErrorProc := ShowReaderError;
end;

initialization

finalization
  ReaderErrorProc := nil;

end.

在 Delphi 2007 IDE 中安装包，当您在 IDE 中打开表单时，DoubleBuffered 和 ParentDoubleBuffered 属性的属性错误将自动被忽略。 当您在 Delphi 2007 中保存表单时，属性值将丢失，因此您应该在代码中初始化它们。 编辑: 我已经添加了代码以将读取器错误消息输出到 IDE 消息窗口:

- TOndrej

---

对于这个简单的观察，我给予加1。在D2009之前，我并不知道这一点。现在，我可以通过在FormCreate中打开它来纠正一些问题。非常有帮助！ - Chris Thornton

Answer 2

是的。除非您从DFM中删除在Delphi 2007中未发布的属性，否则不可能实现。

- Lars Truijens

---

你试过我的答案了吗？对我来说似乎有效，但有一个警告 - D2009特定的属性在D2007中不会保存回.dfm文件 - 但只要你不在D2007中修改并重新保存表单，它们至少会被保留。 - Ondrej Kelle

我猜这是可能的，只是不太实际。 - Lars Truijens

Answer 3

Delphi项目一直非常容易向前移植到新版本。使用旧编译器的当前代码需要更加谨慎，但也是相当简单的。我在Delphi 2005/2006/2007中维护了代码，其他人仍需要在Delphi 6和7中使用。

如果从DFM中删除不兼容的属性，则应该在较旧的版本中正常工作，而不会对Delphi 2009造成干扰。最大的例子是在Delphi 2006中引入的explicit*属性。我有一个自制的“DFM清理器”来剥离这些内容。请记住，这些属性存在是有原因的，因此您应该只去除那些您打算实现向后兼容的属性。

您还可以考虑投资于静态代码分析工具，例如CodeHealer或Pascal Analyzer。除了指出问题（尤其是CodeHealer）并帮助您清理代码外，您还可以选择要分析的Delphi版本，从而更容易找到除DFM属性之外的不兼容性。它们可以作为构建流程的一部分自动化执行。

请注意，共享源代码，但对每个版本保持单独的项目。这在Delphi 2007和Delphi 2009之间尤为重要。最近的.dproj文件使用相同的扩展名，但与Delphi 2007不兼容。您还可能会遇到一些不兼容的资源问题。

- Bruce McGee

---

我不同意 Delphi 项目容易移植的说法。过去我进行过迁移，似乎大多数组件/控件都需要至少进行轻微的甚至是重大的更改。相比之下，在 Visual Studio 中完成的 C# 项目要糟糕得多。 - Boris Yankov

你的经历和我的不同。自从 Delphi 1 以来，我想我没有参与过一个没有至少移动一次的项目。这几乎总是非常直接的。我甚至可以在之前的版本中重新编译其中的几个。 - Bruce McGee

我遇到的问题仅限于我的代码，以解决VCL错误。然后，当新版本发布时，我有时必须撤消这些解决方法，然后找到并实施所有新VCL错误的修复。但是，在Delphi中，从一个版本到下一个版本的基本兼容性非常好。 - David Heffernan

Answer 4

每个表单都有一个dfm文件，其中包含表单及其组件的属性设置。一些属性值具有默认值，因此如果保留默认值，则不会存储它们。 我刚刚进行了一个小测试：

- 在2009中创建一个表单 - 添加几个标准控件 - 保存它 - 在2006中打开它（对不起，这台电脑上没有2007）

而且它可以正常工作，没有出现任何消息。但也许你没有这么幸运。

使用Delphi在不同版本之间共享数据通常会有点麻烦。升级的可能性很大，但降级则很困难。因此，我建议不要在不同版本之间共享表单文件。

据我所知，在dfm文件中不可能添加条件定义。但是，我们真的需要那个吗…… 我更喜欢一种机制，它忽略未知的属性。

- Gamecat

Answer 5

您可以在OnCreate方法中安全地添加代码中的属性，并在它们周围包装{$IFDEF VER200} // NEW PROPERTIES {$ENDIF}。DoubleBuffered可以放在ifdefs之外，因为它存在于Delphi 2007中，只是不可用于属性检查器。

您只需要担心与默认设置不同的属性。对于doublebuffered，只有当设置为true时才需要担心此问题。

在Delphi 2007中加载Delphi 2009表单时，您将收到一个警告，指出将要销毁一个属性，只需记下这些属性，因为这些是您需要处理的属性。

我正在使用这种方法将我的代码从Delphi 2006迁移到Delphi 2009。我的大多数项目都包含多个共享单元，并且必须在Delphi 2006中编译以进行发货版本，而在Delphi 2009中编译以进行“下一个”发布。我还经常使用{$IFDEF UNICODE}定义，其中需要确保字符串是widestring或ansistring，具体取决于例程。

- skamradt