Windows批处理文件：将结构体转换为单行字符串

Question

Windows批处理文件：将结构体转换为单行字符串

3

我需要将这个艰巨的任务作为批处理文件完成，用C语言做这件事并不是最难的，但在DOS中却很麻烦（至少对我来说是这样！）我需要将一个结构体转换为单个变量（字符串），以便能够在程序内再次将其转换为该结构体。不用担心返回值，已经完成了。

结构体的大小会变化，并且其中有一个索引 [0]，需要成为我的变量中的第一项。

以下是这些结构的示例（仅显示3个）：

level.waypoints[0] = spawnstruct();
level.waypoints[0].origin = (1774.5,834.7,67.6);
level.waypoints[0].type = "stand";
level.waypoints[0].childCount = 2;
level.waypoints[0].children[0] = 1;
level.waypoints[0].children[1] = 6;
level.waypoints[1] = spawnstruct();
level.waypoints[1].origin = (1780.6,639.1,65.5);
level.waypoints[1].type = "stand";
level.waypoints[1].childCount = 2;
level.waypoints[1].children[0] = 7;
level.waypoints[1].children[1] = 0;
level.waypoints[2] = spawnstruct();
level.waypoints[2].origin = (1902.2,-345.2,74.2);
level.waypoints[2].type = "stand";
level.waypoints[2].childCount = 2;
level.waypoints[2].children[0] = 3;
level.waypoints[2].children[1] = 97;
level.waypoints[3] = spawnstruct();
level.waypoints[3].origin = ... (goes on...)

因此，第一个结构：

level.waypoints[0] = spawnstruct();
level.waypoints[0].origin = (1774.5,834.7,67.6);
level.waypoints[0].type = "stand";
level.waypoints[0].childCount = 2;
level.waypoints[0].children[0] = 1;
level.waypoints[0].children[1] = 6;

我需要将这个结构转换成这一行：

set flwp_0 "0,1774.5,834.7,67.6,stand,2,1,6"

0（flwp_）是索引，也是“”内的第一项。

因此，在这个例子中，另外两个将是：

set flwp_1 "1,1780.6,639.1,65.5,3,7,0,30"
set flwp_2 "2,1902.2,-345.2,74.2,2,3,97"

孩子数childCount可以是任何值，但我认为不会超过9。因此，我们有多少个childCount，下一行将有更多的孩子。

但我只需要childCount值后面的值，这样我就知道该字符串中还有多少可用项，所以没问题。

我考虑先删除我不需要的所有内容（按顺序）：

level.waypoints[
] = spawnstruct();
].origin = (
);
].type = "
";
].childCount = 
].children[0] = 
].children[1] = 
].children[2] = 
].children[3] = 
].children[4] = 
].children[5] = 
].children[6] = 
].children[7] = 
].children[8] = 
].children[9] = 
;

在第一个结构中，这将留下像这样的内容：

0
01774.5,834.7,67.6
0stand
02
01
06

现在我需要读取并将其转换为我的单行字符串。但是我遇到了问题，因为可能是第一个值，但如果索引具有2或3个字符怎么办？

我还考虑用一些信息替换来跟踪我，这样就不会替换掉文件中的“]”，这样我就知道在它之前的是索引，在它之后的是值。

我还尝试循环创建索引，但没有成功，例如：

level.waypoints[X]

X的取值范围为0到1000（我不认为会超过这个数字）

它不起作用，也许我的第一个想法更好...:\

我需要一个批处理文件（或几个文件），将具有内部结构的多个文件转换为新文件，并将详细信息中的数值转换为字符串。

有什么想法吗？

谢谢！

@Squashman 同时，结果的顺序有些混乱，如您所见：

set flwp_0 "0,1774.5,834.7,67.6,stand,2,1,6"
set flwp_100 "100,1636.76,371.924,240.125,stand,2,101,99"
set flwp_101 "101,1861.45,437.846,240.125,stand,2,102,100"
set flwp_102 "102,1843.93,557.03,240.125,stand,2,103,101"
set flwp_103 "103,1504.58,553.357,64.125,stand,2,8,102"
set flwp_104 "104,653.17,1675.32,64.125,stand,2,26,105"
set flwp_105 "105,338.784,1680.49,232.125,stand,2,104,133"
set flwp_106 "106,-919.398,1537.7,80.125,stand,3,107,109,150"
set flwp_107 "107,-928.311,1111.47,80.125,stand,3,108,106,149"
set flwp_108 "108,-696.488,1095.93,80.125,stand,2,36,107"
set flwp_109 "109,-787.781,1566.87,80.125,stand,2,106,110"
set flwp_10 "10,1423.3,-403.8,64.3,stand,4,11,12,15,3"
set flwp_110 "110,-754.274,1716.71,80.125,stand,2,109,34"
set flwp_111 "111,-736.201,1887.87,64.125,stand,4,112,34,151,152"
set flwp_112 "112,-454.293,1879.4,64.125,stand,4,111,33,34,152"
set flwp_113 "113,125.395,-451.579,58.6958,stand,3,51,114,142"
set flwp_114 "114,282.593,-447.87,68.125,stand,2,115,113"
set flwp_115 "115,304.311,-271.206,68.125,stand,2,116,114"
set flwp_116 "116,447.128,-292.167,68.125,stand,3,118,115,117"
set flwp_117 "117,437.415,-443.822,68.125,stand,2,67,116"
set flwp_118 "118,582.932,-297.811,126.125,stand,2,119,116"
set flwp_119 "119,561.586,-485.701,204.125,stand,2,120,118"
set flwp_11 "11,1240.1,-249.7,74.1,stand,5,9,16,10,12,15"
set flwp_120 "120,423.422,-470.754,204.125,stand,2,119,135"
set flwp_121 "121,1164.82,-1203.64,72.125,stand,4,123,14,126,122"
set flwp_122 "122,1064.12,-1299.76,72.125,stand,3,123,125,121"
set flwp_123 "123,1117.59,-1476.49,72.125,stand,3,124,122,121"
set flwp_124 "124,861.878,-1497.7,72.125,stand,2,125,123"
set flwp_125 "125,878.58,-1294.38,72.125,stand,2,124,122"

能否按正确的顺序写入文件？

非常感谢@Squashman再次提供帮助。

干杯！

好的，实际上顺序并不重要，但我在尝试将每个文件都写入一个新文件时遇到了麻烦……我尝试过但没有成功：

@echo off
 setlocal enabledelayedexpansion

for %%f in (*.gsc) do ( 

 FOR /F "tokens=1-2 delims==;^(^) " %%G IN (%%f) do set %%~G=%%~H
 FOR /F "tokens=2 delims=[]" %%G IN ('set level.waypoints ^|find /I "spawnstruct"') do (
    SET waypoints=!waypoints! %%G
 )

 FOR %%G IN (%waypoints%) do (
    set line=%%G,!level.waypoints[%%G].origin!,!level.waypoints[%%G].type!,!level.waypoints[%%G].childCount!
    FOR /F "tokens=2 delims==" %%H IN ('set level.waypoints[%%G].children') DO set line=!line!,%%H
    set line=set flwp_%%G "!line!"
    echo !line! >> %%f.cfg
 )

)
 pause

有什么线索吗？

=======================================

好的，现在我们非常接近了！只需要处理带有level.waypoints[的行，而其余部分必须被忽略，并且还要添加一个最终的关闭变量，我已经在下面成功地完成了：

@echo off
setlocal enableDelayedExpansion

set findtext="level.waypoints["
for %%F in (*.gsc) do (
  set "out="
  set "i=x"
  > "%%~nF.cfg" (
    for /f usebackq^ tokens^=2^,4^,5^ delims^=[]^=(^)^;^"^  %%A in ("%%F") do (
      if %%A neq !i! (
        if defined out echo !out!"
        set /a "i=%%A, j=0"
        set "out=set flwp_!i! "!i!"

      ) else (
        set /a j+=1
        if !j! leq 3 (set "out=!out!,%%B") else set "out=!out!,%%C"
      )

    )
    if defined out echo !out!"
    set /a "fim=i+1"
    echo set flwp_!fim! "eof"
  )
)

现在我该如何将 findstr %findtext% 添加到这些循环中呢？我尝试了很多不同的方式，但语法是错误的...你能帮我吗？:D

非常感谢@Squashman和@dbenham迄今为止提供的所有帮助。

干杯

- Hajas

“DOS” 是指 Windows 命令提示符 cmd，对吗？ - aschipfl

是的！抱歉！一个在Windows下运行的批处理文件。 :D - Hajas

1

根据您提供的输入示例，航路点1和2的输出示例看起来不正确。 - Squashman

当您提出问题时，提供准确的数据示例确实会有所帮助。 - Squashman

@Squashman 文件的其余部分都是以//开头的注释或者在/* ... */块内的多行注释。文件中还有函数名，所有结构都在其中...就像function() { -我发布的结构- }。这是一个gsc文件（C#）。我们非常接近了，只需要处理包含字符串level.waypoints[的行。我尝试过for %%F in (findstr %findtext% *.gsc) do (...但没有成功。你能帮我解决一下吗？请看一下我最后编辑的代码。谢谢！ - Hajas

2个回答

2

这里是一个相对快速的纯批处理解决方案，使用单个FOR /F循环处理每个文件。它比Squashman的解决方案要快得多。

我设置DELIMS和TOKENS来解析出所有需要的数据元素，无论我解析哪一行。我不关心childCount的值。相反，我只是检测航路点索引的变化来表示新记录的开始，并且递增的航路点行号（j变量）用于识别每行所需的令牌。每行都向out变量添加新文本。

@echo off
setlocal enableDelayedExpansion
for %%F in (*.gsc) do (
  set "out="
  set "i=x"
  > "%%~nF.cfg" (
    for /f usebackq^ tokens^=2^,4^,5^ delims^=[]^=(^)^;^"^  %%A in ("%%F") do (
      if %%A neq !i! (
        if defined out echo !out!"
        set /a "i=%%A, j=0"
        set "out=set flwp_!i! "!i!"
      ) else (
        set /a j+=1
        if !j! leq 3 (set "out=!out!,%%B") else set "out=!out!,%%C"
      )
    )
    if defined out echo !out!"
  )
)

上述内容可以在我的计算机上处理一个23 MB的文件，用时70秒。

但是如果您允许自己超出纯批处理的范围，我可以做得更好。这里是一个高效的JREPL.BAT解决方案，利用了刚刚发布的新版本6.0的特性。 JREPL.BAT是Windows的正则表达式文本处理实用程序。它是纯脚本（混合批处理/Jscript），可以在任何从XP开始的Windows机器上本地运行。不需要第三方exe文件。

通过jrepl /？或jrepl /??命令，可以在命令行中获取详细的文档帮助。

该解决方案应该能够处理接近1 GB大小的文件。每个文件通过单个对JREPL.BAT的调用完全处理。它应该非常高效，因为需要最小化回溯。对于小文件，由于CSCRIPT引擎的启动时间，它会比纯批处理方法慢一些。但对于大文件，它比纯批处理快得多。

下面的代码在仅11秒内处理了相同的23 MB文件 :-)

此第一个版本将复杂正则表达式术语的构建分解为步骤，并在每个捕获组上方包含带注释的数字，以便您有机会理解其工作原理。特别是，请阅读/T和/P选项的文档。并且加强你的正则表达式技能！

@echo off
setlocal

set "filter=(.*?\[\d+])[\s\S]*?(?:\n(?!\1)|(?![\s\S]))"

::   1           2                3                  4
set "find1=l.*?\[(\d+)\][\s\S]*?\((\d.*?)\)[\s\S]*?\q(.*?)\q"
set "repl1=set flwp_$2 \q$2,$3,$4"

::   5                 6
set "find2=;[\s\S]*? = (\d+)"
set "repl2=,$6"

::   7
set "find3=[\s\S]+"
set "repl3=\q\n"

set "find=%find1%|%find2%|%find3%"
set "repl=%repl1%|%repl2%|%repl3%"

for %%F in (*.gsc) do (
  call jrepl.bat "%find%" "%repl%" /t "|" /p "%filter%" /x /m /f "%%F" /o "%%~nF.cfg"
)

这是相同的解决方案，但没有显示任何中间步骤。我使用了行继续进行改进可读性。

@echo off
for %%F in (*.gsc) do (
  call jrepl.bat "l.*?\[(\d+)\][\s\S]*?\((\d.*?)\)[\s\S]*?\q(.*?)\q|;[\s\S]*? = (\d+)|[\s\S]+"^
                 "set flwp_$2 \q$2,$3,$4|,$6|\q\n"^
                 /p "(.*?\[\d+])[\s\S]*?(?:\n(?!\1)|(?![\s\S]))"^
                 /t "|" /x /m /f "%%F" /o "%%~nF.cfg"
)

我想最快的脚本解决方案可能是一个定制的 JScript 或 VBS 脚本。但我喜欢使用 JREPL :-)

更新：这里有一个额外的奖励 - 一个 JREPL 脚本，可以将 *.cfg 转换回 *.gsc。

@echo off
setlocal

set "beg=var pre,i,q='\x22',n='\r\n'"

::        1     2     3             4     5     67
set "find=^.*?\q(\d+),(.*?,.*?,.*?),(.*?),(.*?),|(.*?)[,\q]"

set "repl=i=0;pre='level.waypoints['+$2+']';$txt=pre+' = spawnstruct();'"
set "repl=%repl%+n+pre+'.origin = ('+$3+');'"
set "repl=%repl%+n+pre+'.type = '+q+$4+q+';'"
set "repl=%repl%+n+pre+'.childCount = '+$5+';'"
set "repl=%repl%|$txt=n+pre+'.children['+(i++)+'] = '+$7+';'"

for %%F in (*.cfg) do (
  call jrepl.bat "%find%" "%repl%" /x /t "|" /jq /jbeg "%beg%" /f "%%F" /o "%%~nF.gsc"
)

- dbenham

哇！太棒了！可以添加最后一行吗？例如，最后一个索引是150，所以将最后一行添加为set flwp_151 "eof"？我现在会尝试JREPL。非常感谢@dbenham！:D - Hajas

另外一件事，对于文件中每一行不是这种格式（无用的）的内容，都会打印“set flwp_0“0”"，是否可能只在发现行中出现“level.waypoints[”时处理/打印，以避免生成的文件中出现垃圾？再次感谢！ - Hajas

我尝试使用JREPL，但只有在我事先从所有行中删除缩进时才起作用。我只对具有 level.waypoints[ 的行感兴趣，所有其他行都必须被忽略。再次感谢您的帮助。 - Hajas

好的，我已经更新了问题，现在只需要知道如何将 findstr %findtext% 输入到循环中（或者其他只处理包含字符串 level.waypoints[ 的行的解决方案）。缩进也必须被忽略。再次非常感谢！ - Hajas

网页内容由stack overflow 提供, 点击上面的

可以查看英文原文，
原文链接

- Squashman · Accepted Answer

已根据您的新要求编辑了代码。

 @echo off

 FOR %%F IN (*.gsc) DO (
    setlocal enabledelayedexpansion
    FOR /F "usebackq tokens=1-2 delims==;^(^) " %%G IN (`find /I "level.waypoints["^<"%%F"`) do set %%~G=%%~H
    (FOR /F "tokens=2 delims=[]" %%G IN ('find /I "spawnstruct" ^<"%%F"') do (
        set line=%%G,!level.waypoints[%%G].origin!,!level.waypoints[%%G].type!,!level.waypoints[%%G].childCount!
        FOR /F "tokens=2 delims==" %%H IN ('set level.waypoints[%%G].children') DO set line=!line!,%%H
        set line=set flwp_%%G "!line!"
        echo !line!
    ))>"%%~nF.cfg"
    endlocal
 )
 pause