Spring4D注销接口类型（Spring4D，DUnitX，Delphi-Mocks）

Question

我正在使用spring4d、dunitx和delphi-mocks编写我的第一个单元测试之一。

在我的测试应用程序中，我将一个接口自动注入到我的被测系统类（sut）中：

IMyInterface = interface [{yes, a GUID here}]
  function GetSomething1: TSomething1;
  function GetSomething2: TSomething2;
end;

TMyClass = class
private
    [Inject]
    FMyInterface: IMyInterface;
    // ...
end;

现在当我使用单元测试和模拟时，我使用以下（非常简化的）代码：

TMyTest = class
private
    [Test]
    procedure Test1;

    [Test]
    procedure Test2;
    // ...
end;

procedure TMyTest.Test1;
var
    aSut: TMyClass;
    aIntfMock: TMock<IMyInterface>;
    aSomething1: TSomething1;
begin
    // Arrange
    GlobalContainer.RegisterType<TMyClass>;

    aIntfMock := TMock<IMyInterface>.Create;
    try
        GlobalContainer.RegisterType<IMyInterface>.DelegateTo(
            function: IMyInterface
            begin
                Result := aIntfMock;
            end)
            .AsDefault;

        GlobalContainer.Build;

        aSomething1 := TSomething1.Create;
        try
            aIntfMock.Setup.WillReturn(TValue.From<TSomething1>(aSomething1)).When.GetSomething1;

            aSut := GlobalContainer.Resolve<TMyClass>;
            try
                // Act
                aSut.DoSomething;
            finally
                 FreeAndNil(aSut);
            end;

            // Assert
            // ...
        finally
            FreeAndNil(aSomething1);
        end;
    finally
        aIntfMock.Free; 
    end;
end;

procedure TMyTest.Test2;
var
    aSut: TMyClass;
    aIntfMock: TMock<IMyInterface>;
    aSomething2: TSomething2;
begin
    // Arrange
    GlobalContainer.RegisterType<TMyClass>;

    aIntfMock := TMock<IMyInterface>.Create;
    try
        GlobalContainer.RegisterType<IMyInterface>.DelegateTo(
            function: IMyInterface
            begin
                Result := aIntfMock;
            end)
            .AsDefault;


        GlobalContainer.Build;   // <---- ERegistrationException here

        aSomething2 := TSomething1.Create;
        try
            aIntfMock.Setup.WillReturn(TValue.From<TSomething2>(aSomething2)).When.GetSomething2;

            aSut := GlobalContainer.Resolve<TMyClass>;
            try
                // Act
                aSut.DoSomething;
            finally
                 FreeAndNil(aSut);
            end;

            // Assert
            // ...
        finally
            FreeAndNil(aSomething2);
        end;
    finally
        aIntfMock.Free; 
    end;
end;

第一个测试方法（Test1）运行良好...但在第二个测试方法（Test2）中，在GlobalContainer.Build这一行，spring4d引发了一个异常：ERegistrationException('Duplicate service name found: IMyInterface_u.IMyInterface@IMyInterface_u.IMyInterface')。

有没有可能注销aIntfMock，这样我就可以为每个其他的测试例程注册一个新的呢？

[编辑] 因此解决方案是：

TMyTest = class
private
    FTestContainer: TContainer;
    FIntfMock: TMock<IMyInterface>;
    FSut: TMyClass;

    [Setup]
    procedure Setup;
    [TearDown]
    procedure TearDown;
    [Test]
    procedure Test1;

    [Test]
    procedure Test2;
    // ...
end;

//---------------------

procedure TMyTest.Setup;
begin
    FTestContainer := TContainer.Create;
    FTestContainer.RegisterType<TMyClass>;

    FIntfMock := TMock<IMyInterface>.Create;    

    FTestContainer.RegisterType<IMyInterface>.DelegateTo(
        function: IMyInterface
        begin
            Result := FIntfMock;
        end)
        .AsDefault;

    FTestContainer.Build;

    FSut := FTestContainer.Resolve<TMyClass>;
end;

procedure TMyTest.TearDown;
begin
    FreeAndNil(FSut);
    FIntfMock.Free;
    FreeAndNil(FTestContainer);
end;

procedure TMyTest.Test1;
var
    aSomething1: TSomething1;
begin
    // Arrange

    aSomething1 := TSomething1.Create;
    try
        aIntfMock.Setup.WillReturn(TValue.From<TSomething1>(aSomething1)).When.GetSomething1;

        // Act
        FSut.DoSomething;

        // Assert
        // ...

    finally
        FreeAndNil(aSomething1);
    end;
end;

procedure TMyTest.Test2;
begin
    // ...
end;

感谢您的快速回复...

- Markus

Answer 1

简短回答：不行

详细回答：该容器没有支持注销任何已注册类型的可能性。这是因为注销任何内容都可能对其他类型和创建的实例（尤其是单例）产生级联影响。

我总是建议不要使用GlobalContainer，而是创建自己的TContainer实例。然后，您可以丢弃该实例并在下一个测试中使用新的实例。

您可以查看我们的单元测试，了解如何完成此操作（Spring.Tests.Container.pas中有TContainerTestCase类）

除了容器外，您还应该避免在测试中使用单例。每个单元测试都应该是隔离的。一旦涉及全局状态，就可能会产生副作用。

- Stefan Glienke