在Delphi中根据字段值更改DBGRID行颜色

Question

在Delphi中根据字段值更改DBGRID行颜色

delphicolorsdbgridtdbgrid

4

如何在 Delphi 中更改具有相同字段值的 dbgrid 行的颜色？

例如，所有具有相同教师的行。

注意：这些行已分组，并在 dbgrid 中彼此相邻。

先感谢您。

- teocka

1个回答

网页内容由stack overflow 提供, 点击上面的

可以查看英文原文，
原文链接

- Peter · Accepted Answer

您可以轻松地使用DBGrid的onDrawColumnCell事件来实现此操作：

procedure TForm1.DBGrid1DrawColumnCell(Sender: TObject; const Rect: TRect;
  DataCol: Integer; Column: TColumn; State: TGridDrawState);
begin
 if Table1.FieldByName('Teacher').AsString = 'Joe'
 then
  DBGrid1.Canvas.Brush.Color:=clRed;
 DBGrid1.DefaultDrawColumnCell(Rect, DataCol, Column, State);  

end;

不过，如果您不知道教师的名称，那么您将需要实现某种递归操作，这是我的实现：

var TeacherStringList : TStringList;
    lastColorUsed : TColor;
    AColors : Array of TColor;


function mycolor: TColor;
begin
  result := RGB(Random(256), Random(256), Random(256));
end;

procedure TForm3.Button1Click(Sender: TObject);
var CurrS : String;
    Index : Integer;
begin

  if TeacherStringList.Count <> 0 then TeacherStringList.Clear;
  Table1.DisableControls;
  try
    while not Table1.Eof do
    begin

      CurrS := Table1.FieldByName('Teacher').AsString;
      if (not TeacherStringList.Find(CurrS,Index)) and (not currS.IsEmpty)
      then  TeacherStringList.Add(CurrS);
      Table1.Next;

    end;
    Table1.First;
    SetLength(AColors,TeacherStringList.Count);
    for Index := Low(AColors) to High(AColors)
    do AColors[Index] := mycolor;

  finally
    Table1.EnableControls;
  end;

end;

procedure TForm3.DBGrid1DrawColumnCell(Sender: TObject; const Rect: TRect;
  DataCol: Integer; Column: TColumn; State: TGridDrawState);
var Index : integer;

begin

  if (TeacherStringList.Find(Table1.FieldByName('Teacher').AsString,Index))
  then 
    DBGrid1.Canvas.Brush.Color:= AColors[index];

  DBGrid1.DefaultDrawColumnCell(Rect, DataCol, Column, State);

end;

procedure TForm3.FormCreate(Sender: TObject);
begin
  teacherStringList := TStringList.Create;
  teacherStringList.Sorted := True;
end;

procedure TForm3.FormDestroy(Sender: TObject);
begin
  teacherStringList.Free;
end;