VCL 组件的不透明度/透明度

Question

你是否可以使例如20％的透明度TMemo或其他vcl组件？像TButton或TEdit一样？

在搜索解决方案时，我找到了这个：

从这里开始，我想，如果我在表格上绘制图像（OnPaint），然后将AlphaBlend打开，我就可以实现这个效果，但是没有成功，当整个表格透明时，主要的需要效果没有实现，备忘录后面没有背景图片。

我想实现的效果是：（在Photoshop中完成）

这个可行吗？如果可以，怎么做？（我不要求任何人提供完整的源代码，只需要提供文章或小例子，或者指导方式，只要我能理解就行）

感谢关注。

---

我已经找到了解决方案，可以在带有图像背景的窗体上创建半透明窗体，然后在添加的窗体上添加备忘录并将其与客户端对齐。这不是最好的方法，但它可以正常工作：

procedure TForm1.Button1Click(Sender: TObject);
var
 MM : TMyMemo; frm : TForm;
begin
 frm := TForm.Create(Form1);
 frm.BorderStyle := bsNone;
 frm.AlphaBlend := true;
 frm.AlphaBlendValue := 150;
 frm.Left     := Form1.Left + 90;
 frm.Top      := Form1.Top + 90;
 frm.Width    := 300;
 frm.Height   := 300;
 frm.Position := poDesigned;
 frm.Visible := true;

 MM             := TMyMemo.Create(frm);
 MM.Parent      := frm;
 MM.BorderStyle := bsNone;
 MM.ParentColor := False;
 MM.Align       := alClient;
 MM.Color       := clBlack;
 MM.Font.Color  := clWhite;
 MM.Font.Name   := 'Sylfaen';
 MM.Font.Size   := 11;
 MM.Visible     := True;

 frme := True;
end;

但是还有另一个问题，当我点击备忘录时，背景窗体失去了焦点，当我将新窗体的父级设置为Form1时，上述问题得到解决，但透明效果消失了（窗口仍然透明，但可以透过背景窗口看到无可见的背景），我该如何解决这个问题？

- user2200585

---

如果TMemo是从TWinControl派生的，则它具有.Handle: HWND属性。也许您可以将其与Win32 GDI API一起使用，以强制TMemo进行Alpha混合。但是这可能会产生意想不到的副作用或兼容性要求。 - Arioch 'The

以上主题是如何制作的？有什么想法吗？ - user2200585

阅读编辑后的问题 - user2200585

Answer 1

我认为这个问题经常被问到（也许不是在这里，但我以前看过很多次）。奇怪的是，答案几乎从未出现，尽管它在所有讨论该问题的人中间隐藏着。也许这里的问题将有助于改进未来的搜索过程，只是因为它是stackoverflow :-)

无论如何，这是我去年找到的答案（见下面的代码）。不是我的，但对我有用-链接到author。基本上，该代码定义了一个具有自定义事件处理程序的派生richedit，用于WM_ERASEBACKGROUND消息。

unit TransparentRichEdit;

{ Component made by Proger_XP | http://Proger.i-Forge.net }

interface

uses
  Windows, Messages, SysUtils, Classes, Controls, StdCtrls, ComCtrls, Graphics;

type
  TTransparentRichEdit = class (TRichEdit)
  protected
    FCanvas: TCanvas;
    FBackground: TPicture;

    procedure CreateWnd; override;
    procedure WMEraseBkgnd(var Message: TWMEraseBkgnd); message WM_ERASEBKGND;

    procedure SetBackground(const Value: TPicture);
  public
    constructor Create(AOwner: TComponent); override;
    destructor Destroy; override;
  published
    property Background: TPicture read FBackground write SetBackground;
  end;

procedure Register;

implementation

procedure Register;
begin
  RegisterComponents('Miscellaneous', [TTransparentRichEdit]);
end;

{ TTransparentRichEdit }

constructor TTransparentRichEdit.Create(AOwner: TComponent);
begin
  inherited;
  FCanvas := TCanvas.Create;
  FBackground := TPicture.Create;
end;

destructor TTransparentRichEdit.Destroy;
begin
  FBackground.Free;
  FCanvas.Free;
  inherited;
end;

procedure TTransparentRichEdit.CreateWnd;
begin
  inherited;
  SetWindowLong(Handle, GWL_EXSTYLE, GetWindowLong(Handle, GWL_EXSTYLE) or WS_EX_TRANSPARENT);
end;

procedure TTransparentRichEdit.WMEraseBkgnd(var Message: TWMEraseBkgnd);
var
  UpdateRect: TRect;
  Rgn: HRGN;
  ToBeErased: Boolean;
  Mem: TBitmap;
begin
  ToBeErased:= false;
  Mem := TBitmap.Create;
  try
    Mem.Width := ClientWidth;
    Mem.Height := ClientHeight;

    FCanvas.Handle := Message.DC;
    Message.Result := 1;

    if not GetUpdateRect(Handle, UpdateRect, ToBeErased) then
      UpdateRect := Rect(0, 0, ClientWidth, ClientHeight);
    with UpdateRect do
      Rgn := CreateRectRgn(Left, Top, Right, Bottom);
    SelectClipRgn(FCanvas.Handle, Rgn);

    FCanvas.Draw(0, 0, FBackground.Graphic);
  finally
    Mem.Free;
  end;
end;

 procedure TTransparentRichEdit.SetBackground(const Value: TPicture);
 begin
   FBackground.Assign(Value);
   Repaint;
 end;

 end.

- SpaghettiCook

---

忘了提到，这种方法也适用于 TMemo 等组件。 - SpaghettiCook

我不想让背景完全透明，我想让它变成60-70%左右，这是问题所在。 - user2200585

@user2200585，你应该看一下普通表单处理透明度（即AlphaBlend）的方式。 - Peter