如何在使用Delphi的控制台应用程序中激活玻璃效果（Windows Vista / 7）

Question

我可以在我的控制台应用程序中激活玻璃效果。我使用的是Windows 7和Delphi 2010。

我发现this应用程序，所以这应该是可能的。

- Salvador

---

控制台窗口是一个共享资源。它不属于您的程序。不要对不属于您的窗口进行全局更改。如果您的客户想让他们的控制台窗口看起来漂亮，他们可以安装您链接到的程序。 - Rob Kennedy

Answer 1

几周前，我在我的博客上发布了这篇文章。

关键是要使用GetConsoleWindow和DwmEnableBlurBehindWindow函数。

GetConsoleWindow函数检索与调用进程相关联的控制台使用的窗口句柄。

DwmEnableBlurBehindWindow函数启用提供的窗口句柄的模糊效果（玻璃效果）。

program ConsoleGlassDelphi;

{$APPTYPE CONSOLE}

    uses
  Windows,
  SysUtils;

type
  DWM_BLURBEHIND = record
    dwFlags                 : DWORD;
    fEnable                 : BOOL;
    hRgnBlur                : HRGN;
    fTransitionOnMaximized  : BOOL;
  end;

function DwmEnableBlurBehindWindow(hWnd : HWND; const pBlurBehind : DWM_BLURBEHIND) : HRESULT; stdcall; external  'dwmapi.dll' name 'DwmEnableBlurBehindWindow';//function to enable the glass effect
function GetConsoleWindow: HWND; stdcall; external kernel32 name 'GetConsoleWindow'; //get the handle of the console window

function DWM_EnableBlurBehind(hwnd : HWND; AEnable: Boolean; hRgnBlur : HRGN = 0; ATransitionOnMaximized: Boolean = False; AFlags: Cardinal = 1): HRESULT;
var
  pBlurBehind : DWM_BLURBEHIND;
begin
  pBlurBehind.dwFlags:=AFlags;
  pBlurBehind.fEnable:=AEnable;
  pBlurBehind.hRgnBlur:=hRgnBlur;
  pBlurBehind.fTransitionOnMaximized:=ATransitionOnMaximized;
  Result:=DwmEnableBlurBehindWindow(hwnd, pBlurBehind);
end;

begin
  try
    DWM_EnableBlurBehind(GetConsoleWindow(), True);
    Writeln('See my glass effect');
    Writeln('Go Delphi Go');
    Readln;
  except
    on E:Exception do
      Writeln(E.Classname, ': ', E.Message);
  end;
end.

这只是一个基本的示例；您必须检查Windows操作系统版本以避免问题。

- RRUZ

---

如果“窗口颜色和外观”设置为霜冻，则这种方法效果不佳...白色背景上的白色文本。 - Christopher Chase