如何在单击按钮时动态将组件添加到TScrollBox中，使它们一个接一个地排列？

Question

我创建了一个TScrollBox。在按钮点击时，我动态地添加了标签和编辑框。为了设置组件的位置，我使用了组件的高度、宽度、左侧和顶部属性。但是当屏幕上出现滚动条后，添加了5个组件后，下一个组件的位置会被破坏。下一个组件不会以同步的方式放置在ScrollBox上。

- naren

---

应该有一些ScrollBox的属性，比如ScrollTop或ScrollWhatever。你可以从组件的新位置中减去它。 - Oleh Prypin

我找不到类似于ScrollTop的任何属性.. :( - naren

Answer 1

在滚动框上放置的控件的顶部坐标需要考虑已经滚动的量。如果一次性添加所有控件，则不会出现问题，因为滚动框没有机会“滚动”。

如果您在滚动框有机会“滚动”之后添加控件，则需要考虑垂直“滚动”的数量。下面是一段示例代码，它将标签添加到ScrollBox1中，考虑了垂直滚动，以便控件不会重叠。在这里，我使用窗体的“Tag”属性来保存下一个要添加的控件的Top，并且我还使用Tag为标签生成唯一名称（这样您就可以看到它们正在以正确的坐标进入滚动框中了）。

procedure TForm31.Button1Click(Sender: TObject);
var L: TLabel;
begin
  L := TLabel.Create(Self);
  L.Caption := 'Test: ' + IntToStr(Tag);
  L.Parent := ScrollBox1;
  L.Top := Tag + ScrollBox1.VertScrollBar.Size - ScrollBox1.VertScrollBar.Position;
  Tag := Tag + L.Height;
end;

我有时候采用的另一种方法是跟踪上一个添加的控件，并以该控件的坐标为基础计算新控件的坐标：

var LastControl: TControl;

procedure TForm31.Button1Click(Sender: TObject);
var L: TLabel;
begin
  L := TLabel.Create(Self);
  L.Caption := 'Test: ' + IntToStr(Tag);
  L.Parent := ScrollBox1;
  if Assigned(LastControl) then
    L.Top := LastControl.Top + LastControl.Height
  else
    L.Top := 0;
  Tag := Tag + L.Height;

  LastControl := L;
end;

另一种方法是找到最低的控件，并基于其坐标添加您的控件：

procedure TForm31.Button1Click(Sender: TObject);
var L: TLabel;
    Bottom, TestBottom: Integer;
    i: Integer;
begin
  // Find "Bottom"
  Bottom := 0;
  for i:=0 to ScrollBox1.ControlCount-1 do
    with ScrollBox1.Controls[i] do
    begin
      TestBottom := Top + Height;
      if TestBottom > Bottom then
        Bottom := TestBottom;
    end;
  L := TLabel.Create(Self);
  L.Caption := 'Test: ' + IntToStr(Tag);
  L.Parent := ScrollBox1;
  L.Top := Bottom;
  Tag := Tag + L.Height;
end;

- Cosmin Prund

---

谢谢，你帮了我一个类似的问题。 - Hein du Plessis