在运行时删除创建的TLabel

Question

如何删除已创建的标签。我尝试使用FindComponent但失败了，我该怎么办？应该将其父级设置为其他组件，比如TPanel吗？

procedure TForm1.Button1Click(Sender: TObject);
var
  lblLink: TLabel;
begin
   for i := 0 to stringtList.Count-1 do
   begin 
     lblLink := TLabel.create(self);

     with lblLink do
     begin
       name:='lblLink'+inttostr(i);
       caption:inttostr(i);
       Parent := self;
       font.style := [fsUnderline];
       cursor := crHandPoint;
       color := clBlue;
       font.Color := clBlue;
     end;
   end;
end;

- Аймен Ахмед

---

我看不出FindComponent无法找到您的标签的原因，您是否传递了类似“lblLink0”的名称？ - Sertac Akyuz

是的，但这是个坏主意！因为标签数量取决于stringtList的计数，这显然是不稳定的。 - Аймен Ахмед

Answer 1

您可以遍历Components属性，检查组件名称，最后释放组件。

Var
  LIndex : Integer;
  LComponent : TComponent;
begin
  for LIndex := ComponentCount-1 downto 0 do
    if StartsText('lblLink',Components[LIndex].Name) then
    begin
     LComponent:=Components[LIndex];
     FreeAndNil(LComponent);
    end;
end;

- RRUZ

Answer 2

你不需要手动释放它，已经将释放的责任交给了使用lblLink := TLabel.create(self);创建该标签的窗体。当窗体被释放时，窗体会自动释放标签。

但是，如果需要手动释放，可以通过循环遍历窗体的Components数组来释放它：

procedure TForm1.DeleteLabel(const LabelName: string);
var
  i: Integer;
begin
  for i := ComponentCount - 1 downto 0 do
  begin
    if Components[i] is TLabel then
      if Components[i].Name = LabelName then
      begin
        Components[i].Free;
        Break;
      end;
  end;
end;

- Ken White

Answer 3

您为每个TLabel指定了Owner和Parent，因此在技术上，您根本不需要释放它们。 Owner和Parent会自动处理释放。 但是，如果您想提前释放它们，可以循环遍历Owner的Components列表或Parent的Controls列表，手动查找标签。更好的选择是保留您创建的标签的列表，然后在需要时可以循环遍历该列表，例如：

type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  ...
  private
    Labels: TList;
    procedure FreeLabels;
  ...
  end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  Labels := TList.Create;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  Labels.Free;
end;

procedure TForm1.FreeLabels;
var
  I: Integer;
begin
  for I := 0 to Labels.Count-1 do
    TLabel(Labels[I]).Free;
  Labels.Clear;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  lblLink : TLabel;
  ...
begin 
  ...
  for I := 0 to StringList.Count-1 do
  begin 
    lblLink := TLabel.Create(Self);
    try
      with lblLink do
      begin
        Name := 'lblLink' + IntToStr(i);
        Parent := Self;
        Caption := IntToStr(i);
        Font.Style := [fsUnderline];
        Cursor := crHandPoint;
        Color := clBlue;
        Font.Color := clBlue;
      end;
      Labels.Add(lblLink);
    except
      lblLink.Free;
      raise;
    end;
  end;
end;

- Remy Lebeau