logo标签列表

如何在Emacs中全局启用一个模式？

emacsconfigurationmodeminor-mode
4

我刚刚安装了一个插件，想要在全局启用它。为了手动开启它，我需要输入 M-x highlight-indentation-mode。下面是我尝试过的列表：(highlight-indentation-mode t)、(highlight-indentation-mode 1)、(setq highlight-indentation-mode t)。但是都没有起作用。接着我想到可能需要全局启用这个模式，于是开始搜索相关信息。我尝试了以下方法：

(define-globalized-minor-mode global-highlight-indentation-mode highlight-indentation-mode
  (lambda () (setq highlight-indentation-mode t)))

不，这明显不是我要找的机器人，它虽然开启了变量，但模式仍然无法正常工作。

(define-globalized-minor-mode global-highlight-indentation-mode highlight-indentation-mode
  (lambda () highlight-indentation-mode t))

(define-globalized-minor-mode global-highlight-indentation-mode highlight-indentation-mode
  (highlight-indentation-mode t))

这两个命令刚刚让我的Emacs崩溃了：当我尝试使用这两个命令打开文件时，在配置文件中，Emacs会报错并拒绝打开文件。
更新：根据评论的建议，我也尝试了。
(defun enable-highlight-indentation-mode ()
  (interactive)
    (highlight-indentation-mode t))

(define-globalized-minor-mode global-highlight-indentation-mode highlight-indentation-mode
  enable-highlight-indentation-mode)  

(global-highlight-indentation-mode t)

同样的问题也出现在没有 (interactive) 的情况下。当我试图使用这个功能打开一个文件时，Emacs拒绝打开，并显示以下错误信息：

File mode specification error: (void-function nil)
c-font-lock-fontify-region: Symbol's function definition is void: nil
1
以下链接包含如何为较旧版本的Emacs创建全局模式的示例：http://superuser.com/a/762495/206164。Emacs的开发版（尚未发布稳定公共版本）具有“：global t”选项。基本上，对于半老化的Emacs版本，您只需要一个小函数来打开次要模式，并在全局化的语句中命名该函数。您的第二个示例看起来非常接近，只是您没有将“highlight-indentation-mode t”放在括号中。 - lawlist
(defun turn-on-highlight-indentation-mode () (highlight-indentation-mode 1)) (define-globalized-minor-mode global-highlight-indentation-mode highlight-indentation-mode turn-on-highlight-indentation-mode) - lawlist
@lawlist 我试过了。我在更新中写下了结果。 - Hi-Angel
使用以下代码启用更广泛的调试：(setq debug-on-error t) 这可能会告诉你导致问题的函数名称。 - lawlist
1
这是Anton Johansson的那个吗？如果是，下面回答中的那个似乎可以正常工作。我添加了全局模式。 - lawlist
显示剩余4条评论
1个回答
4
;;; highlight-indentation.el --- Minor modes for highlighting indentation
;; Author: Anton Johansson <anton.johansson@gmail.com> - http://antonj.se
;; Created: Dec 15 23:42:04 2010
;; Version: 0.6.0
;; URL: https://github.com/antonj/Highlight-Indentation-for-Emacs
;;
;; This program is free software; you can redistribute it and/or
;; modify it under the terms of the GNU General Public License as
;; published by the Free Software Foundation; either version 2 of
;; the License, or (at your option) any later version.
;;
;; This program is distributed in the hope that it will be
;; useful, but WITHOUT ANY WARRANTY; without even the implied
;; warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR
;; PURPOSE. See the GNU General Public License for more details.
;;
;;; Commentary:
;; Customize `highlight-indentation-face', and
;; `highlight-indentation-current-column-face' to suit your theme.

;;; Code:

(defgroup highlight-indentation nil
  "Highlight Indentation"
  :prefix "highlight-indentation-"
  :group 'basic-faces)

(defface highlight-indentation-face
  ;; Fringe has non intrusive color in most color-themes
  '((t :inherit fringe))
  "Basic face for highlighting indentation guides."
  :group 'highlight-indentation)

(defcustom highlight-indentation-offset 4
  "Default indentation offset, used if no other can be found from
major mode. This value is always used by
`highlight-indentation-mode' if set buffer local. Set buffer
local with `highlight-indentation-set-offset'"
  :group 'highlight-indentation)

(defvar highlight-indentation-current-regex nil)

;;;###autoload
(define-minor-mode highlight-indentation-mode
  "Highlight indentation minor mode highlights indentation based
on spaces"
  :lighter " ||"
  (when highlight-indentation-current-regex ;; OFF
    (font-lock-remove-keywords nil `((,highlight-indentation-current-regex
                                      (1 'highlight-indentation-face)))))

  (set (make-local-variable 'highlight-indentation-current-regex) nil)

  (when highlight-indentation-mode ;; ON
    (when (not (local-variable-p 'highlight-indentation-offset))
      (set (make-local-variable 'highlight-indentation-offset)
           ;; Set indentation offset from highlight-indentation-offset if set, otherwise
           ;; according to major mode
           (cond ((and (eq major-mode 'python-mode) (boundp 'python-indent))
                  python-indent)
                 ((and (eq major-mode 'python-mode) (boundp 'py-indent-offset))
                  py-indent-offset)
                 ((and (eq major-mode 'python-mode) (boundp 'python-indent-offset))
                  python-indent-offset)
                 ((eq major-mode 'ruby-mode)
                  ruby-indent-level)
                 ((and (eq major-mode 'scala-mode) (boundp 'scala-indent:step))
                  scala-indent:step)
                 ((and (eq major-mode 'scala-mode) (boundp 'scala-mode-indent:step))
                  scala-mode-indent:step)
                 ((or (eq major-mode 'scss-mode) (eq major-mode 'css-mode))
                  css-indent-offset)
                 ((eq major-mode 'nxml-mode)
                  nxml-child-indent)
                 ((eq major-mode 'coffee-mode)
                  coffee-tab-width)
                 ((eq major-mode 'js-mode)
                  js-indent-level)
                 ((eq major-mode 'js2-mode)
                  js2-basic-offset)
                 ((local-variable-p 'c-basic-offset)
                  c-basic-offset)
                 (t
                  (default-value 'highlight-indentation-offset)))))
    (set (make-local-variable 'highlight-indentation-current-regex)
         (format "\\( \\) \\{%s\\}" (- highlight-indentation-offset 1)))
    (font-lock-add-keywords nil `((,highlight-indentation-current-regex
                                   (1 'highlight-indentation-face)))))
  (font-lock-fontify-buffer))

;;;###autoload
(defun highlight-indentation-set-offset (offset)
  "Set indentation offset localy in buffer, will prevent
highlight-indentation from trying to guess indentation offset
from major mode"
  (interactive
   (if (and current-prefix-arg (not (consp current-prefix-arg)))
       (list (prefix-numeric-value current-prefix-arg))
     (list (read-number "Indentation offset: "))))
  (set (make-local-variable 'highlight-indentation-offset) offset)
  (when highlight-indentation-mode
    (highlight-indentation-mode)))


;;;
;;; Copyright (C) Kresten Krab Thorup
;;; Available under Apache License, Version 2.
;;;
;;; This minor mode will highlight the indentation of the current line
;;; as a vertical bar (grey background color) aligned with the column of the
;;; first character of the current line.
;;;
(defface highlight-indentation-current-column-face
  ;; Fringe has non intrusive color in most color-themes
  '((t :inherit fringe))
  "Basic face for highlighting indentation guides."
  :group 'highlight-indentation)

;; used to hold the last regex we installed
(defvar highlight-indentation-current-column-regex nil)

;;;###autoload
(define-minor-mode
  highlight-indentation-current-column-mode
  "Hilight Indentation minor mode displays
a vertical bar corresponding to the indentation of the current line"
  :lighter " |"

  (when highlight-indentation-current-column-regex
    (font-lock-remove-keywords nil highlight-indentation-current-column-regex))

  (set (make-local-variable 'highlight-indentation-current-column-regex) nil)
  (cond (highlight-indentation-current-column-mode
          (add-hook 'post-command-hook 'highlight-indentation-current-column-post-command-hook nil t))
         (t
          (remove-hook 'post-command-hook 'highlight-indentation-current-column-post-command-hook t)

          (font-lock-fontify-buffer))))

(defun highlight-indentation-current-column-post-command-hook ()
  "This hook runs after every keystroke"
  (when highlight-indentation-current-column-regex
    (font-lock-remove-keywords nil highlight-indentation-current-column-regex))
  (let ((indent (save-excursion (back-to-indentation) (current-column))))
    (when (and highlight-indentation-current-column-mode
               (> indent 1))
      (let* ((re (format "^ \\{%d\\}\\( \\)" indent))
             (arg `((,re (1 'highlight-indentation-current-column-face prepend)))))
        (set (make-local-variable 'highlight-indentation-current-column-regex) arg)
        (font-lock-add-keywords nil arg))))
  (font-lock-fontify-buffer))

(defun turn-on-highlight-indentation-mode ()
(interactive)
  (highlight-indentation-mode 1))

(define-globalized-minor-mode global-highlight-indentation-mode
  highlight-indentation-mode turn-on-highlight-indentation-mode)

(global-highlight-indentation-mode 1)

(provide 'highlight-indentation)
1
如果Emacs在完全剥离用户配置或零用户配置下无法正常工作，那么现在可能是时候备份整个安装（到安全位置），并尝试最新版本的Emacs了 - 如果您有能力挑战，甚至可以尝试开发者构建快照。根据您的操作系统，即使是开发者快照也有预构建的二进制文件。 - lawlist
1
Yagamy Light: 运行 emacs -Q 以禁用所有用户和站点范围的elisp，然后使用 M-x load-file 加载lawlist提供的文件以验证默认行为。您正在运行哪个版本的Emacs？(M-x emacs-version) - phils
@phils 抱歉，我不小心忽略了你的评论。我今晚会尝试。 - Hi-Angel
@phils，-Q选项强制忽略.emacs文件中的lisp。正如我提到的，如果没有启用此插件的代码，就不会出现错误。但是，如果您坚持要求，我回到家后可以检查一下。 - Hi-Angel
1
啊哈。抱歉，我之前没有注意到你已经确认过了。（我的错误；之前的评论已经足够清楚了；只是有很多评论:）。如果你得到了完整的调试堆栈跟踪，请一定展示给我们看。 - phils
显示剩余15条评论
网页内容由stack overflow 提供, 点击上面的
可以查看英文原文，
原文链接