每个驱动器都有自己的回收站。当您从C:驱动器删除文件时,它应该被移至C:驱动器上的回收站。当您从USB驱动器中删除文件时,它应该被移至USB驱动器上的回收站。但是,当USB驱动器没有回收站时,文件将被永久删除。这是默认的Windows行为。
FOF_ALLOWUNDO标志仅是建议性的。MSDN对FOF_ALLOWUNDO标志的说明如下:
保留撤消信息,
如果可能的话。
因此,即使使用FOF_ALLOWUNDO标志,Windows永久删除文件时也不会出现任何错误。
我唯一能想到的方法是在删除操作之前使用SHQueryRecycleBin函数(如评论中所指出的Alex Farber)检查驱动器上是否存在回收站。但是,即使回收站存在,也不能完全保证文件将被删除到回收站。回收站具有最大大小限制,它可能已经满了。
更新
您可以使用hack。您可以使用自己的代码模拟将文件移除到回收站,并创建C:\$Recycle.Bin\UserSID文件夹中所有必要的系统记录。我在Windows 7上测试过这种方法,它可以正常工作。它允许忽略回收站的最大大小限制。它还允许将文件从USB移动到任何驱动器上的回收站中。
更新2
对于Vista+,您可以使用未记录的接口IRecycleBinManager(俄语描述可以在网页
http://rcrrad.com/2010/10/14/bitbucket-interfaces/中找到):
const
IID_IEnumRecycleItems: TGUID = '{6E325F88-D12F-49E5-895B-8EC98630C021}';
IID_IRecycle: TGUID = '{0125E62F-8349-443A-854B-A55FB84CFA35}';
IID_IRecycleBin: TGUID = '{F964AD97-96F4-48AB-B444-E8588BC7C7B3}';
IID_IRecycleBinManager: TGUID = '{5869092D-8AF9-4A6C-AE84-1F03BE2246CC}';
CLSID_RecycleBinManager: TGUID = '{4A04656D-52AA-49DE-8A09-CB178760E748}';
type
tagRECYCLEBIN_TYPE = (RBTYPE_VOLUME, RBTYPE_KNOWNFOLDER);
TRecycleBinType = tagRECYCLEBIN_TYPE;
PDeletedItem = ^TDeletedItem;
tagDELETEDITEM = packed record
dwFileSizeLow: DWORD;
dwFileSizeHigh: DWORD;
ftDeletionTime: TFileTime;
szOriginalPath: array[0..Pred(MAX_PATH)] of WideChar;
szDisplacedPath: array[0..Pred(MAX_PATH)] of WideChar;
end;
TDeletedItem = tagDELETEDITEM;
IEnumRecycleItems = interface(IUnknown)
['{6E325F88-D12F-49E5-895B-8EC98630C021}']
function Next(celt: ULONG; out rgelt: TDeletedItem;
var pceltFetched: ULONG): HRESULT; stdcall;
function Skip(celt: ULONG): HRESULT; stdcall;
function Reset: HRESULT; stdcall;
function Clone(out ppenum: IEnumRecycleItems): HRESULT; stdcall;
end;
IRecycle = interface(IUnknown)
['{0125E62F-8349-443A-854B-A55FB84CFA35}']
function Compact(): HRESULT; stdcall;
function GetFileData(const pszPath: LPCWSTR;
out lpData: TDeletedItem): HRESULT; stdcall;
function GetItemCount(out lpCount: TLargeInteger): HRESULT; stdcall;
function GetUsedSpace(out lpUsedSpace: TLargeInteger): HRESULT; stdcall;
function IsEmpty(): HRESULT; stdcall;
function PurgeAll(pfo: IFileOperation): HRESULT; stdcall;
function PurgeItems(const lpstrItems: LPCWSTR;
pfo: IFileOperation): HRESULT; stdcall;
function SuspendUpdating(fSuspend: BOOL): HRESULT; stdcall;
function RecycleItem(const lpstrItem: LPCWSTR; const dwAttrs: DWORD;
const iFileSize: TLargeInteger; out psi: IShellItem): HRESULT; stdcall;
function RestoreItems(const lpstrItems: LPCWSTR;
pfo: IFileOperation): HRESULT; stdcall;
function IsRecycled(const pszPath: LPCWSTR;
lpRecycled: PBOOL): HRESULT; stdcall;
function EnumItems(dwFlags: DWORD;
out EnumRecycleItems: IEnumRecycleItems): HRESULT; stdcall;
function WillRecycle(const pszPath: LPCWSTR): HRESULT; stdcall;
end;
IRecycleBin = interface(IUnknown)
['{F964AD97-96F4-48AB-B444-E8588BC7C7B3}']
function Compact(): HRESULT; stdcall;
function GetFileData(const pszPath: LPCWSTR;
out lpData: TDeletedItem): HRESULT; stdcall;
function GetItemCount(out lpCount: TLargeInteger): HRESULT; stdcall;
function GetUsedSpace(out lpUsedSpace: TLargeInteger): HRESULT; stdcall;
function IsEmpty(): HRESULT; stdcall;
function PurgeAll(pfo: IFileOperation): HRESULT; stdcall;
function PurgeItems(const lpstrItems: LPCWSTR;
pfo: IFileOperation): HRESULT; stdcall;
function SuspendUpdating(fSuspend: BOOL): HRESULT; stdcall;
function RecycleItem(const lpstrItem: LPCWSTR; const dwAttrs: DWORD;
const iFileSize: TLargeInteger; out psi: IShellItem): HRESULT; stdcall;
function RestoreItems(const lpstrItems: LPCWSTR;
pfo: IFileOperation): HRESULT; stdcall;
function IsRecycled(const pszPath: LPCWSTR;
lpRecycled: PBOOL): HRESULT; stdcall;
function EnumItems(dwFlags: DWORD;
out EnumRecycleItems: IEnumRecycleItems): HRESULT; stdcall;
function WillRecycle(const pszPath: LPCWSTR): HRESULT; stdcall;
function Initialize(const rbType: TRecycleBinType;
const pszID: LPCWSTR): HRESULT; stdcall;
function GetTypeID(out rbType: TRecycleBinType;
var pszID: LPWSTR): HRESULT; stdcall;
function GetIDList(out ppidl: PItemIDList): HRESULT; stdcall;
function GetLocation(pszPathBuffer: LPWSTR;
cchMax: DWORD): HRESULT; stdcall;
function GetMaxCapacityRange(out lpMin: TLargeInteger;
out lpMax: TLargeInteger): HRESULT; stdcall;
function GetMaxCapacity(out lpCapacity: TLargeInteger): HRESULT; stdcall;
function SetMaxCapacity(const lpCapacity: TLargeInteger): HRESULT; stdcall;
function GetPurgeOnDelete(out fNukeOnDelete: BOOL): HRESULT; stdcall;
function SetPurgeOnDelete(const fNukeOnDelete: BOOL): HRESULT; stdcall;
end;
IRecycleBinManager = interface(IUnknown)
['{5869092D-8AF9-4A6C-AE84-1F03BE2246CC}']
function Compact(): HRESULT; stdcall;
function GetFileData(const pszPath: LPCWSTR;
out lpData: TDeletedItem): HRESULT; stdcall;
function GetItemCount(out lpCount: TLargeInteger): HRESULT; stdcall;
function GetUsedSpace(out lpUsedSpace: TLargeInteger): HRESULT; stdcall;
function IsEmpty(): HRESULT; stdcall;
function PurgeAll(pfo: IFileOperation): HRESULT; stdcall;
function PurgeItems(const lpstrItems: LPCWSTR;
pfo: IFileOperation): HRESULT; stdcall;
function SuspendUpdating(fSuspend: BOOL): HRESULT; stdcall;
function RecycleItem(const lpstrItem: LPCWSTR; const dwAttrs: DWORD;
const iFileSize: TLargeInteger; out psi: IShellItem): HRESULT; stdcall;
function RestoreItems(const lpstrItems: LPCWSTR;
pfo: IFileOperation): HRESULT; stdcall;
function IsRecycled(const pszPath: LPCWSTR;
lpRecycled: PBOOL): HRESULT; stdcall;
function EnumItems(dwFlags: DWORD;
out EnumRecycleItems: IEnumRecycleItems): HRESULT; stdcall;
function WillRecycle(const pszPath: LPCWSTR): HRESULT; stdcall;
function DelayCompaction(const fDelay: BOOL): HRESULT; stdcall;
function GetRecycleBinCount(out iCount: Integer): HRESULT; stdcall;
function GetRecycleBinAt(const index: Integer; const iid: TGUID;
out ppv): HRESULT; stdcall;
function GetRecycleBin(const pszPath: LPCWSTR; const iid: TGUID;
out ppv): HRESULT; stdcall;
function Refresh(): HRESULT; stdcall;
end;
您可以使用以下代码检查将文件删除到回收站的可能性:
function CanFileBeDeletedToRecycleBin(const AFileName: UnicodeString): Boolean;
var
RecycleBinManager: IRecycleBinManager;
begin
OleCheck(CoCreateInstance(CLSID_RecycleBinManager, nil, CLSCTX_INPROC_SERVER or CLSCTX_LOCAL_SERVER, IRecycleBinManager, RecycleBinManager));
try
Result := RecycleBinManager.WillRecycle(PWideChar(AFileName)) = S_OK;
finally
RecycleBinManager := nil;
end;
end;
更新 3
您也可以尝试以下代码将对象删除到回收站:
function GetObjectSize(const AFileName: UnicodeString): Int64;
var
FindHandle: THandle;
FindData: TWin32FindDataW;
S: Int64;
begin
Result := 0;
FindHandle := FindFirstFileW(PWideChar(AFileName), FindData);
if FindHandle = INVALID_HANDLE_VALUE then
RaiseLastOSError;
try
repeat
if (FindData.cFileName <> UnicodeString('.')) and (FindData.cFileName <> '..') then
begin
Int64Rec(S).Lo := FindData.nFileSizeLow;
Int64Rec(S).Hi := FindData.nFileSizeHigh;
Result := Result + S;
if FindData.dwFileAttributes and FILE_ATTRIBUTE_DIRECTORY <> 0 then
Result := Result + GetObjectSize(AFileName + '\*.*');
end;
until not FindNextFileW(FindHandle, FindData);
finally
FindClose(FindHandle);
end;
end;
procedure DeleteToRecycleBin(const AFileName: UnicodeString);
var
Attr: DWORD;
Size: Int64;
RecycleBinManager: IRecycleBinManager;
RecycleBin: IRecycleBin;
ShellItem: IShellItem;
begin
OleCheck(CoCreateInstance(CLSID_RecycleBinManager, nil, CLSCTX_INPROC_SERVER or CLSCTX_LOCAL_SERVER, IRecycleBinManager, RecycleBinManager));
try
OleCheck(RecycleBinManager.GetRecycleBin(PWideChar(AFileName), IRecycleBin, RecycleBin));
try
Attr := GetFileAttributes(PWideChar(AFileName));
Size := GetObjectSize(AFileName);
OleCheck(RecycleBin.RecycleItem(PWideChar(AFileName), Attr, Size, ShellItem));
ShellItem := nil;
finally
RecycleBin := nil;
end;
finally
RecycleBinManager := nil;
end;
end;