我可以在表单画布上绘制一些东西并覆盖表单上的控件吗？
我尝试了以下方法：
procedure TForm1.FormPaint(Sender: TObject);
var x,y: Integer;
begin
x := Mouse.CursorPos.X - 10;
y := Mouse.CursorPos.Y - 10;
x := ScreentoClient(point(x,y)).X - 10;
y := ScreenToClient(point(x,y)).Y - 10;
Canvas.Brush.Color := clRed;
Canvas.FillRect(rect(x, y, x + 10, y + 10));
Invalidate;
end;
矩形在其他控件绘制之前被绘制，因此它被隐藏在这些控件的后面（根据Delphi文档，这是预期的行为）。
我的问题是如何在控件上方绘制图形？
WM_PAINT，这当然会重新开始绘图处理。即使您不移动鼠标，您发布的代码示例也会一遍又一遍地运行 'OnPaint' 事件。由于您的绘图依赖于光标位置，因此您将使用 'OnMouseMove' 事件完成此操作。但是，您还需要拦截其他窗口控件的鼠标消息。以下示例使用 'ApplicationEvents' 组件，出于这个原因。如果您的应用程序将有多个窗体，则需要设计一种机制来区分您正在绘制的窗体。
另请参见文档，VCL 的 Invalidate 使整个窗口失效。您不需要这样做，您只是绘制一个小矩形，而且您知道您要绘制什么和已经绘制了哪些部分。只需使您要绘制和已绘制的位置无效。
至于在控件上绘图，实际上画图部分很容易，但是您不能使用提供的画布来完成。表单具有 WS_CLIPCHILDREN 样式，子窗口的表面将被从更新区域中排除，因此您必须使用 GetDCEx 或 GetWindowDC。正如评论中所提到的 'user205376'，擦除您所绘制的内容会有些棘手，因为您可能正在多个控件上绘制一个矩形。但是该 API 也有快捷方式，您将在代码中看到。
我尝试对代码进行了一些注释以便于跟踪，但省略了错误处理。实际绘画可以在 'OnPaint' 事件处理程序中完成，但未从 'TWinControl' 下降的控件在处理程序之后绘制。因此，在 WM_PAINT 处理程序中完成它。
type
TForm1 = class(TForm)
[..]
ApplicationEvents1: TApplicationEvents;
procedure FormCreate(Sender: TObject);
procedure ApplicationEvents1Message(var Msg: tagMSG; var Handled: Boolean);
private
FMousePt, FOldPt: TPoint;
procedure WM_PAINT(var Msg: TWmPaint); message WM_PAINT;
public
end;
var
Form1: TForm1;
implementation
{$R *.dfm}
procedure TForm1.FormCreate(Sender: TObject);
begin
// no rectangle drawn at form creation
FOldPt := Point(-1, -1);
end;
procedure TForm1.ApplicationEvents1Message(var Msg: tagMSG;
var Handled: Boolean);
var
R: TRect;
Pt: TPoint;
begin
if Msg.message = WM_MOUSEMOVE then begin
// assume no drawing (will test later against the point).
// also, below RedrawWindow will cause an immediate WM_PAINT, this will
// provide a hint to the paint handler to not to draw anything yet.
FMousePt := Point(-1, -1);
// first, if there's already a previous rectangle, invalidate it to clear
if (FOldPt.X > 0) and (FOldPt.Y > 0) then begin
R := Rect(FOldPt.X - 10, FOldPt.Y - 10, FOldPt.X, FOldPt.Y);
InvalidateRect(Handle, @R, True);
// invalidate childs
// the pointer could be on one window yet parts of the rectangle could be
// on a child or/and a parent, better let Windows handle it all
RedrawWindow(Handle, @R, 0,
RDW_INVALIDATE or RDW_UPDATENOW or RDW_ALLCHILDREN);
end;
// is the message window our form?
if Msg.hwnd = Handle then
// then save the bottom-right coordinates
FMousePt := SmallPointToPoint(TSmallPoint(Msg.lParam))
else begin
// is the message window one of our child windows?
if GetAncestor(Msg.hwnd, GA_ROOT) = Handle then begin
// then convert to form's client coordinates
Pt := SmallPointToPoint(TSmallPoint(Msg.lParam));
windows.ClientToScreen(Msg.hwnd, Pt);
FMousePt := ScreenToClient(Pt);
end;
end;
// will we draw? (test against the point)
if PtInRect(ClientRect, FMousePt) then begin
R := Rect(FMousePt.X - 10, FMousePt.Y - 10, FMousePt.X, FMousePt.Y);
InvalidateRect(Handle, @R, False);
end;
end;
end;
procedure TForm1.WM_PAINT(var Msg: TWmPaint);
var
DC: HDC;
Rgn: HRGN;
begin
inherited;
if (FMousePt.X > 0) and (FMousePt.Y > 0) then begin
// save where we draw, we'll need to erase before we draw an other one
FOldPt := FMousePt;
// get a dc that could draw on child windows
DC := GetDCEx(Handle, 0, DCX_PARENTCLIP);
// don't draw on borders & caption
Rgn := CreateRectRgn(ClientRect.Left, ClientRect.Top,
ClientRect.Right, ClientRect.Bottom);
SelectClipRgn(DC, Rgn);
DeleteObject(Rgn);
// draw a red rectangle
SelectObject(DC, GetStockObject(DC_BRUSH));
SetDCBrushColor(DC, ColorToRGB(clRed));
FillRect(DC, Rect(FMousePt.X - 10, FMousePt.Y - 10, FMousePt.X, FMousePt.Y), 0);
ReleaseDC(Handle, DC);
end;
end;
应用程序主窗口无法绘制在其他控件表面上。控件会定期绘制和擦除自己（基于控件的“绘制周期”）。
您的应用程序只能在允许应用程序这样做的控件上进行绘制。许多常见控件为应用程序提供了灵活性，以通过控件自定义绘制技术来自定义控件外观。
你不能这样做。
控件是绘制在它们的父窗口之上的。无论你在父窗口上绘制什么，都会被控件遮盖。不清楚为什么你需要进行这样的绘制；但是，也许你可以在表单内创建一个透明的控件并将其置于前端，然后在它的画布上绘制。这样你的绘图看起来就在表单和其他控件的顶部，但用户不能与表单上的其他控件交互，因为它们在透明控件的后面。
你不能这样做。你需要创建一个窗口控件（例如一个窗口），并将此窗口放在你想要绘制“在上面”的控件之上。然后你可以：
复制带有控件的窗体的位图，并将此位图用作此新控件的背景图像，或者
使此新窗口具有不规则形状，以便在某些不规则形状的区域外是透明的。
我做了一些涉及在我的表单上绘制组件周围手柄的事情，这是我所做的。
首先创建一个像这样的消息：
Const
PM_AfterPaint = WM_App + 1;
Procedure AfterPaint(var msg: tmsg); Message PM_AfterPaint;
Procedure AfterPaint(var msg: tmsg);
begin
{place the drawing code here}
ValidateRect(Handle, ClientRect);
end;
Validaterect 会告诉 Windows 不需要重绘你的窗体。你的绘画将导致窗体的一部分被 "invalidate"。ValidateRect 告诉 Windows 一切都是 "validate"。
最后一步，你还需要覆盖绘制过程。
Procedure Paint; Override;
Procedure TForm1.paint;
Begin
Inherited;
PostMessage(Handle, PM_AfterPaint, 0, 0);
End;
TMemo上放置一个TButton，您是否期望备忘录能够在按钮表面上绘制？如果您将 Microsoft WordPad 窗口放在 Microsoft Paint 窗口上方，您是否期望 Paint 窗口能够在 WordPad 窗口内部绘制？ - Andreas Rejbrand