在Word VBA中使用引用来动态创建控件

Question

我正在编写一个Word 2003表单，用于收集对同一问题的多个回答。我有一个按钮宏，按下后会复制各种输入字段（下拉框、单选按钮等），以准备接受新的回答。

然而，我需要更改单选按钮的文本，并在组合框上设置OnChange事件，但我无法找到正确的语法进行操作。这两个控件都来自“控件工具箱”工具栏。

下面是我用于复制控件的宏代码。

Private Sub CommandButton11_Click() 
Set Doc = ActiveDocument
Response = MsgBox("Add another response?", vbYesNo, "Confirm action")
    If Response = vbYes Then
        If Doc.ProtectionType <> wdNoProtection Then
          Doc.Unprotect
        End If

        Selection.MoveRight
        Selection.MoveDown
        Selection.TypeParagraph
        ''# keep the reference to this control and set the OnChange event handler
        Selection.InlineShapes.AddOLEControl ClassType:="Forms.ComboBox.1"
        Selection.MoveRight Unit:=wdCharacter, Count:=1
        Selection.TypeText Text:=vbTab
        Selection.TypeText Text:=vbTab
        ''# keep the reference to this control and set text
        Selection.InlineShapes.AddOLEControl ClassType:="Forms.OptionButton.1"
        Selection.MoveRight Unit:=wdCharacter, Count:=1

        Doc.Protect Type:=wdAllowOnlyFormFields, NoReset:=True
    End If
End Sub

- Marc

Answer 1

动态添加事件处理程序有点棘手。

您可以将代码动态添加到ThisDocument中。这是Microsoft描述的方法：http://support.microsoft.com/?scid=kb%3Ben-us%3B246299&x=14&y=10。然而，当我尝试在Word 2007中执行此操作时，它崩溃了。

另一种方法是为事件处理添加一个类，并为每个控件创建该类的实例。将以下代码放入模块中：

Option Explicit

Public objControls() As clsComboBox

Private Sub CommandButton11_Click()
    Dim objShape As InlineShape

    If ActiveDocument.ProtectionType <> wdNoProtection Then
        ActiveDocument.Unprotect
    End If

    Selection.MoveRight
    Selection.MoveDown
    Selection.TypeParagraph
    ' keep the reference to this control and set the OnChange event handler
    Set objShape = Selection.InlineShapes.AddOLEControl(ClassType:="Forms.ComboBox.1")
    With objShape.OLEFormat.Object
        .AddItem "Item 1"
        .AddItem "Item 2"
    End With

    Selection.MoveRight Unit:=wdCharacter, Count:=1
    Selection.TypeText Text:=vbTab
    Selection.TypeText Text:=vbTab
    ' keep the reference to this control and set text
    Set objShape = Selection.InlineShapes.AddOLEControl(ClassType:="Forms.OptionButton.1")
    With objShape.OLEFormat.Object
        .Caption = "My great option"
    End With
    Selection.MoveRight Unit:=wdCharacter, Count:=1

    ActiveDocument.Protect Type:=wdAllowOnlyFormFields, NoReset:=True

    ' we have to execute the creation of the event handlers with a delay
    ' to make it work (seems Word needs some time for object creation)
    Application.OnTime When:=Now + TimeValue("00:00:01"), Name:="prcCreateReference"

End Sub

Public Sub prcCreateReference()
    Dim objShape As InlineShape
    Dim intCount As Integer

    On Error Resume Next
    For Each objShape In ThisDocument.InlineShapes
        intCount = intCount + 1
        ReDim Preserve objControls(1 To intCount)
        If TypeOf objShape.OLEFormat.Object Is ComboBox Then
            Set objControls(intCount) = New clsComboBox
            Set objControls(intCount).ComboBox = objShape.OLEFormat.Object
        ElseIf TypeOf objShape.OLEFormat.Object Is OptionButton Then
            ' add event handlers for option buttons
        End If
    Next
End Sub

这段代码应该放在名为clsComboBox的类模块中:

Option Explicit

Private WithEvents mobjComboBox As MSForms.ComboBox

Friend Property Set ComboBox(objComboBox As MSForms.ComboBox)
    Set mobjComboBox = objComboBox
End Property

Private Sub mobjComboBox_Change()
    MsgBox "Selection changed."
End Sub

Private Sub mobjComboBox_Click()
    MsgBox "Clicked."
End Sub

请注意，变量objControls必须是clsComboBox类型。将此变量声明为Object或Variant对我没有起作用（有人能解释为什么吗？）。

- divo

---

做得好。我发现对于“Application.OnTime”调用可以使用更小的延迟。我使用的是：Application.OnTime VBA.Now + 0.000001, "prcCreateReference"，只有稍微不到1/10秒。哦，我正在使用Word 2007。 - Hannah Vernon