使用 LWP::Agent 的 Perl JSON::RPC::Client

Question

我被要求不使用JSON::RPC::Client，而是使用LWP进行调用。以下是我的代码：

服务器端：

#!/usr/bin/perl

use strict;
use lib ".";

use ServerLib;

use JSON::RPC::Server::Daemon;

die "Do Not run as Root\n" if($< == 0);
print "Starting Daemon\n";
my $daemon =  JSON::RPC::Server::Daemon->new(LocalPort => 8000);
$daemon->dispatch({'/jsonrpc/API' => 'ServerLib'})->handle();
exit;

模块：

package ServerLib;

use base qw(JSON::RPC::Procedure); # Perl 5.6 or more than
use JSON;
use Data::Dumper;
use Sys::Hostname;
use Net::RabbitMQ;
use YAML qw( LoadFile );
use strict;

$| = 1;
my $VERSION = 0.2.0;

sub echo : Public(message:string) {
    my ($s, $obj) = @_;
    my $message = $obj->{'message'};
    print "got message => $message\n";
    print "returning: $message\n";
    my $object = { message => $message,
                   foobar => "garbage" };

    return $object;
 }
package ServerLib::system;

sub describe {
    {
        sdversion => "0.1",
        name      => 'ServerLib',
    };
}

1;

工作客户端：

#!/usr/bin/perl

use strict;

use JSON::RPC::Client;
use Data::Dumper;
my $client = new JSON::RPC::Client;

my $uri = 'http://localhost:8000/jsonrpc/API';
my $obj = {
    method  => 'echo', # or 'MyApp.sum'
    params  => ["my message"],
};

my $res = $client->call( $uri, $obj );

if($res){
   if ($res->is_error) {
       print "Error : ", $res->error_message;
   }
    else {
       print Dumper($res->result);
   }
 }
 else {
    print $client->status_line;
 }

无法工作的客户端：

#!/usr/bin/perl -w

use strict;
use JSON;
use LWP::Simple;
use Data::Dumper;

my $actionurl = "http://localhost:8000/jsonrpc/API";

my $ua = LWP::UserAgent->new();
$ua->agent("JSONClient/0.1");

my $object = { method => "echo",
           params => [@ARGV ] };

my $json = to_json($object);
print "$json\n";
my $req = HTTP::Request->new(POST => $actionurl);
$req->content_type('application/json');
$req->content($json);

my $res = $ua->request($req);
if ($res->is_success)
{
    print "Succeeded:\n" . Dumper($res->dump);
    print "DUmp: ". $res->dump;
    my $result = to_json($res->content);
 }
  else
      {
        print "Failed\n";
 }

我注意到两个客户端的服务器进程，但第二个客户端没有收到任何返回数据。

DUmp: HTTP/1.1 200 OK
Connection: close
Date: Tue, 03 Jan 2012 18:24:24 GMT
Server: libwww-perl-daemon/5.827
Content-Type: application/json; charset=UTF-8
Client-Date: Tue, 03 Jan 2012 18:24:24 GMT
Client-Peer: 127.0.0.1:8000
Client-Response-Num: 1

(no content)

有人知道我漏掉了什么吗？这应该很简单，但出于某种原因，我找不到像RPC::Client看到的响应字符串。

- Joe Coder

---

为什么不能使用 JSON::RPC::Client 或者 JSON::RPC::LWP？ - Brad Gilbert

他们不想在客户机器上安装额外的库。 - Joe Coder

那么，只需将它们像项目中的文件一样捆绑在一起，完成。 - Brad Gilbert

Answer 1

这是一个棘手的问题。我的一位同事发现了这个问题，他不在Stackoverflow上，所以我会发布解决方法。

这个：

my $object = { method => "echo",
       params => [@ARGV ] };

需要的版本为 => "1.1"，添加到其中变成：

my $object = { method => "echo",
               params => [@ARGV],
               version => "1.1",};

不确定这为什么很重要，但一旦添加了它，它就像魔法般工作。

- Joe Coder

Answer 2

• “非工作客户端”的输出是什么？“成功”还是“失败”？
• 你传递了哪些参数？(@ARGV)
• 如果你转储请求对象，你会得到什么输出？
• 如果你转储响应对象，你会得到什么输出？

- edibleEnergy