如何在 Terraform 中遍历所有 AWS 实例？

Question

我相对新手使用terraform，我正在尝试迭代所有aws_instances以应用null_resource。您可以使用多个通配符来访问所有实例吗，而不管它们的名称是什么？

EC2实例分为三种类型：

aws_instance.web.* (3 instances)
aws_instance.app.* (3 instances)
aws_instance.db.*  (2 instances)

这是我尝试将null_resource应用于所有八个aws_instances的方法:

resource "null_resource" "install_security_package" {

  #count = "${length(aws_instance)}" #terraform error: resource count can't reference variable: aws_instance
  #count = "${length(aws_instance.*)}" #terraform error: resource variables must be three parts: TYPE.NAME.ATTR
  count = "${length(aws_instance.*.*)}" #terraform error: unknown resource 'aws_instance.*'

  connection {
    type        = "ssh"
    host        = "${element(aws_instance.*.private_ip, count.index)}"
    user        = "${lookup(var.user, var.platform)}"
    private_key = "${file("${var.private_key_path}")}"
    timeout     = "2m"
  }

  provisioner "remote-exec" {
    inline = [
      "sudo rpm -Uvh http://www.example.com/security/repo/security_baseline.rpm",
    ]
  }
}

- skohrs

Answer 1

目前无法匹配给定类型的所有资源。正如您所见，"splat"语法只允许选择从特定资源块创建的所有实例。

在Terraform中，您今天可以最接近的方法是将不同的资源连接在一起：

concat(aws_instance.web.*.private_ip, aws_instance.app.*.private_ip, aws_instance.db.*.private_ip)

在本回答撰写时的 Terraform 当前版本中，为了避免在多个地方重复使用复杂表达式，需要使用一些在 github 问题 #4084 中分享的解决方法。即将推出的一个名为 Local Values 的功能将使这变得更加简单，允许为列表指定名称以在多个地方重复使用。

# Won't work until Terraform PR#15449 is merged and released
locals {
  aws_instance_addrs = "${concat(aws_instance.web.*.private_ip, aws_instance.app.*.private_ip, aws_instance.db.*.private_ip)}"
}

resource "null_resource" "install_security_package" {

  count = "${length(local.aws_instance_addrs)}"

  connection {
    type        = "ssh"
    host        = "${local.aws_instance_addrs[count.index]}"
    user        = "${lookup(var.user, var.platform)}"
    private_key = "${file("${var.private_key_path}")}"
    timeout     = "2m"
  }

  provisioner "remote-exec" {
    inline = [
      "sudo rpm -Uvh http://www.example.com/security/repo/security_baseline.rpm",
    ]
  }
}

- Martin Atkins