如何使用Ring服务流式传输PDF

Question

我想通过ring/compojure直接提供由clj-http生成的文档。

我以为使用ring.util/piped-output-stream可以解决问题，但似乎我对此还不够了解...

下面是代码：

(defn laminat-pdf-t
  [natno]
  (piped-input-stream
   (fn [output-stream])
   (pdf
    [ {:title (str "Omanimali-Kuscheltierpass" natno)
       :orientation :landscape
       :size :a6
       :author "Omanimali - Stefanie Tuschen"
       :register-system-fonts true
       }
      ;; [:svg {} (clojure.java.io/file
      ;;           (str "/einbuergern/" natno "/svg" ))]
      [:paragraph "Some Text"]      ]
    output-stream)))

(defn laminat-pdf
  "generate individualized cuddly toy passport page"
  [natno]
  {:headers {"Content-Type" "application/pdf"}
   :body (laminat-pdf-t natno)})

导致空响应...

我需要做些什么不同的事情吗？

谢谢，

马蒂亚斯

- mathiasp

Answer 1

我认为您的代码中可能有一个括号放错了位置（请看下面的laminat-pdf-t函数 - 我稍微调整了一下）。以下是我所做的事情（首先使用leiningen 2.3.4创建了一个名为pdf-play的项目），在Windows上的IE 11.0.9600.16521、Firefox 28.0和Chrome 33.0.1750.154上正确显示了PDF（很抱歉，这些是我唯一安装的浏览器，我没有Linux或Mac电脑，但我认为浏览器不会有任何影响）：

project.clj

(defproject pdf-play "0.1.0-SNAPSHOT"
  :dependencies [[org.clojure/clojure "1.5.1"]
                 [compojure "1.1.6"]
                 [clj-pdf "1.11.15"]]
  :plugins [[lein-ring "0.8.10"]]
  :ring {:handler pdf-play.handler/app})

src/pdf_play/handler.clj

(ns pdf-play.handler
  (:use compojure.core
        ring.util.io
        clj-pdf.core)
  (:require [compojure.handler :as handler]
            [compojure.route :as route]))

(defn laminat-pdf-t
  [natno]
  (piped-input-stream
   (fn [output-stream]
     (pdf
       [{:title (str "Omanimali-Kuscheltierpass" natno)
         :orientation :landscape
         :size :a6
         :author "Omanimali - Stefanie Tuschen"
         :register-system-fonts true
         }
         ;; [:svg {} (clojure.java.io/file
         ;;           (str "/einbuergern/" natno "/svg" ))]
         [:paragraph "Some Text"]]
       output-stream))))

(defn laminat-pdf
  "generate individualized cuddly toy passport page"
  [natno]
  {:headers {"Content-Type" "application/pdf"}
   :body (laminat-pdf-t natno)})

(defroutes app-routes
  (GET "/" [] (laminat-pdf 1234))
  (route/resources "/")
  (route/not-found "Not Found"))

(def app (handler/site app-routes))

然后在命令提示符下启动它，如下所示：

lein ring server

我在浏览器中看到了一个 PDF 文件，其中印有 "Some Text"。

- kmp