我有一个批处理文件，它通过一系列中间变量计算出一个变量：
@echo off
setlocal
set base=compute directory
set pkg=compute sub-directory
set scripts=%base%\%pkg%\Scripts
endlocal
%scripts%\activate.bat
由于endlocal会覆盖scripts环境变量，因此最后一行代码未被调用，但它必须在endlocal之后才能设置一堆其他环境变量供用户使用。
如何调用一个旨在设置永久环境变量的脚本，但其位置由临时环境变量确定？
我知道我可以在endlocal之前创建临时批处理文件，并在endlocal之后调用它，如果没有更好的方法，我将这样做，但我想知道是否有更简洁的解决方案。
ENDLOCAL & SET VAR=%TEMPVAR%这个模式是经典的。但在某些情况下，它并不理想。
如果您不知道TEMPVAR的内容，并且该值包含特殊字符，例如< > &或|，那么可能会遇到问题。您通常可以通过使用引号来保护它，例如SET "VAR=%TEMPVAR%"，但如果有特殊字符并且该值已被引用，那么可能会出现问题。
如果您担心特殊字符，则FOR表达式是跨越ENDLOCAL障碍传输值的绝佳选择。在ENDLOCAL之前应启用延迟扩展，在ENDLOCAL之后应禁用延迟扩展。
setlocal enableDelayedExpansion
set "TEMPVAR=This & "that ^& the other thing"
for /f "delims=" %%A in (""!TEMPVAR!"") do endlocal & set "VAR=%%~A"
限制：
如果在ENDLOCAL之后启用延迟扩展，那么如果TEMPVAR包含!，最终值将被破坏。
包含换行符的值无法传输。
如果您必须返回多个值，并且您知道一个字符不能出现在任一值中，则只需使用适当的FOR /F选项。例如，如果我知道这些值不能包含|：
setlocal enableDelayedExpansion
set "temp1=val1"
set "temp2=val2"
for /f "tokens=1,2 delims=|" %%A in (""!temp1!"|"!temp2!"") do (
endLocal
set "var1=%%~A"
set "var2=%%~B"
)
如果您必须返回多个值，并且字符集没有限制，则使用嵌套的 FOR /F 循环：
setlocal enableDelayedExpansion
set "temp1=val1"
set "temp2=val2"
for /f "delims=" %%A in (""!temp1!"") do (
for /f "delims=" %%B in (""!temp2!"") do (
endlocal
set "var1=%%~A"
set "var2=%%~B"
)
)
一定要查看jeb的答案，这是一种安全、防弹的技术，适用于所有可能的值和情况。
2017-08-21 - 新功能RETURN.BAT
我与DosTips用户jeb合作开发了一个批处理实用程序，名为RETURN.BAT，可用于从脚本或被调用的例程中退出，并在ENDLOCAL障碍上返回一个或多个变量。非常酷 :-)
下面是代码的3.0版本。我很可能不会保持这个代码的最新状态。最好跟随链接以确保您获取最新版本，并查看一些示例用法。
RETURN.BAT
::RETURN.BAT Version 3.0
@if "%~2" equ "" (goto :return.special) else goto :return
:::
:::call RETURN ValueVar ReturnVar [ErrorCode]
::: Used by batch functions to EXIT /B and safely return any value across the
::: ENDLOCAL barrier.
::: ValueVar = The name of the local variable containing the return value.
::: ReturnVar = The name of the variable to receive the return value.
::: ErrorCode = The returned ERRORLEVEL, defaults to 0 if not specified.
:::
:::call RETURN "ValueVar1 ValueVar2 ..." "ReturnVar1 ReturnVar2 ..." [ErrorCode]
::: Same as before, except the first and second arugments are quoted and space
::: delimited lists of variable names.
:::
::: Note that the total length of all assignments (variable names and values)
::: must be less then 3.8k bytes. No checks are performed to verify that all
::: assignments fit within the limit. Variable names must not contain space,
::: tab, comma, semicolon, caret, asterisk, question mark, or exclamation point.
:::
:::call RETURN init
::: Defines return.LF and return.CR variables. Not required, but should be
::: called once at the top of your script to improve performance of RETURN.
:::
:::return /?
::: Displays this help
:::
:::return /V
::: Displays the version of RETURN.BAT
:::
:::
:::RETURN.BAT was written by Dave Benham and DosTips user jeb, and was originally
:::posted within the folloing DosTips thread:
::: http://www.dostips.com/forum/viewtopic.php?f=3&t=6496
:::
::==============================================================================
:: If the code below is copied within a script, then the :return.special code
:: can be removed, and your script can use the following calls:
::
:: call :return ValueVar ReturnVar [ErrorCode]
::
:: call :return.init
::
:return ValueVar ReturnVar [ErrorCode]
:: Safely returns any value(s) across the ENDLOCAL barrier. Default ErrorCode is 0
setlocal enableDelayedExpansion
if not defined return.LF call :return.init
if not defined return.CR call :return.init
set "return.normalCmd="
set "return.delayedCmd="
set "return.vars=%~2"
for %%a in (%~1) do for /f "tokens=1*" %%b in ("!return.vars!") do (
set "return.normal=!%%a!"
if defined return.normal (
set "return.normal=!return.normal:%%=%%3!"
set "return.normal=!return.normal:"=%%4!"
for %%C in ("!return.LF!") do set "return.normal=!return.normal:%%~C=%%~1!"
for %%C in ("!return.CR!") do set "return.normal=!return.normal:%%~C=%%2!"
set "return.delayed=!return.normal:^=^^^^!"
) else set "return.delayed="
if defined return.delayed call :return.setDelayed
set "return.normalCmd=!return.normalCmd!&set "%%b=!return.normal!"^!"
set "return.delayedCmd=!return.delayedCmd!&set "%%b=!return.delayed!"^!"
set "return.vars=%%c"
)
set "err=%~3"
if not defined err set "err=0"
for %%1 in ("!return.LF!") do for /f "tokens=1-3" %%2 in (^"!return.CR! %% "") do (
(goto) 2>nul
(goto) 2>nul
if "^!^" equ "^!" (%return.delayedCmd:~1%) else %return.normalCmd:~1%
if %err% equ 0 (call ) else if %err% equ 1 (call) else cmd /c exit %err%
)
:return.setDelayed
set "return.delayed=%return.delayed:!=^^^!%" !
exit /b
:return.special
@if /i "%~1" equ "init" goto return.init
@if "%~1" equ "/?" (
for /f "tokens=* delims=:" %%A in ('findstr "^:::" "%~f0"') do @echo(%%A
exit /b 0
)
@if /i "%~1" equ "/V" (
for /f "tokens=* delims=:" %%A in ('findstr /rc:"^::RETURN.BAT Version" "%~f0"') do @echo %%A
exit /b 0
)
@>&2 echo ERROR: Invalid call to RETURN.BAT
@exit /b 1
:return.init - Initializes the return.LF and return.CR variables
set ^"return.LF=^
^" The empty line above is critical - DO NOT REMOVE
for /f %%C in ('copy /z "%~f0" nul') do set "return.CR=%%C"
exit /b 0
FOR /F "delims=" %%A in (""!tempvar!"") do endlocal & set "var=%%~A"。 - jeb; 开头，则会被跳过。用引号括起来是个好主意。另一个选项是在发出 SETLOCAL 命令之前将值初始化为空，但如果通过多个 FOR /F 循环返回多个值，则可能会失败。 - dbenham@ECHO OFF
SETLOCAL
REM Keep in mind that BAR in the next statement could be anything, including %1, etc.
SET FOO=BAR
ENDLOCAL && SET FOO=%FOO%
endlocal，然后 set 中的变量已经被扩展了。 - Joey!处失败（dbenham也说过这一点）。@echo off
setlocal EnableDelayedExpansion
cls
for /f %%a in ('copy /Z "%~dpf0" nul') do set "CR=%%a"
set LF=^
rem TWO Empty lines are neccessary
set "original=zero*? %%~A%%~B%%~C%%~L!LF!one&line!LF!two with exclam^! !LF!three with "quotes^&"&"!LF!four with ^^^^ ^| ^< ^> ( ) ^& ^^^! ^"!LF!xxxxxwith CR!CR!five !LF!six with ^"^"Q ^"^"L still six "
setlocal DisableDelayedExpansion
call :lfTest result original
setlocal EnableDelayedExpansion
echo The result with disabled delayed expansion is:
if !original! == !result! (echo OK) ELSE echo !result!
call :lfTest result original
echo The result with enabled delayed expansion is:
if !original! == !result! (echo OK) ELSE echo !result!
echo ------------------
echo !original!
goto :eof
::::::::::::::::::::
:lfTest
setlocal
set "NotDelayedFlag=!"
echo(
if defined NotDelayedFlag (echo lfTest was called with Delayed Expansion DISABLED) else echo lfTest was called with Delayed Expansion ENABLED
setlocal EnableDelayedExpansion
set "var=!%~2!"
rem echo the input is:
rem echo !var!
echo(
rem ** Prepare for return
set "var=!var:%%=%%~1!"
set "var=!var:"=%%~2!"
for %%a in ("!LF!") do set "var=!var:%%~a=%%~L!"
for %%a in ("!CR!") do set "var=!var:%%~a=%%~3!"
rem ** It is neccessary to use two IF's else the %var% expansion doesn't work as expected
if not defined NotDelayedFlag set "var=!var:^=^^^^!"
if not defined NotDelayedFlag set "var=%var:!=^^^!%" !
set "replace=%% """ !CR!!CR!"
for %%L in ("!LF!") do (
for /F "tokens=1,2,3" %%1 in ("!replace!") DO (
ENDLOCAL
ENDLOCAL
set "%~1=%var%" !
@echo off
goto :eof
)
)
exit /b
我也想为此做出贡献，告诉您如何传递类似数组的变量集合：
@echo off
rem clean up array in current environment:
set "ARRAY[0]=" & set "ARRAY[1]=" & set "ARRAY[2]=" & set "ARRAY[3]="
rem begin environment localisation block here:
setlocal EnableExtensions
rem define an array:
set "ARRAY[0]=1" & set "ARRAY[1]=2" & set "ARRAY[2]=4" & set "ARRAY[3]=8"
rem `set ARRAY` returns all variables starting with `ARRAY`:
for /F "tokens=1,* delims==" %%V in ('set ARRAY') do (
if defined %%V (
rem end environment localisation block once only:
endlocal
)
rem re-assign the array, `for` variables transport it:
set "%%V=%%W"
)
rem this is just for prove:
for /L %%I in (0,1,3) do (
call echo %%ARRAY[%%I]%%
)
exit /B
setlocal块内被定义并且通过if defined查询，因此只会执行一次endlocal。对于所有后续循环迭代，setlocal块已经结束，因此if defined的值为FALSE。
这依赖于至少分配一个数组元素或者实际上在setlocal/endlocal块中至少定义一个以ARRAY开头的变量。如果在其中不存在任何变量，则不会执行endlocal。在setlocal块外面，不能定义任何此类变量，否则，if defined将会多次评估并且endlocal将会被多次执行。setlocal命令之前清空标志变量，例如：set "ARR_FLAG="；setlocal/endlocal块内定义标志变量，即向其分配一个非空值（最好是在for /F循环之前）：set "ARR_FLAG=###"；if defined命令行更改为：if defined ARR_FLAG (；for /F选项字符串更改为"delims="；for /F循环中的set命令行更改为：set "%%V"；类似以下代码（我还没有测试）：
@echo off
setlocal
set base=compute directory
set pkg=compute sub-directory
set scripts=%base%\%pkg%\Scripts
pushd %scripts%
endlocal
call .\activate.bat
popd
由于上述方法无法正常工作（请参考Marcelo的评论），我建议按照以下方式进行：
set uniquePrefix_base=compute directory
set uniquePrefix_pkg=compute sub-directory
set uniquePrefix_scripts=%uniquePrefix_base%\%uniquePrefix_pkg%\Scripts
set uniquePrefix_base=
set uniquePrefix_pkg=
call %uniquePrefix_scripts%\activate.bat
set uniquePrefix_scripts=
其中uniquePrefix_被选择为在您的环境中“几乎肯定”是唯一的。
您还可以在进入批处理文件时测试“uniquePrefix_…”环境变量是否按预期未定义 - 如果不是，则可以退出并显示错误。
我不喜欢将BAT文件复制到TEMP目录作为一般解决方案，因为（a）存在与>1个调用者的竞争条件的潜在可能性，以及（b）在一般情况下，BAT文件可能正在使用相对于其位置的路径访问其他文件（例如%~dp0..\somedir\somefile.dat）。
以下丑陋的解决方案将解决（b）：
setlocal
set scripts=...whatever...
echo %scripts%>"%TEMP%\%~n0.dat"
endlocal
for /f "tokens=*" %%i in ('type "%TEMP%\%~n0.dat"') do call %%i\activate.bat
del "%TEMP%\%~n0.dat"
如果您选择使用其他响应中有时提到的“经典”ENDLOCAL & SET VAR =％TEMPVAR％（并且满意某些响应中显示的缺点已经解决或不是问题），请注意您可以进行多个变量，即 ENDLOCAL ＆SET var1 =％local1％＆SET var2 =％local2％ 。
我分享这个是因为除了下面链接的网站，我只看到过用于单个变量的“技巧”，像我一样的一些人可能会错误地认为它仅适用于单个变量。
echo %scripts%\activate.bat > %TEMP%\activate.bat
endlocal
call %TEMP%\activate.bat
del %TEMP%\activate.bat
这太丑了，我想低头羞耻。欢迎更好的答案。
这样怎么样？
@echo off
setlocal
set base=compute directory
set pkg=compute sub-directory
set scripts=%base%\%pkg%\Scripts
(
endlocal
"%scripts%\activate.bat"
)
!或;等特殊字符。）这表明我们所有人更关心教学而不仅仅是快速地回答问题。那就是 StackOverflow。 - Jesse Chisholm