如何重命名运行mnesia数据库的节点

Question

如何重命名运行mnesia数据库的节点

14

我在machine1上创建了一个Mnesia数据库/架构。该节点的名称为mypl@machine1。由于machine1出现故障，我将所有文件移动到了machine2上。只要代码使用名称“mypl@machine1”运行，一切都正常运行。显然这有点混淆，因为现在它正在machine2上运行。

如果我使用节点名“mypl@machine2”启动Erlang，则Mnesia数据库似乎为空。

如何将Mnesia数据库中的节点从machine1重命名为machine2？

- mdorseif

2个回答

2

解决方法是迁移。只需启动mnesia集群并将所有表和模式迁移到其他节点。然后从原始节点中删除并忘记。

- Hynek -Pichi- Vychodil

网页内容由stack overflow 提供, 点击上面的

可以查看英文原文，
原文链接

- archaelus · Accepted Answer

我认为这个问题无法在单个节点上在线完成（有人可以吗？），但是可以通过备份/恢复以及运行两个节点并添加表副本来实现。在Mnesia用户指南第6.9.1节中，您会发现一些代码使用mnesia：traverse_backup在mnesia备份文件中修改模式表（如下所示）中的节点名称。您应该使用的模块名称可能是mnesia_backup。

使用此代码，您需要：

%% On mypl@machine1
mnesia:backup("/path/to/mnesia.backup").
change_node_name(mnesia_backup, mypl@machine1, mypl@machine2,
                 "/path/to/mnesia.backup", "/path/to/new.mnesia.backup").
%% On mypl@machine2
mnesia:restore("/path/to/new.mnesia.backup", []).

我不确定是否需要在mypl@machine2上先创建模式。

来自用户指南的更改节点名称代码：

change_node_name(Mod, From, To, Source, Target) ->
    Switch =
        fun(Node) when Node == From -> To;
           (Node) when Node == To -> throw({error, already_exists});
           (Node) -> Node
        end,
    Convert =
        fun({schema, db_nodes, Nodes}, Acc) ->
                {[{schema, db_nodes, lists:map(Switch,Nodes)}], Acc};
           ({schema, version, Version}, Acc) ->
                {[{schema, version, Version}], Acc};
           ({schema, cookie, Cookie}, Acc) ->
                {[{schema, cookie, Cookie}], Acc};
           ({schema, Tab, CreateList}, Acc) ->
                Keys = [ram_copies, disc_copies, disc_only_copies],
                OptSwitch =
                    fun({Key, Val}) ->
                            case lists:member(Key, Keys) of
                                true -> {Key, lists:map(Switch, Val)};
                                false-> {Key, Val}
                            end
                    end,
                {[{schema, Tab, lists:map(OptSwitch, CreateList)}], Acc};
           (Other, Acc) ->
                {[Other], Acc}
        end,
    mnesia:traverse_backup(Source, Mod, Target, Mod, Convert, switched).