使用VB6调用带有OUT参数的MySQL存储过程

Question

我在MySQL（服务器版本5.5）中编写了这个过程。

DELIMITER $$

DROP PROCEDURE IF EXISTS `InsertList` $$

CREATE DEFINER=`root`@`localhost` PROCEDURE `InsertList`(IN fName VARCHAR(20), IN fType VARCHAR(3), IN fFood varchar(20), Out fResult int)

BEGIN

  insert into tblguest (firstname, confirm, food) values (fName, fType, fFood);

  select count(id) from tblguest into fResult;

END $$

DELIMITER ;

当我在MySQL Query Browser中调用这个过程时，它会返回预期的结果。

Call InsertList ('V1', 'No', 'F1', @result);

Select @result; 

--> 它成功地返回了表中id的计数

我用VB6编写了以下代码

Dim res As Integer
On Error GoTo chkErr

Set cmd = New ADODB.Command
cmd.ActiveConnection = cn
cmd.CommandType = adCmdStoredProc
cmd.CommandText = "InsertList"

cmd.Parameters.Append cmd.CreateParameter("fName", adVarChar, adParamInput, 20, Text3.Text)
cmd.Parameters.Append cmd.CreateParameter("fType", adVarChar, adParamInput, 3, Text2.Text)
cmd.Parameters.Append cmd.CreateParameter("fFood", adVarChar, adParamInput, 20, Text1.Text)
cmd.Parameters.Append cmd.CreateParameter("fResult", adInteger,adParamOutput)

cmd.Execute

res = cmd("fResult")
MsgBox res
Exit Sub

chkErr:

    Select Case Err.Number
        Case Else
            Text4.Text = Err.Number & " - " & Err.Description
    End Select

但是当它尝试运行语句cmd.execute时，它会抛出以下错误：

-2147467259 - [MySQL][ODBC 5.1 Driver][mysqld-5.5.34] dbtest.InsertList存储过程的第4个OUT或INOUT参数不是BEFORE触发器中的变量或NEW伪变量。

我已经看到适用于SQL的代码可以工作，那么是否是MySQL本身在使用带有OUT参数的存储过程时存在问题？

- Vikkas Miittal

---

另外，请注意，如果我修改该过程并删除“OUT”参数，则可以正常运行并将数据插入表中...因此它与“OUT”参数有关。 - Vikkas Miittal

Answer 1

似乎是MySQL ODBC和C/API的未解决bug。

一个解决方案是使用带有准备变量的SQL命令来执行它：

Dim rs As ADODB.Recordset 

Set cmd = New ADODB.Command
cmd.ActiveConnection = cn
cmd.CommandType = adCmdText
cmd.CommandText = "call InsertList(?,?,?,@fResult)"

cmd.Parameters.Append cmd.CreateParameter("fName", adVarChar, adParamInput, 20, Text3.Text)
cmd.Parameters.Append cmd.CreateParameter("fType", adVarChar, adParamInput, 3, Text2.Text)
cmd.Parameters.Append cmd.CreateParameter("fFood", adVarChar, adParamInput, 20, Text1.Text)

cmd.Execute

'And after that, using the same connection, get the value of 
'@fResult from a single query:

Set rs = cn.Execute("select @fResult as fResult")
MsgBox rs!fResult

您将获得期望值。

- Ivan Cachicatari