Prolog - 简化求导

Question

我刚刚开始学习Prolog，这学期的作业是实现一个相当基础的d(function, variable, derivative)函数，我的实现如下：

d(X,X,1) :- !.
d(C,X,0) :- atomic(C). %, (C \= X).
d(X**E,X,E*X**(E-1)).
d(U+V,X,A+B) :- d(U,X,A), d(V,X,B).
d(U-V,X,A-B) :- d(U,X,A), d(V,X,B).
d(U*V,X,DU*V+U*DV) :- d(U,X,DU), d(V,X,DV).
d(U/V,X,(DU*V-U*DV)/(V*V)) :- d(U,X,DU), d(V,X,DV).

我知道这并不完整，但它涵盖了练习中所需的所有任务。

然而， ?- d((x*x+2*x+3)/(3*x),x,R). 导致

R = ((1*x+x*1+ (0*x+2*1)+0)* (3*x)- (x*x+2*x+3)* (0*x+3*1))/ (3*x* (3*x)). 这看起来一点也不美观。 is/2 不喜欢我的 x，因为它不是一个数字...

有没有简单的解决方法可以实现更干净的结果？

- 4cello

---

is/2是用于算术计算的，其中你知道变量的数值实例化情况，因此它不适用于这个目的。如果你想要更漂亮的结果，你需要创建一个谓词来简化表达式。 - lurker

Answer 1

我更愿意将此视为两个独立的问题:

首先，正确进行导数运算（根据您具体的要求，您可能已经接近了）。

然后，在代数层面上简化表达式。利用代数恒等式，看看是否将交换律/结合律/分配律定律应用于某些子表达式可以使它们重写成等价但更简单/更紧凑的形式。

作为起点，您可能需要查看与之有关的问题“在Prolog中替换表达式的部分”。

---

这是一个简单的草图，说明如何使用iwhen/2简化-以防止不充分的实例化：

expr_simplified(A, B) :-
   iwhen(ground(A), xpr_simplr(A,B)).
xpr_simplr(A, B) :-
   (  atomic(A)
   -> A = B
   ;  ( A = X+0 ; A = 0+X ; A = 1*X ; A = X*1 )
   -> xpr_simplr(X, B)
   ;  ( A = 0*_ ; A = _*0 )
   -> B = 0
   ;  A = X+X
   -> B = X*2
   ;  A = X*X
   -> B = X**2
   ;  A = X**1
   -> B = X
   ;  A =.. [F|Xs0],                          % 默认 catch-all
      maplist(xpr_simplr, Xs0, Xs),
      B =.. [F|Xs]
   ).

让我们看看它对您提供的表达式做了什么。我们将expr_simplified/2应用到达到一个固定点为止：

?- A = ((1*x+x*1+(0*x+2*1)+0)*(3*x)-(x*x+2*x+3)*(0*x+3*1))/(3*x*(3*x)),
   expr_simplified(A,B),
   expr_simplified(B,C),
   expr_simplified(C,D).
A = ((1*x+x*1+(0*x+2*1)+0)*(3*x)-(x*x+2*x+3)*(0*x+3*1))/(3*x*(3*x)),
B = ((x+x+(0+2))*(3*x)-(x**2+2*x+3)*(0+3))/(3*x)**2,
C = ((x*2+2)*(3*x)-(x**2+2*x+3)*3)/(3*x)**2,
D = C.                                        % 达到了固定点

尽管简化器不完美，但表达式变得更加易读。

- repeat

---

谢谢！这看起来比以前好多了！ - 4cello

Answer 2

获取一个数字的可能性是将每个变量x的实例替换为一个值，访问派生树。您应该编写一个子句来匹配每个二元运算符，或者使用通用访问，例如

set_vars(E, Vs, Ev) :-
    E =.. [F,L,R],
    set_vars(L, Vs, Lv),
    set_vars(R, Vs, Rv),
    Ev =.. [F,Lv,Rv].
set_vars(V, Vs, N) :- memberchk(V=N, Vs).
set_vars(V, _, V).

that yields

?- d((x*x+2*x+3)/(3*x),x,R), set_vars(R,[x=5],E), T is E.
R = ((1*x+x*1+ (0*x+2*1)+0)* (3*x)- (x*x+2*x+3)* (0*x+3*1))/ (3*x* (3*x)),
E = ((1*5+5*1+ (0*5+2*1)+0)* (3*5)- (5*5+2*5+3)* (0*5+3*1))/ (3*5* (3*5)),
T = 0.29333333333333333 

但是，你第一条子句中存在一个错误，一旦修正，就可以直接评估派生表达式：

d(X,V,1) :- X == V, !.
...

现在，我们可以放弃实用程序set_vars/3，因此。

?- d((T*T+2*T+3)/(3*T),T,R), T=8, V is R.
T = 8,
R = ((1*8+8*1+ (0*8+2*1)+0)* (3*8)- (8*8+2*8+3)* (0*8+3*1))/ (3*8* (3*8)),
V = 0.3177083333333333.

- CapelliC