使用 Delphi 2007 进行 Base64 编码和解码

Question

我需要在旧版的Delphi 2007中将字节数组编码为base64字符串（同时解码此字符串）。

更多信息：

我尝试过使用synapse库（正如在Binary to Base64 (Delphi)中所建议的那样）。

- Hwau

---

Base64是一种标准编码，无论语言或版本如何都可以使用。这意味着它被编码或解码的方式可能存在问题。我们能看到你的编码和解码的代码吗？ - Jerry Dodge

您可以使用Indy尝试TIdDecoderMIME类。 - RRUZ

和 TIdEncoderMIME - Remy Lebeau

EncdDecd.pas不在$(DELPHI)\Source\Internet路径下？ - Mohamad

@Hwau：我在 Delphi 7 中使用过这个单元。 - Mohamad

Answer 1

Indy随Delphi一起发布，具有处理base64的TIdEncoderMIME和TIdDecoderMIME类。例如：

uses
  ..., IdCoder, IdCoderMIME;

var
  Bytes: TIdBytes;
  Base64String: String;
begin
  //...
  Bytes := ...; // array of bytes
  //...
  Base64String := TIdEncoderMIME.EncodeBytes(Bytes);
  //...
  Bytes := TIdDecoderMIME.DecodeBytes(Base64String);
  //...
end;

此外，还有一些编码/解码String和TStream数据的方法。

更新：或者，如果你的版本没有上述class方法：

// TBytesStream was added in D2009, so define it manually for D2007

uses
  ..., IdCoder, IdCoderMIME
  {$IF RTLVersion < 20)
  , RTLConsts
  {$IFEND}
  ;

{$IF RTLVersion < 20)
type
  TBytesStream = class(TMemoryStream)
  private
    FBytes: TBytes;
  protected
    function Realloc(var NewCapacity: Longint): Pointer; override;
  public
    constructor Create(const ABytes: TBytes); overload;
    property Bytes: TBytes read FBytes;
  end;

constructor TBytesStream.Create(const ABytes: TBytes);
begin
  inherited Create;
  FBytes := ABytes;
  SetPointer(Pointer(FBytes), Length(FBytes));
  FCapacity := FSize;
end;

const
  MemoryDelta = $2000; // Must be a power of 2

function TBytesStream.Realloc(var NewCapacity: Integer): Pointer;
begin
  if (NewCapacity > 0) and (NewCapacity <> FSize) then
    NewCapacity := (NewCapacity + (MemoryDelta - 1)) and not (MemoryDelta - 1);
  Result := Pointer(FBytes);
  if NewCapacity <> FCapacity then
  begin
    SetLength(FBytes, NewCapacity);
    Result := Pointer(FBytes);
    if NewCapacity = 0 then
      Exit;
    if Result = nil then raise EStreamError.CreateRes(@SMemoryStreamError);
  end;
end;
{$IFEND}

var
  Bytes: TBytes;
  BStrm: TBytesStream;
  Encoder: TIdEncoderMIME;
  Decoder: TIdDecoderMIME;
  Base64String: String;
begin
  //...
  Bytes := ...; // array of bytes
  //...
  BStrm := TBytesStream.Create(Bytes);
  try
    Encoder := TIdEncoderMIME.Create;
    try
      Base64String := Encoder.Encode(BStrm);
    finally
      Encoder.Free;
    end;
  finally
    BStrm.Free;
  end;
  //...
  BStrm := TBytesStream.Create;
  try
    Decoder := TIdDecoderMIME.Create;
    try
      Decoder.DecodeBegin(BStrm);
      Decoder.Decode(Base64String);
      Decoder.DecodeEnd;
    finally
      Decoder.Free;
    end;
    Bytes := BStrm.Bytes;
  finally
    BStrm.Free;
  end;
  //...
end;

- Remy Lebeau

---

它在更高版本的Delphi上运行良好！感谢您的建议和示例，我会尽快在Delphi 2007上进行检查，但我认为它也适用于旧版IDE。 - Hwau

@Hwau：您可以将Indy升级到最新版本，即使在旧版Delphi上也可以。 - whosrdaddy

很不幸，使用Delphi2007时EncodeBytes和DecodeBytes函数未声明。我宁愿不手动升级indy，还有其他方法吗？ - Hwau

@Hwau：你需要查看D2007的IdCoder单元，了解该版本实际可用的函数。最坏的情况是，class方法可能不可用，因此尝试实例化TIdEncoderMIME/TIdDecoderMIME对象，并使用它们的非class方法。我在答案中更新了一个示例。 - Remy Lebeau

@RemyLebeau：抱歉长时间没有回复，Delphi-2007 中似乎未定义TBytesStream，还有什么其他方法可以将字节数组加载到流中吗？ - Hwau

TBytesStream是在D2009中添加的。我已经更新了我的答案，包括D2007的实现。或者，您可以将字节简单地复制到标准的TMemoryStream中。 - Remy Lebeau

Answer 2

与您在问题中所述的相反，EncdDecd单元已包含在Delphi 2007中。您可以直接使用它。

- David Heffernan

Answer 3

David Heffernan做出了很好的回答！

在您的用途中添加“EncdDecd”类，它将具有以下过程：

function DecodeString (const Input: string): string;
function DecodeBase64 (const Input: string): TBytes;

使用https://www.base64encode.org/进行测试

在Delphi和该网站中，“Working”字符串的结果均为：“V29ya2luZw==”

ShowMessage ('Working =' + EncodeString ('Working'));
ShowMessage ('Working =' + DecodeString ('V29ya2luZw =='));

- Fernando Lúcio F de Camargo

Answer 4

对于旧版本的 Delphi（Delphi XE7 之前），请使用以下方法：

uses 
Soap.EncdDecd

procedure DecodeFile(const Base64: AnsiString; const FileName: string);
var
  BStream: TBytesStream;
begin
  BStream := TBytesStream.Create(DecodeBase64(Base64));
  try
    BStream.SaveToFile(Filename);
  finally
    BStream.Free;
  end;
end;

对于Delphi的NEWS版本，请使用：

uses
System.NetEncoding;

procedure DecodeFile(const Base64: String; const FileName: string);
var
  BStream: TBytesStream;
begin
  BStream:= TBytesStream.Create(TNetEncoding.Base64.DecodeStringToBytes(Base64));
  try
    BStream.SaveToFile(Filename);
  finally
    BStream.Free;
  end;
end;

- Marlon Nardi

Answer 5

这里是EncodeToBase64：

uses
classes, sysutils;

function EncodeToBase64(var Buffer: TBytes): Longint;
const
  EncodingTable: PChar = 'ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/';
var
  WriteBuf: array[0..3] of Byte;
  Buf: array[0..2] of Byte;
  Dest: TMemoryStream;
  i, j, Count: Integer;
begin
  Result := 0;

  Count := Length(Buffer);
  j := Count div 3;

  if j > 0 then
  begin
    Dest:= TMemoryStream.Create();  
    try
      Dest.Position := 0;
      for i := 0 to j - 1  do
      begin
        Move(Buffer[i * 3], Buf[0], 3); 
        WriteBuf[0] := Ord(EncodingTable[Buf[0] shr 2]);
        WriteBuf[1] := Ord(EncodingTable[(Buf[0] and 3) shl 4 or (Buf[1] shr 4)]);
        WriteBuf[2] := Ord(EncodingTable[(Buf[1] and 15) shl 2 or (Buf[2] shr 6)]);
        WriteBuf[3] := Ord(EncodingTable[Buf[2] and 63]);  
        Dest.Write(WriteBuf, 4);  
        Inc(Result, 4);
        Dec(Count, 3);    
      end;          

      if Count in [1, 2] then  
      begin           
        Move(Buffer[i * 3], Buf[0], Count);
        WriteBuf[0] := Ord(EncodingTable[Buf[0] shr 2]);
        WriteBuf[1] := Ord(EncodingTable[(Buf[0] and 3) shl 4 or (Buf[1] shr 4)]); 
        if Count = 1 then
          WriteBuf[2] := Ord('=')
        else                                           
          WriteBuf[2] := Ord(EncodingTable[(Buf[1] and 15) shl 2 or (Buf[2] shr 6)]);
        WriteBuf[3] := Ord('='); 
        Dest.Write(WriteBuf, 4);  
        Inc(Result, 4);
        Dec(Count, Count);
      end;

      if Result > 0 then
      begin
        SetLength(Buffer, Result);
        Dest.Position := 0;
        Dest.Read(Buffer[0], Result);   
      end;  
    finally
      Dest.Free;
    end;
  end;

end; 

这应该可以在不需要任何特殊的单位或组件的情况下工作。

- Dejan Dozet