logo标签列表

获取字符串输入并使用DOS中断显示输入（MASM）

stringassemblyinputkeyboardmasm
4
在MASM中，我创建了一个缓冲变量来保存从键盘输入的用户字符串。我不知道如何将字符串输入保存到该缓冲变量中。我没有像irvine这样的库链接，并希望使用DOS中断完成此操作。到目前为止，我的一些代码大致如下：
            .model small

            .stack 100h

            .data
buff        db  25 dup(0), 10, 13
lbuff       EQU ($ - buff)              ; bytes in a string

            .code
main:
            mov ax, @data
            mov ds, ax              

            mov ah, 0Ah         ; doesn't work
            mov buff, ah        ; doesn't seem right
            int 21h                 


            mov     ax, 4000h       ; display to screen
            mov     bx, 1           
            mov     cx, lbuff           
            mov     dx, OFFSET buff     
            int     21h 

            mov ah, 4ch
            int 21h

            end main

我认为使用0Ah是正确的，因为它适用于读取缓冲字符输入数组。

int 21h/0Ah 需要在 dx 中提供缓冲区的地址。缓冲区中的第一个字节需要是最大输入值。通过将 ah 填充到其中，您已经指定了您想要十个字符（可能需要更多）。在中断返回后，第二个字节是实际输入的字符数。输入文本从缓冲区 +2 开始。 - Frank Kotler
@FrankKotler 好的，我部分地通过执行mov dx，offset 25 mov ah，0Ah int 21h（抱歉，我不确定如何在评论中格式化此内容）使其工作。那么输入的字符从dx + 2开始？我该如何将其移动到我的buff变量中？ - Jumpman
输入函数需要在dx寄存器中传递缓冲区的起始位置，例如"mov dx, OFFSET buff"，并将最大输入值存储在缓冲区的第一个字节中，例如"mov [buff], ah"，限制为10个字符。输出函数需要"mov dx, OFFSET buff+2"，以及实际输入的字符数"mov cl, [buff+1]"。 - Dirk Wolfgang Glomp
@DirkWolfgangGlomp 所以，不是 mov dx, OFFSET buff，而应该是 mov dx, OFFSET buff+2，因为字符串从2个字节之后开始。然后 mov cx, lbuff 需要变成 mov cl, [buff+1]，因为这样可以在字符串移动 +2 之后得到正确的长度，对吗？那么我在哪里执行 mov [buff], ah？是在 mov ah, 0Ah 之前吗？ - Jumpman
4个回答
11

我对你的代码进行了一些修改。首先，“buff”变量需要三级格式（允许的最大字符数，另外一个字节用于输入的字符数以及缓冲区本身），因为这是0AH服务所需的。为了使用0AH服务，我添加了“offset buff”（正如Wolfgang所说）。这是代码：

            .model small

            .stack 100h

            .data

buff        db  26        ;MAX NUMBER OF CHARACTERS ALLOWED (25).
            db  ?         ;NUMBER OF CHARACTERS ENTERED BY USER.
            db  26 dup(0) ;CHARACTERS ENTERED BY USER.

            .code
main:
            mov ax, @data
            mov ds, ax              

;CAPTURE STRING FROM KEYBOARD.                                    
            mov ah, 0Ah ;SERVICE TO CAPTURE STRING FROM KEYBOARD.
            mov dx, offset buff
            int 21h                 

;CHANGE CHR(13) BY '$'.
            mov si, offset buff + 1 ;NUMBER OF CHARACTERS ENTERED.
            mov cl, [ si ] ;MOVE LENGTH TO CL.
            mov ch, 0      ;CLEAR CH TO USE CX. 
            inc cx ;TO REACH CHR(13).
            add si, cx ;NOW SI POINTS TO CHR(13).
            mov al, '$'
            mov [ si ], al ;REPLACE CHR(13) BY '$'.            

;DISPLAY STRING.                   
            mov ah, 9 ;SERVICE TO DISPLAY STRING.
            mov dx, offset buff + 2 ;MUST END WITH '$'.
            int 21h

            mov ah, 4ch
            int 21h

            end main

当0AH从键盘捕获字符串时，它以ENTER（字符13）结束。因此，如果您想捕获25个字符，您必须指定26个。

要知道用户输入的字符数（长度），请访问第二个字节（偏移量为buff + 1）。ENTER不包括在内，因此，如果用户键入8个字符和ENTER，则第二个字节将包含数字8，而不是9。

输入的字符从偏移量buff + 2开始，并在字符13出现时结束。我们使用这个将长度添加到buff + 2 + 1，以将chr(13)替换为“$”。现在我们可以显示字符串了。

是的：这三行代码都在buff变量中。是的：如果你想修改字符串中的字符，你必须让SI指向buff+2。 - Jose Manuel Abarca Rodríguez
使用40h或4000h（我不确定为什么是4000h，它是我的参考资料的一部分）而不是使用09h函数会更容易，这样字符串末尾就不必有'$'。据我所知，缺点是即使用户没有输入全部25个字符，它也会显示所有25个字符。 - Jumpman
如果你知道长度，你可以使用ah = 13h和int 10h（像这个答案http://stackoverflow.com/questions/29460318/how-to-print-colored-string-in-assembly-language/29478158#29478158），但是如果你不想担心长度，你可以使用$。我从未尝试过40h或4000h。 - Jose Manuel Abarca Rodríguez
1
@JoseManuelAbarcaRodriguez，你不必执行从22到29步骤，在CH（13）处放置$。你可以简单地将db 26 dup(0)替换为db 26 dup('$')。 - Hamza Anis
2

这是我的代码，也许可以帮助你。

;Input String Copy output

dataarea segment
    BUFFER db 81
           db ?
    STRING DB 81 DUP(?)
    STR1 DB 10,13,'$'   
dataarea ends

extra segment
    MESS1 DB 'After Copy',10,13,'$'
    MESS2 DB 81 DUP(?)
extra ends

code segment
main proc far
    assume cs:code,ds:dataarea,es:extra
start:
    push ds
    sub ax,ax
    push ax

    mov ax,dataarea   
    mov ds,ax

    mov ax,extra      
    mov es,ax

    lea dx,BUFFER     
    mov ah,0ah
    int 21h

    lea si,STRING
    lea di,MESS2
    mov ch,0
    mov cl,BUFFER+1
    cld
    rep movsb
    mov al,'$'
    mov es:[di],al

    lea dx,STR1            ;to next line
    mov ah,09h
    int 21h

    push es
    pop ds

    lea dx,MESS1           ;output:after copy
    mov ah,09h
    int 21h

    lea dx,MESS2
    mov ah,09h
    int 21h

    ret
main endp
code ends
    end start

结果如下：

c:\demo.exe
Hello World!
After Copy
Hello World!
0
你可以按照这段代码进行操作：
; Problem : input array from user

.MODEL SMALL
.STACK
.DATA
   ARR DB 10 DUB (?)     

.CODE
 MAIN PROC
    MOV AX, @DATA
    MOV DS, AX

    XOR BX, BX
    MOV CX, 5

    FOR: 
      MOV AH, 1
      INT 21H
      MOV ARR[BX], AL
      INC BX
    LOOP FOR

    XOR BX, BX
    MOV CX, 5

    PRINT:  
     MOV AX, ARR[BX] ;point to the  current index 

     MOV AH, 2       ;output
     MOV DL, AX  
     INT 21H     

     INC BX           ;move pointer to the next element 
    LOOP PRINT       ;loop until done

 MAIN ENDP
0

试试这个，它从用户输入中获取一个10个字符的字符串，并以以下方式显示它："Hello *10个字符的字符串输入"

.MODEL TINY
.CODE
.286
ORG 100h

    START:
     MOV DX, OFFSET BUFFER
     MOV AH, 0ah
     INT 21h
     JMP PRINT
     BUFFER DB 10,?, 10 dup(' ')

     PRINT:
     MOV AH, 02
     MOV DL, 0ah
     INT 21h
     MOV AH, 9
     MOV DX, OFFSET M1
     INT 21h
     XOR BX, BX
     MOV BL, BUFFER[1]
     MOV BUFFER [BX+2], '$'
     MOV DX, OFFSET BUFFER +2
     MOV AH, 9
     INT 21h

    M1: db 'Hello $'


 END START
 END
网页内容由stack overflow 提供, 点击上面的
可以查看英文原文，
原文链接