#将shell变量传递给awk可以用几种方法完成。其中一些方法比其他方法更好。这应该包括其中的大部分。如果您有评论,请在下方留言。 v1.5
使用 -v
选项(最佳方式,最具可移植性)
使用 -v
选项:(附注:在 -v
后面加一个空格,否则可移植性会较差。例如,awk -v var=
而不是 awk -vvar=
)
variable="line one\nline two"
awk -v var="$variable" 'BEGIN {print var}'
line one
line two
这应该与大多数的awk
兼容,并且变量也可以在BEGIN
块中使用:
如果你有多个变量:
awk -v a="$var1" -v b="$var2" 'BEGIN {print a,b}'
警告。正如Ed Morton所写,转义序列将被解释,因此\t
将变成一个真正的tab
而不是你要搜索的\t
。可以通过使用ENVIRON[]
或通过ARGV[]
访问来解决。
附注 如果您的分隔符中有竖线或其他正则表达式元字符,例如|?(
等,它们必须进行双重转义。例如,3个竖线|||
变成-F'\\|\\|\\|'
。您也可以使用-F"[|][|][|]"
。
从程序/函数中获取数据到awk
的示例(这里使用了日期)
awk -v time="$(date +"%F %H:%M" -d '-1 minute')" 'BEGIN {print time}'
测试将shell变量的内容作为正则表达式的示例:
awk -v var="$variable" '$0 ~ var{print "found it"}'
代码块后的变量
在这里,我们获取了awk
代码后的变量。只要您不需要在BEGIN
块中使用该变量,这将正常工作:
variable="line one\nline two"
echo "input data" | awk '{print var}' var="${variable}"
or
awk '{print var}' var="${variable}" file
awk '{print a,b,$0}' a="$var1" b="$var2" file
- 通过这种方式,我们还可以为每个文件设置不同的字段分隔符
FS
。
awk '一些代码' FS=',' file1.txt FS=';' file2.ext
echo "输入数据" | awk 'BEGIN {print var}' var="${variable}"
Here-string
变量也可以通过支持它们的shell(包括Bash)使用here-string添加到awk
中:
awk '{print $0}' <<< "$variable"
test
这与以下内容相同:
printf '%s' "$variable" | awk '{print $0}'
P.S. 这将变量视为文件输入。
ENVIRON
输入
正如 TrueY 所写,您可以使用 ENVIRON
来打印环境变量。
在运行 AWK 之前设置一个变量,您可以像这样打印出它:
export X=MyVar
awk 'BEGIN{print ENVIRON["X"],ENVIRON["SHELL"]}'
MyVar /bin/bash
或者对于一个未导出的变量:
x=MyVar
x="$x" awk 'BEGIN{print ENVIRON["x"],ENVIRON["SHELL"]}'
MyVar /bin/bash
ARGV
输入
正如 Steven Penny 所写,您可以使用 ARGV
将数据传入 awk:
v="my data"
awk 'BEGIN {print ARGV[1]}' "$v"
my data
将数据导入到代码本身中,而不仅仅是BEGIN部分。
v="my data"
echo "test" | awk 'BEGIN{var=ARGV[1];ARGV[1]=""} {print var, $0}' "$v"
my data test
代码中的变量:谨慎使用
你可以在awk
代码中使用变量,但这样做会使代码变得混乱且难以阅读。正如Charles Duffy
指出的那样,这个版本也可能成为代码注入的受害者。如果有人向变量中添加了不良内容,它将作为awk
代码的一部分被执行。
这种方法通过提取代码中的变量,使其成为代码的一部分。
如果你想要创建一个根据变量动态改变的awk
,可以这样做,但是请勿将其用于普通变量。
variable="line one\nline two"
awk 'BEGIN {print "'"$variable"'"}'
line one
line two
这是一个代码注入的例子:
variable='line one\nline two" ; for (i=1;i<=1000;++i) print i"'
awk 'BEGIN {print "'"$variable"'"}'
line one
line two
1
2
3
.
.
1000
你可以通过这种方式向awk添加许多命令。甚至可以使用非有效的命令使其崩溃。
然而,这种方法的一个有效用途是当你想要将一个符号传递给awk并应用于某些输入时,例如一个简单的计算器:
$ calc() { awk -v x="$1" -v z="$3" 'BEGIN{ print x '"$2"' z }'; }
$ calc 2.7 '+' 3.4
6.1
$ calc 2.7 '*' 3.4
9.18
没有办法使用一个由shell变量填充的awk变量来实现这个,你需要让shell变量在awk解释之前扩展成awk脚本的一部分。请参考下面Ed M.的评论。
额外信息:
使用双引号
在变量"$variable"
周围加上双引号是一个好习惯。
如果不这样做,多行文本会被合并成一行。
示例:
var="Line one
This is line two"
echo $var
Line one This is line two
echo "$var"
Line one
This is line two
其他错误您可以在没有双引号的情况下获得:
variable="line one\nline two"
awk -v var=$variable 'BEGIN {print var}'
awk: cmd. line:1: one\nline
awk: cmd. line:1: ^ backslash not last character on line
awk: cmd. line:1: one\nline
awk: cmd. line:1: ^ syntax error
而且使用单引号时,它不会展开变量的值。
awk -v var='$variable' 'BEGIN {print var}'
$variable
关于AWK和变量的更多信息
阅读此常见问题解答。
/var/
放进去。相反地,使用波浪号:awk -v var="$var" '$0 ~ var'
。 - Noam Manos/.../
分隔符表示字面意义的正则表达式,所以其中不会有任何扩展。如果您不想使用字面意义的正则表达式,则不要使用/.../
分隔符,而是使用"..."
和/或变量来创建动态正则表达式。 - Ed Morton