如何使用Indy在DNS中查找LDAP服务器？

Question

如何使用Indy在DNS中查找LDAP服务器？

4

使用Windows上的nslookup命令或Linux上的host命令，计算机可以查询DNS以获取LDAP服务器（请参见https://serverfault.com/questions/153526/how-can-i-find-the-ldap-server-in-the-dns-on-windows）。

是否可能使用Indy DNS解析器组件进行这些查询？

nslookup -type=srv _ldap._tcp.DOMAINNAME

或者

host -t srv _ldap._tcp.DOMAINNAME

- mjn

1个回答

网页内容由stack overflow 提供, 点击上面的

可以查看英文原文，
原文链接

- whosrdaddy · Accepted Answer

简单：

program SO18309621;

{$APPTYPE CONSOLE}

uses
  IdDNSResolver,
  SysUtils;

var
  Dns : TIdDNSResolver;
  Rec : TResultRecord;
  Srv : TSRVRecord;
  Index : Integer;
begin
  try
    Dns := TIdDNSResolver.Create;
    try
      Dns.Host := 'mydnsserver.mydomain';
      Dns.QueryType := [qtService];
      Dns.Resolve('_ldap._tcp.mydomain');
      for Index := 0 to Dns.QueryResult.Count - 1 do
      begin
        Rec := Dns.QueryResult[Index];
        if Rec is TSRVRecord then
        begin
          Srv := TSRVRecord(Rec);
          Writeln('Target=', Srv.Target, ', Port=', Srv.Port, ', Priority=', Srv.Priority, ', Weight=', Srv.Weight);
        end;
      end;
    finally
      Dns.Free;
    end;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.