如何使QtQuick 2中的Canvas元素支持HiDPI（retina）显示？

Question

我有一个以下的 QML 应用程序：

import QtQuick 2.1
import QtQuick.Controls 1.0
import QtQuick.Layouts 1.0
import QtQuick.Window 2.0

ApplicationWindow {
    id: window
    width: 480
    height: 240


    RowLayout {

        Rectangle {
            width: window.height
            height: window.height
            radius: window.height / 2
            color: "black"
        }

        Canvas {
            id: canvas
            width: window.height
            height: window.height

            onPaint: {
                var ctx = canvas.getContext('2d');
                var originX = window.height / 2
                var originY = window.height / 2
                var radius = window.height / 2

                ctx.save();

                ctx.beginPath();
                ctx.arc(originX, originY, radius, 0, 2 * Math.PI);
                ctx.fillStyle = Qt.rgba(0, 0, 0, 1);
                ctx.fill();

                ctx.restore();
            }

        }
    }
}

这会产生两个相邻的黑色圆圈。左边的一个（矩形）在Retina显示器上非常清晰，而右边的一个（画布）则相当模糊。如果我添加

。

                antialiasing: false

在Canvas中，它产生了粗糙模糊的像素。

我需要做什么才能使Canvas具有HiDPI感知能力？

_{（我正在Mac OS X 10.8上使用Qt 5.2.0 beta 1）}

---

编辑：我想到的解决方法是将Canvas包装在一个Item中，在onPaint内部放大所有内容，然后在Canvas上使用一个transform将其缩小回来。

    Canvas {
        id: canvas
        x: 0
        y: 0
        width: parent.width * 2   // really parent.width after the transform
        heigth: parent.height * 2 // really parent.height after the transform

        /* ... */

        // This scales everything down by a factor of two.
        transform: Scale {
            xScale: .5
            yScale: .5
        }

        onPaint: {
            var ctx = canvas.getContext('2d');
            ctx.save();
            ctx.scale(2, 2)       // This scales everything up by a factor of two.

            /* ... */
        }
    }

- Tobias

Answer 1

我们在qml-material中使用了同样的技巧，即先将尺寸加倍，然后缩小比例。不过，你可以做出一些改进：

1. 使用scale而非transform。
2. 使用QtQuick.Window模块中的Screen.devicePixelRatio，而非将比例因子硬编码为2/0.5。

因此，你的代码可以简化为：

Canvas {
    property int ratio: Screen.devicePixelRatio

    width: parent.width * ratio
    heigth: parent.height * ratio
    scale: 1/ratio

    onPaint: {
        var ctx = canvas.getContext('2d');
        ctx.save();
        ctx.scale(ratio, ratio)

        // ...
    }
}

- iBelieve