为什么幺半范畴和应用函子的定律告诉我们同样的事情？

Question

不久前，我学到了Monoidal是表示Applicative的另一种方式。在Typeclassopedia上有一个有趣的问题：

3. (棘手的) 证明根据你从第一个练习中得出的实现 [使用unit和(**)编写的pure和(<*>)以及另一种方法]，通常的Applicative法则和上述Monoidal法则是等价的。

以下是这些类和规则：

-- A note from https://wiki.haskell.org/Typeclassopedia#Alternative_formulation:
-- In this and the following laws, ≅ refers to isomorphism rather than equality. 
-- In particular we consider (x,()) ≅ x ≅ ((),x) and ((x,y),z) ≅ (x,(y,z)).

-- Monoidal.
class Functor f => Monoidal f where
  unit :: f ()
  (**) :: f a -> f b -> f (a,b)

-- unit ** v ≅ v - Left Identity.
-- u ** unit ≅ u - Right Identity.
-- u ** (v ** w) ≅ (u ** v) ** w - Associativity.

-- Applicative. 
class Functor f => Applicative f where
  pure  :: a -> f a
  infixl 4 <*>, ...
  (<*>) :: f (a -> b) -> f a -> f b
  ...

-- pure id <*> v = v - Identity.
-- pure f <*> pure x = pure (f x) - Homomorphism.
-- u <*> pure y = pure ($ y) <*> u - Interchange.
-- u <*> (v <*> w) = pure (.) <*> u <*> v <*> w - Composition.

使用其他组合子编写组合子并不是什么大问题：

unit   = pure ()
f ** g = (,) <$> f <*> g = liftA2 (,) f g

pure x  = const x <$> unit
f <*> g = uncurry ($) <$> (f ** g)

以下是我对为什么法律告诉我们相同的事情的理解：

u <*> pure y = pure ($ y) <*> u -- Interchange: Applicative law.

我们首先需要注意的是，($ y) ≅ y（更正式地说：(y -> a) -> a ≅ y）。有了这个想法后，交换律简单地告诉我们(a, b) ≅ (b, a)。

pure id <*> v = v -- Identity: Applicative law.

我认为id本身就是一个单元，因为它是类型forall a. a -> a的唯一成员。因此，这个定律给出了左单位元：

unit ** v = v -- Left Identity: Monoidal law.

现在我们可以使用 (a, b) ≅ (b, a) 来写出右单位元：

u ** unit = u -- Right Identity: Monoidal law.

组合定律：

u <*> (v <*> w) = pure (.) <*> u <*> v <*> w -- Composition: Applicative law.

我认为这个定律与Monoidal的结合律是同一件事：

u ** (v ** w) ≅ (u ** v) ** w

也就是说，(a, (b, c)) ≅ ((a, b), c)。而Applicative只是增加了一层应用。

因此，我们已经覆盖了所有的Monoidal法则。我认为没有必要反过来做，因为我们将使用相同的同构关系。但是有人可能会注意到一些奇怪的东西——我们没有使用同态Applicative法则：

pure f <*> pure x = pure (f x)

我试图通过自然性自由定理理解同态，这里的 Monoidal 是指单子范畴：

fmap (g *** h) (u ** v) = fmap g u ** fmap h v

但是很奇怪，同态并不处理副作用，然而自然性却可以正常工作。

所以，我有三个问题：

1. 我的推理正确吗？
2. 同态在这张图片中的位置是什么？
3. 我们如何从应用角度理解自然性自由定理？

- Zhiltsoff Igor

---

只需按照有条不紊的方式进行。您已经拥有“1. 实现。 Applicative --> Monoidal”、“2. 实现。 Monoidal --> Applicative”。现在，根据应用法则和“1.”实现，证明每个Monoidal法则；然后根据Monoidal法则和“2.”实现证明每个Applicative法则。在每个证明中，从前提开始，并在仔细记录每一步使用的已知法则的同时到达所需的结论。这是机械的。如果您想了解其感觉，请在将所有内容写下后再进行操作。这就是我会做的事情。 - Will Ness

所以当我们慢慢仔细地进行时，我们可以确信。模糊的推理没有任何保证（除非你真的知道你在说什么）。例如"($ y) ≅ y"，我认为这完全不正确。 - Will Ness

@WillNess 嗯，我没有尝试进行正式证明（如你所建议的）。然而，我不明白为什么你提到的同构不成立。从左到右，我们有 \ t -> t id；从右到左 - \ t -> ($ t)。我错在哪里了？ - Zhiltsoff Igor

同构是在类型之间进行的，但 y 和 ($ y) 是值？也许我没有完全理解你的意思。 - Will Ness

@WillNess 是的，我在谈论值。至少我不知道 $ 类型运算符。我猜它很笨拙，但对于直觉来说似乎很合适。这是一个不好的表达方式吗？老实说，我所有关于这种证明的经验都只是像你所说的那样机械化的工作。如果你能给我一些例子，说明这种风格被正确地执行了，我会非常感激。 - Zhiltsoff Igor

Answer 1

暂时将这个放在这里...想讨论一下，但我已经花了太长时间来实现它：这是一个Coq证明脚本，以绝对无懈可击的方式展示了等效性。

Require Import Coq.Program.Basics.
Require Import Coq.Init.Datatypes.
Require Import Coq.Init.Notations.

Notation "f ∘ g" := (compose f g).

Class Functor (F: Type -> Type) : Type :=
  { fmap : forall {x} {y}, (x->y) -> (F x->F y)
  ; fmap_id : forall x, @fmap x x id = id
  ; fmap_compose : forall {x} {y} {z} (f: y->z) (g: x->y)
                     , fmap (f∘g) = fmap f ∘ fmap g
  }.

Lemma fmap_twice {F} `{Functor F} {x} {y} {z} (f: y->z) (g: x->y) (xs: F x)
                     : fmap (f∘g) xs = fmap f (fmap g xs).
Proof.
  rewrite fmap_compose. now compute.
Qed.

Definition parallel {a} {b} {c} {d} (f: a->c) (g: b->d)
  : (a*b) -> (c*d) := fun xy => match xy with
                                | (x,y) => (f x, g y)
                                end.

Notation "f *** g" := (parallel f g) (at level 40, left associativity).

Definition rassoc {a} {b} {c} : ((a*b)*c) -> (a*(b*c))
    := fun xyz => match xyz with | ((x,y),z) => (x,(y,z)) end.

Definition tt_ {a} (x:a) := (tt, x).
Definition _tt {a} (x:a) := (x, tt).

Class Monoidal F `{Functor F} : Type :=
  { funit : F unit
  ; fzip : forall {a} {b}, F a -> F b -> F (a*b)
  ; left_identity : forall {a} (v: F a)
           , fzip funit v = fmap tt_ v
  ; right_identity : forall {a} (v: F a)
           , fzip v funit = fmap _tt v
  ; associativity : forall {a} {b} {c} (u: F a) (v: F b) (w: F c)
           , fzip u (fzip v w) = fmap rassoc (fzip (fzip u v) w)
  ; naturality : forall {a} {b} {c} {d}
                        (g: a->c) (h: b->d) (u: F a) (v: F b)
           , fmap (g***h) (fzip u v) = fzip (fmap g u) (fmap h v)
  }.

Notation "u ** v" := (fzip u v) (at level 40, left associativity).

Lemma naturalityL {F} `{Monoidal F} {a} {b} {c}
                           (f: a->c) (u: F a) (v: F b)
           : fmap (f***id) (fzip u v) = fzip (fmap f u) v.
Proof.
  assert (v = fmap id v) as ->. { now rewrite fmap_id. }
  rewrite <- naturality.
  assert (v = fmap id v) as <-. { now rewrite fmap_id. }
  now trivial.
Qed.
Lemma naturalityR {F} `{Monoidal F} {a} {b} {c}
                           (f: b->c) (u: F a) (v: F b)
           : fmap (id***f) (fzip u v) = fzip u (fmap f v).
Proof.
  assert (u = fmap id u) as ->. { now rewrite fmap_id. }
  rewrite <- naturality.
  assert (u = fmap id u) as <-. { now rewrite fmap_id. }
  now trivial.
Qed.

Definition to {a} {b} (y: a) (f: a->b) := f y.

Class Applicative F `{Functor F} : Type :=
  { pure : forall {a}, a -> F a
  ; app : forall {a} {b}, F (a->b) -> F a -> F b
  ; identity : forall {a} (v: F a)
              , app (pure id) v = v
  ; homomorphism : forall {a} {b} (f: a->b) (x: a)
              , app (pure f) (pure x) = pure (f x)
  ; interchange : forall {a} {b} (u: F (a->b)) (y: a)
              , app u (pure y) = app (pure (to y)) u
  ; composition : forall {a} {b} {c}
                         (u: F (b->c)) (v: F (a->b)) (w: F a)
              , app u (app v w) = app (app (app (pure compose) u) v) w
  ; appFtor : forall {a} {b} (g: a->b) (x: F a)
              , fmap g x = app (pure g) x
  }.

Notation "fs <*> xs" := (app fs xs) (at level 40, left associativity).

Require Import Coq.Program.Tactics.
Require Import Coq.Logic.FunctionalExtensionality.

Definition apl {a} {b} (fx: (a->b)*a)
   := match fx with |(f,x) => f x end.

Program Instance MonoidalIsApplicative {F} `{Monoidal F}
    : Applicative F
  := { pure := fun {a} (x: a) => fmap (const x) funit
     ; app := fun {a} {b} (fs: F (a->b)) (xs: F a)
              => fmap apl (fzip fs xs) }.
Next Obligation. (* identity *)
  rewrite <- naturalityL.
  rewrite -> left_identity.
  repeat (rewrite <- fmap_twice).
  rewrite -> fmap_id.
  now compute.
Qed.
Next Obligation. (* homomorphism *)
  rewrite <- naturality.
  rewrite -> left_identity.
  repeat (rewrite <- fmap_twice).
  now compute.
Qed.
Next Obligation. (* interchange *)
  rewrite <- naturalityL.
  rewrite <- naturalityR.
  repeat (rewrite <- fmap_twice).
  rewrite -> right_identity.
  rewrite -> left_identity.
  repeat (rewrite <- fmap_twice).
  now compute.
Qed.
Next Obligation. (* composition *)
  rewrite <- naturalityR.
  rewrite -> associativity.
  repeat (rewrite <- naturalityL).
  rewrite -> left_identity.
  repeat (rewrite <- naturalityL).
  repeat (rewrite <- fmap_twice).

  f_equal.                      (*    This part is just about *)
  unfold compose.                 (*  convincing Coq that two  *)
  apply functional_extensionality. (* functions are equal, it  *)
  intro x.                         (* has nothing to do with   *)
  destruct x as ((btc, atb), a0). (*  applicative or monoidal  *)
  now compute.                  (*    functors, specifically. *)
Qed.
Next Obligation. (* appFtor *)
  rewrite <- naturalityL.
  rewrite -> left_identity.
  repeat (rewrite <- fmap_twice).
  now compute.
Qed.


Lemma fmapPure {F} `{Applicative F} {a} {b}
        (f: a->b) (x: a) : fmap f (pure x: F a) = pure (f x).
Proof.
  rewrite -> appFtor.
  now apply homomorphism.
Qed.

Lemma fmapBracket {F} `{Applicative F} {a} {b} {c} {d}
      (f: c->d) (g: a->b->c) (xs: F a) (ys: F b)
     : fmap f (fmap g xs<*>ys) = fmap (fun x y => f (g x y)) xs <*> ys.
Proof.
  repeat (rewrite -> appFtor).
  rewrite -> composition.
  rewrite -> homomorphism.
  rewrite -> composition.
  repeat (rewrite -> homomorphism).
  now compute.
Qed.

Lemma fmap_both {F} `{Applicative F} {a} {b} {c} {d}
      (f: a->c->d) (g: b->c) (xs: F a) (ys: F b)
     : fmap f xs <*> fmap g ys = fmap (fun x y => f x (g y)) xs <*> ys.
Proof.
  repeat (rewrite -> appFtor).
  rewrite -> composition.
  repeat (rewrite <- appFtor).
  rewrite <- fmap_twice.
  rewrite -> interchange.
  rewrite -> appFtor.
  rewrite -> composition.
  repeat (rewrite -> homomorphism).
  rewrite <- appFtor.
  now compute.
Qed.

Definition tup {a} {b} (x:a) (y:b) : (a*b) := (x,y).

Program Instance ApplicativeIsMonoidal {F} `{Applicative F}
    : Monoidal F
  := { funit := pure tt
     ; fzip := fun {a} {b} (u: F a) (v: F b)
                   => fmap tup u <*> v }.
Next Obligation. (* left_identity *)
  repeat (rewrite -> appFtor).
  rewrite -> homomorphism.
  now compute.
Qed.
Next Obligation. (* right_identity *)
  repeat (rewrite -> appFtor).
  rewrite -> interchange.
  rewrite -> composition.
  repeat (rewrite -> homomorphism).
  now compute.
Qed.
Next Obligation. (* associativity *)
  repeat (rewrite -> fmapBracket).
  rewrite -> composition.
  repeat (rewrite <- appFtor).
  rewrite <- fmap_twice.
  rewrite -> fmap_both.
  now compute.
Qed.
Next Obligation. (* naturality *)
  rewrite -> fmap_both.
  rewrite <- fmap_twice.
  rewrite -> fmapBracket.
  now compute.
Qed.

使用 Coq 8.9.1 编译。

- leftaroundabout

Answer 2

我们拥有

-- Monoidal.
class Functor f => Monoidal f where
  unit :: f ()
  (**) :: f a -> f b -> f (a,b)

-- unit ** v ≅ v - Left Identity.
-- u ** unit ≅ u - Right Identity.
-- u ** (v ** w) ≅ (u ** v) ** w - Associativity.

-- Applicative,
class Functor f => Applicative f where
  pure  :: a -> f a
  infixl 4 <*>
  (<*>) :: f (a -> b) -> f a -> f b

-- pure id <*> v = v - Identity.
-- pure f <*> pure x = pure (f x) - Homomorphism.
-- u <*> pure y = pure ($ y) <*> u - Interchange.
-- u <*> (v <*> w) = pure (.) <*> u <*> v <*> w - Composition.

实现1. 应用 --> 幺半群

unit     = pure ()
xs ** ys = pure (,) <*> xs <*> ys

实现方式二：单子到应用

pure x  = const x <$> unit
fs <*> xs = uncurry ($) <$> (fs ** xs)

现在，根据应用律和实现1证明幺半律：

左单位元。 unit ** v ≅ v

unit ** v = pure () ** v
          = pure (,) <*> pure () <*> v
          = pure (\x -> (,) () x) <*> v
          = pure (\x -> (() , x)) <*> v
          = pure (() ,) <*> v
          ≅ pure id <*> v
          = v

右恒等性质。u ** unit ≅ u

u ** unit = u ** pure ()
          = pure (,) <*> u <*> pure ()
          = pure ($ ()) <*> (pure (,) <*> u)  -- u <*> pure y = pure ($ y) <*> u 
          -- u <*> (v <*> w) = pure (.) <*> u <*> v <*> w
          = pure (.) <*> pure ($ ()) <*> pure (,) <*> u
          = pure ((.) ($ ())) <*> pure (,) <*> u
          = pure ((.) ($ ()) (,)) <*> u
          = pure (\x -> (.) ($ ()) (,) x) <*> u
          = pure (\x -> ($ ()) ((,) x)) <*> u
          = pure (\x -> (,) x ()) <*> u
          = pure (\x -> (x , ())) <*> u
          = pure (, ()) <*> u
          ≅ pure id <*> u
          = u

结合律. u ** (v ** w) ≅ (u ** v) ** w

u ** (v ** w) = ......

你应该能够继续进行下去。我希望我没有犯任何错误，但如果有，请纠正它们。

- Will Ness

Answer 3

根据Will Ness的建议：

除了已经提到的定律外，我们还可以得到关于同态的信息（我使用规定 Applicative 如何与 Functor 相关的规律：fmap g x = pure g <*> x）。

pure f <*> pure x = 
= uncurry ($) <$> ((,) <$> (pure f) <*> (pure x)) = 
= (uncurry ($) .) <$> ((,) <$> (pure f)) <*> (pure x) =
= ((uncurry ($) .) . (,) <$> (pure f)) <*> (pure x) = 
= (uncurry ($) . (,) f) <$> (pure x) =
= pure $ (uncurry ($) . (,) f) x = 
= pure (f x)

所以，我猜测同态和fs <*> xs = uncurry ($) <$> (fs ** xs)都让我们能够在函子层面上执行应用。

- Zhiltsoff Igor