如何在批处理文件中退出 SET /p 命令

Question

如何在批处理文件中退出 SET /p 命令

batch-filecmd

4

如何在一定时间后退出SET /p命令？例如，如果用户输入时间太长，我希望退出SET /p。

- user3746711

4个回答

2

基本上，你是不能的。

你可以尝试使用choice来接受单个字符并设置等待超时时间。

- Magoo

0

下面是一个批处理-JScript混合脚本，可以实现你想要的功能。JScript已经随着Windows XP及以后的每个版本一同安装。请将此文件保存为.bat扩展名。

@if (@CodeSection == @Batch) @then


@echo off
rem Give the desired wait time in milliseconds:
start "" /B Cscript //nologo //E:JScript "%~F0" 10000
set "input=Time out"
set /P "input=You have 10 seconds to complete this input: "
echo Input read: %input%
goto :EOF


@end


WScript.Sleep(WScript.Arguments(0));
WScript.CreateObject("WScript.Shell").SendKeys("{ENTER}");

- Aacini

这个解决方案只有在发送Enter按键时，焦点在控制台窗口上时才“有效”。因此，这不是一个真正健壮的解决方案。 - Bill_Stewart

@Bill_Stewart 这可能是你能得到的最好的。 - John DOE

@JohnDOE - 在我看来，editv32/editv64是更好、更强大的解决方案。 - Bill_Stewart

如果允许下载工具，则Aacini的答案默认有效，这也是您可以获得的“最佳”结果。 - John DOE

@Bill_Stewart：你说得对。我在我的新答案中解决了这个问题。感谢您指出这个问题。;) - Aacini

显示剩余2条评论

0

如果允许使用可下载工具，则可以使用 editv64.exe（64 位）或 editv32.exe（32 位），并带上 -t 参数。例如：

editv64 -p "Enter something within 10 seconds: " -t 10 INP

这个工具还有其他的优点，比如在输入时隐藏输入字符串（-m），以及可以交互地编辑现有的环境变量。你可以在这里下载：

http://www.westmesatech.com/editv.html

- Bill_Stewart

网页内容由stack overflow 提供, 点击上面的

可以查看英文原文，
原文链接

- Aacini · Accepted Answer

这是一个纯批处理方案，避免了使用Batch-JScript混合脚本时在未聚焦原始窗口时导致的问题。

@echo off
setlocal EnableDelayedExpansion

rem Execute a SET /P command with time out
rem Antonio Perez Ayala

rem If this file is re-executed as pipe's right side, go to it
if "%~1" equ "TimeoutMonitor" goto %1

del InputLine.txt 2> NUL
(
   set /P "line=You have 10 seconds to complete this input: " > CON
   > InputLine.txt call set /P "=%%line%%" < NUL
) 2> NUL | "%~F0" TimeoutMonitor 10
set /P "line=" < InputLine.txt
del InputLine.txt
echo Line read: "!line!"
goto :EOF


:TimeoutMonitor

rem Get the PID of pipe's left side
tasklist /FI "IMAGENAME eq cmd.exe" /FO TABLE /NH > tasklist.txt
for /F "tokens=2" %%a in (tasklist.txt) do (
   set "leftSidePipePID=!lastButOnePID!"
   set "lastButOnePID=%%a"
)
del tasklist.txt

rem Wait for the input line, or until the number of seconds passed
for /L %%i in (1,1,%2) do (
   ping -n 2 localhost > NUL
   if exist InputLine.txt exit /B
)

rem Timed out: kill the SET /P process and create a standard input line
taskkill /PID %leftSidePipePID% /F > NUL
echo/
echo Timed Out> InputLine.txt

exit /B