编译Telegram源代码时出现“文件未找到”的错误提示

Question

编译Telegram源代码时出现“文件未找到”的错误提示

3

我正在尝试构建一个类似Telegram的应用程序。我下载了他们的源代码(https://github.com/DrKLO/Telegram)(适用于Android)。

我的主要问题是，在我尝试编译代码并将其导出到我的手机时，使用Android Studio，我收到以下错误:

错误：在任务':TMessagesProj:packageDebug'的配置中发现了问题。文件'C:\Users\Bogdan\Desktop\Telegram\Telegram-master\TMessagesProj\config\debug.keystore'指定为属性'signingConfig.storeFile'不存在。

显然缺少一个文件，但是哪个文件，如何解决这个问题？

谢谢！

P.S.你能提供一个类似于这个或类似于whatsapp的应用程序的源代码链接吗？

- Bogdan Mocanu

1个回答

网页内容由stack overflow 提供, 点击上面的

可以查看英文原文，
原文链接

- Mokhtarabadi · Accepted Answer

修改Telegram/TMessagesProj/build.gradle文件，并在gradle配置中删除或注释签名选项，如下所示：

apply plugin: 'com.android.application'

repositories {
    mavenCentral()
}

dependencies {
    compile 'com.android.support:support-v4:22.2.+'
    compile 'com.google.android.gms:play-services:3.2.+'
    compile 'net.hockeyapp.android:HockeySDK:3.5.+'
    compile 'com.googlecode.mp4parser:isoparser:1.0.+'
}

android {
    compileSdkVersion 22
    buildToolsVersion '22.0.1'

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_7
        targetCompatibility JavaVersion.VERSION_1_7
    }
/**
    signingConfigs {
        debug {
            storeFile file("config/debug.keystore")
        }

        release {
            storeFile file("config/release.keystore")
            storePassword RELEASE_STORE_PASSWORD
            keyAlias RELEASE_KEY_ALIAS
            keyPassword RELEASE_KEY_PASSWORD
        }
    }
*/
    buildTypes {
        debug {
            debuggable true
            jniDebuggable true
           // signingConfig signingConfigs.debug
        }

        release {
            debuggable false
            jniDebuggable false
            //signingConfig signingConfigs.release
        }

        foss {
            debuggable false
            jniDebuggable false
           // signingConfig signingConfigs.release
        }
    }

    sourceSets.main {
        jniLibs.srcDir 'libs'
        jni.srcDirs = [] //disable automatic ndk-build call
    }

    sourceSets.debug {
        manifest.srcFile 'config/debug/AndroidManifest.xml'
    }

    sourceSets.release {
        manifest.srcFile 'config/release/AndroidManifest.xml'
    }

    sourceSets.foss {
        manifest.srcFile 'config/foss/AndroidManifest.xml'
    }

    defaultConfig {
        minSdkVersion 8
        targetSdkVersion 22
        versionCode 572
        versionName "3.0.1"
    }
}