使用terraform允许一个AWS安全组访问另一个安全组

Question

我希望将一个安全组的访问权限授予另一个安全组，但我无法使其正常工作，请问有人可以指出我做错了什么吗？

下面是我的模块的 main.tf：

resource "aws_security_group" "rds_sg" {
    name = "${var.name}-${var.environment}-rds"
    description = "Security Group ${var.name}-${var.environment}"
    vpc_id = "${var.vpc_id}"
    tags {
        Name = "${var.name}-${var.environment}-rds"
        environment =  "${var.environment}"
    }

    // allows traffic from the SG itself
    ingress {
        from_port = 0
        to_port = 0
        protocol = "-1"
        self = true
    }

    // allow traffic for TCP 3306
    ingress {
        from_port = 3306
        to_port = 3306
        protocol = "tcp"
        security_group_id = "${var.security_group_id}"
    }

    // outbound internet access
    egress {
        from_port = 0
        to_port = 0
        protocol = "-1"
        cidr_blocks = ["0.0.0.0/0"]
    }
}

output "rds_sg_id" {
    value = "${aws_db_security_group.rds_sg.id}"
}

模块的variables.tf：

// Module specific variables
variable "name" {
    default = "test"
}

variable "environment" {
    default = "test"
}

variable "vpc_id" {
    description = "The VPC this security group will go in"
}

variable "security_group_id" {
    description = "Security Group id"
}

security_groups_id的值来自另一个模块，所以在我的主文件中是这样的：

module "rds_sg" {
    source = "./modules/rds_sg"
    name = "tendo"
    environment = "dev"
    vpc_id = "${module.vpc_subnets.vpc_id}"
    security_group_id = "${module.web_sg.web_sg_id}"
}

但是当我尝试执行 "terraform" 时，出现了以下错误：

Errors:

  * 1 error(s) occurred:

* module root: module rds_sg: security_group_id is not a valid parameter

- Arbab Nazar

---

看到那个错误信息，我感觉安全组ID在模块内不存在。你能给我们展示一下模块代码吗？ - Liam

@LiamJones，请您审阅一下，我已经更新了问题并提供了所有必要的细节。谢谢。 - Arbab Nazar

Answer 1

我想我已经找到了问题所在；您在模块的main.tf中使用了错误的参数来提供安全组。请参见下面修改后的代码和文档。

// allow traffic for TCP 3306
ingress {
    from_port = 3306
    to_port = 3306
    protocol = "tcp"
    security_groups = ["${var.security_group_id}"]
}

- Liam

Answer 2

使用 aws_security_group_rule Terraform 资源来实现规则。

resource "aws_security_group_rule" "ingress" {
  type                     = "ingress"
  from_port                = 3306
  to_port                  = 3306
  protocol                 = "tcp"
  source_security_group_id = var.security_group_id
  security_group_id        = aws_security_group.rds_sg.id
}

- mellifluous

Answer 3

以下方法对我有效，这里我允许一个安全组的所有端口。

  ingress {
     from_port   = 0
     to_port     = 65535
     protocol    = "tcp"
     security_groups = ["${aws_security_group.OTHER_SECURITY_GROUP_NAME.id}"]
 }

- Shree Prakash

Answer 4

将安全组的ID作为变量输出。

output "rds_sg_id" {
  value = "${aws_security_group.rds_sg.id}"
}

使用安全组时

// allow traffic for TCP 3306
    ingress {
        from_port = 3306
        to_port = 3306
        protocol = "tcp"
        security_group_id = "${var.rds_sg_id}"
    }

- Daniel Lang

---

我做了同样的事情，但仍然出现错误，请您检查一下我的更新问题。谢谢。 - Arbab Nazar