gnuplot png 白底黑字问题

Question

在gnuplot-4.2.6中，我可以使用以下命令生成漂亮的黑底白字图像：

set term png medium x000000 xffffff
set output 'file.png'
plot x

这将生成一个黑色背景和白色坐标轴、坐标轴标签、标题、图例文本等的png文件。

新的gnuplot-5.0.1会抱怨上述“set term”命令，说“过时的颜色选项”。我能想到的最接近于获得白色底黑色字的图像是使用以下命令将背景设置为黑色：

set term png medium background '#ffffff'
set output 'file.png'
plot x

但是这只是将背景设置为黑色，而没有将轴、轴标签等设置为白色。

有人知道如何在最新版本的gnuplot中获得白底黑字的png图片吗？

- Paul

---

png 终端本身已经过时了。尝试使用 pngcairo，它可能允许您做您想要的事情。我无法自己检查，因为我不使用 gnuplot-5。 - Miguel

感谢提供的信息。我正在使用CentOS-6.6，安装cairo和cairo-devel对gnuplot的配置和构建没有影响。 - Paul

Answer 1

这些png终端的颜色选项在4.6版本中被删除。日志中提到：这个机制已经过时了，除了用于设置背景颜色之外。 从4.6.0版本开始，您可以（也必须）明确地设置每个部分的线条颜色和文字颜色：

set terminal pngcairo background rgb 'black'
set xlabel 'ylabel' tc rgb 'white'
set ylabel 'xlabel' tc rgb 'white'
set border lc rgb 'white'
set key tc rgb 'white'

set linetype 1 lc rgb 'white'
set output 'bw.png'
plot x lc 1, x**2 lc 1

如果您只需要这些设置用于某些图片，可以将几个部分移动到某种名为`black-and-white.gp`的配置文件中，其内容如下：

set macros
bg = 'background rgb "black"'
white = 'textcolor rgb "white"'
set xlabel @white
set ylabel @white
set linetype 11 lc rgb 'white'
set border lc 11
set key @white

在实际的绘图文件中，您可以像这样使用它：

load 'black-and-white.gp'
set terminal pngcairo @bg
set xlabel 'xlabel'
set ylabel 'ylabel'

set output 'bw.png'
plot x lc 11, x**2 lc 11

- Christoph

---

我很高兴他们删除了这个过时的选项，现在我们可以明确地进行操作，而不是在一个已经使用了十多年的脚本中进行黑客攻击。过时并不能阻止我们前进！ - Florian Heigl

对于带有误差条的绘图，还可以使用“set bars lc rgb 'white'”。 - ɲeuroburɳ