使用XSL在第一个位置插入XML节点

Question

XSLT目前会在导入不存在时插入它。

<?xml version="1.0" encoding="utf-8"?>
<Project DefaultTargets="Build" ToolsVersion="4.0" xmlns="http://schemas.microsoft.com/developer/msbuild/2003">
    ...
    ...
    <Import Project="$(SolutionDir)BuildShared.targets" />
</Project>

我需要将它作为第一个节点插入。

<?xml version="1.0" encoding="utf-8"?>
<Project DefaultTargets="Build" ToolsVersion="4.0" xmlns="http://schemas.microsoft.com/developer/msbuild/2003">
    <Import Project="$(SolutionDir)BuildShared.targets" />
    ...
    ...
</Project>

template.xsl;

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:ms="http://schemas.microsoft.com/developer/msbuild/2003">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

    <xsl:template match='@*|node()'>
        <xsl:copy>
            <xsl:apply-templates select='@*|node()'/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="/ms:Project[not(ms:Import[@Project='$(SolutionDir)BuildConfiguration.targets'])]">
        <xsl:copy>          
            <xsl:apply-templates select="node()|@*"/>
            <Import xmlns="http://schemas.microsoft.com/developer/msbuild/2003" Project="$(SolutionDir)BuildConfiguration.targets"/>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

交换import和apply-templates行会导致：

运行时错误: 文件template.xsl第9行元素copy

属性节点必须在元素的任何子节点之前添加。

- Thermionix

Answer 1

只需对node()和@*分别执行xsl:apply-templates：

<xsl:template match="/ms:Project[not(ms:Import[@Project='$(SolutionDir)BuildConfiguration.targets'])]">
    <xsl:copy>          
        <xsl:apply-templates select="@*"/>
        <Import xmlns="http://schemas.microsoft.com/developer/msbuild/2003" Project="$(SolutionDir)BuildConfiguration.targets"/>
        <xsl:apply-templates select="node()"/>
    </xsl:copy>
</xsl:template>

- Daniel Haley