在Jenkins声明式流水线中，是否有可能检查是否从特定代码库签出？

Question

在Jenkins声明式流水线中，是否有可能检查是否从特定代码库签出？

3

我希望我的Jenkinsfile中有一个发布阶段，仅在从原始代码库中检出时运行。这是为了避免在克隆的代码库上由于缺失密钥等问题而导致错误消息的出现。请注意保留HTML标记。

stage('Release')
 {
  when
   {
    allOf 
     {
      // TODO Check for repository url https://github.com/PowerStat/TemplateEngine.git
      branch 'master'
     }
   }
  steps
   {
    script
     {
      if (isUnix()) 
       {           
        sh 'mvn --batch-mode release:clean'
        sh 'mvn --batch-mode release:prepare'
        sh 'mvn --batch-mode release:perform'
       }
      else
       {
        bat 'mvn --batch-mode release:clean'
        bat 'mvn --batch-mode release:prepare'
        bat 'mvn --batch-mode release:perform'
       }
     }
   }
 }

我已经学习了Pipeline语法: when，但不知道如何实现我想要的测试。

我考虑使用环境变量全局变量参考，但没有找到包含存储库URL的变量。

所以我的问题是：如何在声明式流水线中实现此检查？

- PowerStat

1个回答

网页内容由stack overflow 提供, 点击上面的

可以查看英文原文，
原文链接

- Szymon Stepniak · Accepted Answer

你可以通过执行命令git config remote.origin.url获取远程存储库的URL。你可以在when块内使用expression指令来执行此命令 - 它定义了一个返回boolean值的闭包。

考虑以下示例：

def expectedRemoteUrl = "https://github.com/PowerStat/TemplateEngine.git"

pipeline {
    agent any

    stages {
        stage("Release") {
            when {
                allOf {
                    branch 'tmp'
                    expression {
                        def remoteUrl = isUnix() ?
                            sh(script: "git config remote.origin.url", returnStdout: true)?.trim() :
                            bat(script: "git config remote.origin.url", returnStdout: true)?.trim()

                        return expectedRemoteUrl == remoteUrl
                    }
                }
            }

            steps {
                echo "Do your release steps here..."
            }
        }
    }
}

或者，如果在运行管道的节点上没有可用的git命令，您可以使用scm.userRemoteConfigs?.first()?.url获取远程存储库的URL。请考虑以下示例：

def expectedRemoteUrl = "https://github.com/PowerStat/TemplateEngine.git"

pipeline {
    agent any

    stages {
        stage("Release") {
            when {
                allOf {
                    branch 'tmp'
                    expression {
                        def remoteUrl = scm.userRemoteConfigs?.first()?.url

                        return expectedRemoteUrl == remoteUrl
                    }
                }
            }

            steps {
                echo "Do your release steps here..."
            }
        }
    }
}